como asignar a un item combobox un numero

[[Caral]]

Hola
Asi no se vale, yo no pude borrar el mio...
Saludos

[ecfisa]

Hola Kamael.

Te agrego otra opción.

Ejemplo:

Código Delphi [-]
...
procedure TForm1.FormCreate(Sender: TObject);
const 
  METAL: array[1..6] of string =('Cobre', 'Aluminio', 'Hierro', 'Mercurio', 'Oro', 'Plata');
  VALOR: array[1..6] of Integer = (10, 20, 30, 40, 50, 60);
var
  i: Integer;
begin
  with ComboBox1 do
  begin
    for i:= 1 to 6 do
      AddItem(METAL[i], TObject(VALOR[i]));  // nombre de metal y valor
    ItemIndex:= 0;
  end;
end;

procedure TForm1.ComboBox1CloseUp(Sender: TObject);
begin
  with ComboBox1 do
    ShowMessage('Metal: ' + Items[ItemIndex] + #10#13 +  // nombre de metal
                'Valor: ' + IntToStr(Integer(Items.Objects[ItemIndex])));  // valor
end;

Saludos.

[Kamael]

gracias a todos por responder tan rapido. Lo he solucionado de esta manera :

If Combobox1.Text = 'Aluminio' then
 begin
    lbabel1.Caption := FloatToStr(0.029) ;
  end ;

 If Combobox1.Text = 'Cobre' then
 begin
 
   Label2.Caption := FloatToStr(0.017) ;
end;

De todas maneras repasare vuestro codigo, pues me parece mas interesante que el mio

[[Delphius]]

Para ese caso yo no me mataría pensando demasiado y me iría por lo simple:

Código Delphi [-]
type
TChemical = record
  Name: string[20];
  Value: double;
end;

TChemicalList[0..CHEMICALS_COUNTS] of TChemical;

var
  Cl: TChemicalList;

Inicializo el array con los datos (otra alternativa, quizá más apropiada, es directamente definir este array como constante e inicializado por defecto) y cargo en el combo el [].Name. De este modo se puede vincular la posición del ítem seleccionado (ItemIndex) con el elemento en cuestión y recuperar el valor.

A modo de ejemplo:

Código Delphi [-]
TForm1.SelectElement(Sender: TObject);
var value: double;
begin
  Value := Cl[ComboBox1.ItemIndex].Value;
  // otras operaciones con Value
end;

Saludos,

[[Caral]]

Hola
Otro ejemplo mas usando arrays dinamicos (como estoy con esto )
Siguiendo el ejemplo de mi amigo ecfisa el que me parecio muy bueno os hago otro con menos codigo.

asignamos el array publico sin datos:

Código Delphi [-]
public
    { Public declarations }
    Valores: array of string
  end;

En el evento onchange del combobox, le indicamos cuantos valores, le asignamos el valor y lo presentamos:

Código Delphi [-]
procedure TForm1.ComboBox1Change(Sender: TObject);
var
  i  :Integer;
  valor : Real;
begin
    SetLength( Valores, 4 );
    Valores[0] := '0.017';
    Valores[1] := '0.22';
    Valores[2] := '1.22';
    Valores[3] := '2.015';

    for i := 0 to ComboBox1.ItemIndex  do begin
    label1.Caption:=  Valores[i];

end;
end;

Como estoy aprendiendo.
saludos

[[Delphius]]

La alternativa, como bien indico sería algo como:

Código Delphi [-]
const
  CHEMICAL_LIST: array [0..CHEMICALS_COUNTS] of TChemical =
  (
    (Name: 'Oro'; Value: 0.1);
    (Name: 'Plata'; Value: 0.2);
    // ...
  );

Y ya tenemos directamente este array constante que no requiere llenarlo, basta con pasar los datos al Combo:

Código Delphi [-]
for i := 0 to CHEMICALS_COUNTS do
ComboBox1.Items.Add(CHEMICAL_LIST[i]);

Saludos,

[[Delphius]]

Un ejemplo muy básico:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

const
  CHEMICALS_COUNT = 2;

type
  TChemical = record
    Name: string[20];
    Value: Double;
  end;

const
  CHEMICALS_LIST: array [0..CHEMICALS_COUNT - 1] of TChemical =
  (
    (Name: 'ele1'; Value: 0.1), // pos 0
    (Name: 'ele2'; Value: 0.2) // pos 1
  );

type
  TForm1 = class(TForm)
    cobx1: TComboBox;
    ll1: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure cobx1Change(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var i: Integer;
begin
 // llenamos el combo:
 for i := 0 to CHEMICALS_COUNT - 1 do
   cobx1.Items.Add(CHEMICALS_LIST[i].Name);
end;

procedure TForm1.cobx1Change(Sender: TObject);
var elem: string;
    value: Double;
begin
  elem := CHEMICALS_LIST[cobx1.ItemIndex].Name;
  value := CHEMICALS_LIST[cobx1.ItemIndex].Value;

  ll1.Caption := 'El valor del elemento ' + elem + ' es: ' + FloatToStr(value);
end;

end.

Saludos,

[[Caral]]

Hola
Me pregunto:
Para que llenar los items del combobox si Kamael ya los tiene ?.
Creo que le complicáis la vida con esto, aunque siempre es bueno saber algo mas, recordad que es principiante.
Saludos