Form.Components como Parametro

[Neeruu]

Hola Dec!!!

Si pensé eso, pero como hago para poder pasar Formulario y Frame?

Hay veces que tengo los componentes sobre el Formulario y otras los tengo en un Frame.

Entonces, Como debería quedarme el tipo de parámetro y como debería leerlo para que esto me sea indistinto a la hora de recuperar los componentes en el procedimiento?

Podría ser pasarlo como TClass y en el procedimiento preguntar que tipo de clase es y según eso leerlo con el tipo que corresponda???


Saluda Atte Neeruu!!!

[luisgutierrezb]

no tengo el delphi a la mano, cuestion de revisar pero segun recuerdo el formulario y frame tienen un ancestro comun y creo que es TCustomForm, si es asi, no necesitarias irte tan atras como el TClass

[ecfisa]

Hola.

Coincido con lo que te han sugerido dec y luisgutierrezb.

Probá de este modo:

Código Delphi [-]
procedure ComponentsColorDataSetStatus(myState:TDataSetState; AControl: TControl);
var
  i:Integer;
  myColor:TColor;
begin
  myColor:= clWhite;
  Case myState of
    dsInactive: myColor := clGray;
    dsBrowse  : myColor := clWindow;
    dsEdit    : myColor := $00B7DBFF;
    dsInsert  : myColor := $00C5DEC9;
  end;
  if AControl is TForm then
    with TForm(AControl) do
      for i:= 0 to ComponentCount -1 do
      begin
        if Components[i] is TDBEdit then
          TDBEdit(Components[i]).Color := myColor;
        ...
      end;
  if AControl is TFrame then
    with TFrame(AControl) do
      for i:= 0 to ComponentCount -1 do
      begin
        if Components[i] is TDBEdit then
          TDBEdit(Components[i]).Color := myColor;
        ...
      end;
end;

Llamadas:

Código Delphi [-]
  ...
  ComponentsColorDataSetStatus(DataSet.State, Form1);
  ComponentsColorDataSetStatus(DataSet.State, Frame1);

No uso los componentes Tcx, por lo que tendrías que probar si el código funciona con ellos, aunque supongo que debería...

Saludos.

[xorc]

Hola amigos del club delphi:
Hace tiempo que programo en este lenguaje tan genial y ahora tengo un problema algo parecido a lo que tratan en este foro, y al no haber visto la manera de ingresar un nuevo tema (no me acuerdo como se hacia) recurro a ustedes de esta manera, espero que me disculpen la intromisión:
El problema que tengo es el siguiente:

Tengo un procedimiento implementado que hace parpadear un componente tcombobox, y lo hice de la siguiente manera:

Código Delphi [-]
Procedure TForm1.Parpadear(Sender:TControl;color1:TColor);
var colorinicial:tcolor;
Begin
  if sender is TComboBox then 
  Begin //solo sucede si el parametro sender es un TcomboBox
    with sender as Tcombobox do
    Begin
      colorinicial:=color;
      color:=color1; update; Sleep(100); 
      color:=colorinicial; Update; 
    End;
  End;
End;

A este procedimieto lo llamo desde otro lado del programa por ejemplo así:
parpadear(Combobox1,clyellow); //aqui ComboBox1 es un TComboBox
lo que hace parpadear color amarillo al combobox1 que esta en mi forma;
hasta aqui todo funciona ok, pero también tengo otro tipo de componentes, tipo tedit, tcurrentedit, tmemo, etc., en mi forma y para que cada uno parpadee según el caso debo copiar exactamente el codigo anterior, variando simplemente las líneas de
if sender is TComboBox then //y
with sender as TCombobox
reemplazando el tipo con lo que corresponda al paramentro enviado.
He intentado eliminar la linea de "if" y utilizar la siguiente forma:
With sender as sender.ClassType do
pero aunque no provoca error, tampoco se logra visualizar el efecto deseado (el componente parametro no cambia de color).

PREGUNTA: ¿cómo puedo utilizar el procedimiento parpadear, en todos los componentes sin tener que aplicar polimorfismo propiamente dicho? (sin sobrecargar el procedimiento parpadear ni repetir el resto del código para cada clase de objeto que sea descendiente de tcontrol).

Si a alguien se le ocurre alguna forma de que la línea de codigo With sender as sender.ClassType do funcione como deberia, por favor le agradeceria que me de luces.
Mil gracias.

[Casimiro Noteví]

Recuerda poner los tags al código fuente, ejemplo:



Gracias

[ecfisa]

Hola xorc.

Primero te comento que estas líneas son redundantes:

Código Delphi [-]
  if sender is TComboBox then   // Es un TComboBox.
  begin 
    with sender as Tcombobox do //  ¿ Para que ?, si ya sabemos que es un TComboBox

Mejor sería:

Código Delphi [-]
  if Sender is TComboBox then  // Es un TComboBox.
  begin
    with TComboBox(Sender) do  // con el TComboBox hacer
    ...

Ahora, para que el procedimiento se le pueda aplicar a diferentes controls yo usaría RTTI:

Código Delphi [-]
...
uses TypInfo;

procedure TForm1.Parpadear(AHandle: THandle; AColor: string);
var
  Aux: TColor;
  TC: TControl;
  PInfo: PPropInfo;
begin
  TC:= FindControl(AHandle);
  PInfo:= GetPropInfo(TC.ClassType, 'Color');
  if PInfo <> nil then
  begin
    Aux:= GetOrdProp(TC, 'Color');
    SetOrdProp(TC, PInfo, StringToColor(AColor));
    Update;
    Sleep(100);
    SetOrdProp(TC, PInfo, Aux);
    Update;
  end;
end;

Ejemplo de llamadas:

Código Delphi [-]
...
  Parpadear(Panel1.Handle, 'clRed');
  Parpadear(ComboBox1.Handle, 'clLime');
  Parpadear(Edit1.Handle,'clBlue');
...

Saludos.

[xorc]

Excelente!!!.
ecfisa, es precisamente lo que estaba tratando de hacer.
No conocia lo del RTTI pero me acabas de abrir los ojos hacia una funcion que me será utili en muchas otras funciones. Gracias y sigan ayudando a los que consultamos.