richedit

[[José Luis Garcí]]

Busca en el foro y encontraras una funcion para justificar en Richedit, yoo trabajo con ella si no la encuentras, dimelo y te la busco en casa, por cierto si no recuerdo mal tambien es posible cambiar el color de fondo de una parte del texto por si quieres destacar algo.

[yossi]

encontre esta funcion aca en el foro, no se si te refieres a esta que mencionan en este hilo
http://www.clubdelphi.com/foros/showthread.php?t=162

tambien encontre en otro hilo que mencionaban un componente "justifyrichedit"
lo descargue de aqui http://www.programmersheaven.com/dow.../download.aspx
para justificar funciona, tengo que probar las demas opciones

[yossi]

el componente "justifyrichedit" es un richedit pero con la opcion de justificar el texto. ese problema ya esta resuelto gracias al foro y a ustedes

pero ahora tengo otra dificultad dentro de la misma

tengo un boton mediante el cual el texto seleccionado se coloca en negrita, igualmente ento botones para el subrayado, hacer que el texto se coloque en negrita o en subrayado ya lo hice, el problema esta en quitarle la negrita a un texto sin quitarle el subrayado, no hallo la manera de acceder a la propiedad fsbold del style directamente para colocarlo en false y asi mantener el subrayado.

alguna idea?

[ecfisa]

Hola yossi.

Si utilizas un TButton podrías usar algo como este código:

procedure TForm1.btNegritaClick(Sender: TObject);
begin
  with RichEdit1.SelAttributes do
    if fsBold in Style then
      Style:= Style - [fsBold]
    else
      Style:= Style + [fsBold];
end;

Pero al hacer click sobre el TButton, perdes la selección del texto al perder el foco.
Mejor sería usar un TPopupMenu con los items: Negrita, Subrayado e Itálica. Asignar el
PopupMenu al TRichEdit y poner en el evento OnClick del TMenuItem lo siguiente:

procedure TForm1.Negrita1Click(Sender: TObject);
begin
   Negrita1.Checked := not Negrita1.Checked;
   with RichEdit1.SelAttributes do
     if Negrita1.Checked then
      Style:= Style + [fsBold]
     else
      Style:= Style - [fsBold];
end;

ahora te quedará la selección.

Tendrías que hacer lo mismo con Subrayado e Itálica. ([fsUnderline], [fsItalic])

Saludos.

[Mystery]

Hola foro....
bueno yo trabajo con el delphi 6 y en los demos viene un buen ejemplo de trabajo con RichEdit... no se si en otras versiones de delphi aparece este demo...
bueno sin mas
Mystery

[[José Luis Garcí]]

Te pongo el código que uso para lo siguiente

Código Delphi [-]

procedure TFprincipal.ColorBox2Click(Sender: TObject);
//-------------------------------------------------------------------------------
//***********************************************[color del fondo]****
//-------------------------------------------------------------------------------
var
  Format: CHARFORMAT2;
begin
  FillChar(Format, SizeOf(Format), 0);
  with Format do
  begin
    cbSize := SizeOf(Format);
    dwMask := CFM_BACKCOLOR;
    crBackColor := ColorBox2.Selected;
    redtrededitcion.Perform(EM_SETCHARFORMAT, SCF_SELECTION, Longint(@Format));
  end;
end;

procedure TFprincipal.ColorBox1Click(Sender: TObject);
//-------------------------------------------------------------------------------
//*****************************************************[ELEGIMOS COLOR texto]****
//-------------------------------------------------------------------------------
begin
redtrededitcion.SelAttributes.Color := ColorBox1.Selected;
end;

procedure TFprincipal.btn5Click(Sender: TObject);
//-----------------------------------------------------------------------------
//**************************************************[ Justificar Texto  ]******
//-----------------------------------------------------------------------------
begin
   if Length(redtrededitcion.selText)>0 then JustifyRichEdit(redtrededitcion,FAlse)
                                        else JustifyRichEdit(redtrededitcion,True);
end;


// AllText : True=todo o texto; False=parágrafo atual
procedure JustifyRichEdit(RichEdit :TRichEdit; AllText :Boolean);
const
  TO_ADVANCEDTYPOGRAPHY   = $1;
  EM_SETTYPOGRAPHYOPTIONS = (WM_USER + 202);
  EM_GETTYPOGRAPHYOPTIONS = (WM_USER + 203);
var
  ParaFormat :TParaFormat;
  SelStart,
  SelLength :Integer;
begin
  ParaFormat.cbSize := SizeOf(ParaFormat);
  if SendMessage(RichEdit.handle,
              EM_SETTYPOGRAPHYOPTIONS,
              TO_ADVANCEDTYPOGRAPHY,
              TO_ADVANCEDTYPOGRAPHY) = 1 then
  begin
    SelStart := RichEdit.SelStart;
    SelLength := RichEdit.SelLength;
    if AllText then
      RichEdit.SelectAll;
    ParaFormat.dwMask := PFM_ALIGNMENT;
    ParaFormat.wAlignment := PFA_JUSTIFY;
    SendMessage(RichEdit.handle, EM_SETPARAFORMAT, 0, LongInt(@ParaFormat));
// Restaura seleção caso tenhamos mudado para All
    RichEdit.SelStart := SelStart;
    RichEdit.SelLength := SelLength;
  end;
end;

procedure TFprincipal.ColorBox3Change(Sender: TObject);
//-----------------------------------------------------------------------------
//*****************************************[ Color de Fondo del Editor  ]******
//-----------------------------------------------------------------------------
begin
   redtrededitcion.Color:=ColorBox3.Selected;
end;

Espero os sirva

[ecfisa]

Hola José Luis.

Yo también tenía por algún lado esa rutina ... y buscando la encontré.

Y como suelo copiar y pegar las url, la saque de aqui :http://www.swissdelphicenter.ch/en/showcode.php?id=1438

Como detalle, agrego que hay que agregar

uses RichEdit;

si no, va a arrojar errores de identificador desconocido con: CHARFORMAT2, cbSize, ...

Saludos.