exportar a word

[crack_neon]

Hola un saludo,

Andaba buscando algo como esto, ya probé el ejemplo y definitivamente funciona, pero el detalle está en que yo necesito abrir las consultas en un documento que ya ha sido creado y posicionar los datos en un área específica del documento, es como se ha preguntado en otros hilos, tener una plantilla y solo modificar los datos que traemos de la bd.

La verdad que ya vi opciones pero ninguna me ayuda mucho tambien pensaba exportar de QReport a word, pero igual siento que mucho mas complicado y hay un hilo donde Marcozorrilla decia que no se podia, asi que me olvido de esa alternativa.

Creo que esta forma de pasar los datos es la mejor, solo necesito saber como enviarlos a un archivo ya creado.

Hojala me pueda dar una idea estimado roman.

De antemano gracias...como siempre confiando en los expertos.

[rafita]

Hola compañeros
Yo aporto un trozo de código donde se abre un documento de word existente (como requiere Crack-neon) y sustituyo un "Marcador" del documento y después añado unos datos en columnas (mediante tabuladores). Al final de código intentaba convertir ese trozo del documento en una tabla, pero como me fallaba lo he borrado (y le he explicado al usuario como puede hacerlo él desde word.

Código Delphi [-]
 
procedure TFConsultas.GenerarDocumentoWord;
var Fichero, SoloLectura, SalvarCambios, FormatoOriginal, Ruta, Marcador, Contenido : OleVariant;
    MiDocumento : _document;
 begin
  // Conexión con Word
  try
    MiWord.Connect;
  except
    ShowMessage('WordXP (o posterior) no está instalado en este equipo');
    Abort;
  end;
  // selección del documento base
  Fichero:='Z:\Informatica\delphi\Bomberos-Personal\Informe de un día.doc';
  // abrir el documento seleccionado con los parámetros necesarios
  SoloLectura:=True;
  MiDocumento:=MiWord.Documents.Open(Fichero, EmptyParam, SoloLectura,
               EmptyParam, EmptyParam, EmptyParam, EmptyParam, EmptyParam, EmptyParam,
               EmptyParam, EmptyParam, EmptyParam, EmptyParam, EmptyParam, EmptyParam);
  // sustituir el marcador de la fecha
  Marcador:='FechaTitulo';
  Contenido:=FechaLiteral(Label2.Caption);
  if MiDocumento.Bookmarks.Exists(Marcador) then MiDocumento.Bookmarks.Item(Marcador).Range.InsertBefore(Contenido);
  // insertamos los campos de la consulta en la tabla
  MiDocumento.Paragraphs.Last.Range.Font.Size:=12;
  ADOQuery1.First;
   if ADOQuery1.RecordCount>0 then
     While Not ADOQuery1.Eof do
     begin
       MiDocumento.Paragraphs.Last.Range.Text:=ADOQuery1.FieldByName('Apellidos').AsString+', '+ADOQuery1.FieldByName('Nombre').AsString+#9
       +ADOQuery1.FieldByName('Categoria').AsString+#9
       +wManiobras+wHorasExtras+wReduccion+wDiaLibre+wBaja+#9
       +ADOQuery1.FieldByName('Observaciones').AsString+#13;
       ADOQuery1.Next;
     end;
  // aquí habría que seleccionar el trozo de documento y convertirlo en tabla, pero como ya he dicho, no lo h conseguido
  // maximizamos la ventana de Word y desconectamos
  MiWord.WindowState:=wdWindowStateMaximize;
  MiWord.ActiveWindow.WindowState:=wdWindowStateMaximize;
  MiWord.PrintPreview;
  MiWord.Visible:=True;
  SalvarCambios:=wdDoNotSaveChanges;
  FormatoOriginal:=unAssigned;
  Ruta:=unAssigned;
  try
    MiWord.Disconnect;
  except
    on e:Exception do
    begin
      ShowMessage('Se ha producido el error '+e.Message);
      MiWord.Disconnect;
    end;
  end;
end;

Espero te sirva para algo.
Saludos

[crack_neon]

Gracias rafita, justo lo que buscaba, ya terminé de implementar el código y todo salio a la perfección.

Otro problema resuelto.

Saludos nuevamente.