Encriptar imágenes

[roman]

Yo aquí preparándome para la cena de noche buena. Mientras tanto, y viendo que anda por aquí seoane, aprovecho para preguntar ¿cómo se puede encriptar una imágen? No se trata sólo de encriptar el fichero sino de obtener otra imágen válida pero irreconocible.

La idea sería meter ruido en una imagen, como cuando en la tele ocultan un rostro, pero que se pueda recuperar la imagen original conociendo alguna clave o algo.

No se apuren en contestar que esto no es algo que necesite, sólo algo que tengo curiosidad.

// Saludos

[[seoane]]

Esta bien que se acuerden de uno.

El problema no es encriptar la imagen, si no la compresión. Manipular una imagen y guardarla como bmp, para luego recuperar los datos originales, es algo sencillo. También los seria para otros formatos de compresión como gif, tif o png, donde durante el proceso de compresión no se pierde información de la imagen original. Pero por ejemplo con el formato jpeg, la cosa cambia, en el proceso de compresión se pierde parte de la información de la imagen original, así que cuando quisiéramos deshacer la manipulación y volver a la primera imagen, no conseguiríamos un buen resultado. La imagen se recompondría pero parecerían multitud de puntitos multicolor molestando

Ahora vamos con un poco de codigo:

Código Delphi [-]
type
  Triple = array[1..3]of Byte;

procedure Cifrar(Imagen: TPicture; Clave: Longint);
var
  Bitmap: TBitmap;
  P: ^Triple;
  i, j: Integer;
begin
  RandSeed:= Clave;
  if not (Imagen.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Width:= Imagen.Width;
      Bitmap.Height:= Imagen.Height;
      Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
      Imagen.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
  Imagen.Bitmap.PixelFormat:= pf24bit;
  for j:= 0 to Imagen.Bitmap.Height - 1 do
  begin
    P:= Imagen.Bitmap.ScanLine[j];
    for i:= 0 to Imagen.Bitmap.Width - 1 do
    begin
      P^[1]:= P^[1] xor Byte(Random(256));
      P^[2]:= P^[2] xor Byte(Random(256));;
      P^[3]:= P^[3] xor Byte(Random(256));
      inc(P);
    end;
  end;
end;

// Por ejemplo
  Cifrar(Image1.Picture,1978);
  Image1.Refresh;

En la función anterior usamos un simple cifrado XOR sobre los pixeles. EL resultado es un montón de pixeles multicolor que no se parecen en nada a la imagen original. Para obtener la imagen original solo tenemos que volver a realizar la misma operación porque como ya sabrás (a xor b) xor b = a

También podemos superponer una imagen sobre otra, esto lo explico aquí:
http://www.clubdelphi.com/foros/showthread.php?t=35371

Y ahora se me ocurre, que podríamos hacer una codificación similar a la que usan algunos canales de televisión de pago. Cambian el orden de las lineas horizontales, dejando una imagen en la que a veces se puede intuir lo que pasa, pero prácticamente irreconocible. Alguno se quedo ciego intentando ver los partidos de fútbol gratis

Este ultimo método lo dejo para mas tarde, porque no consigo resolver un problema al copiar las lineas horizontales que hace que el proceso sea muy lento, y además me están llamando para cenar

FELIZ NAVIDAD A TODOS !!!

[[seoane]]

Bueno, como decía antes, en este otro algoritmo desordenamos las lineas. Se diferencia de los anteriores es que toda la información sigue ahí, así que funciones como el histograma devolverían el mismo resultado en la imagen original y en la encriptada. La desventaja es que al igual que hacen los decodificadores pirata de televisión, aplicando un análisis estadístico se puede llegar a recomponer la imagen, aun sin saber la contraseña.

Código Delphi [-]
procedure Cifrar(Imagen: TPicture; Clave: Longint);
var
  Bitmap: TBitmap;
  P1, P2: ^Triple;
  i, j, k: Integer;
  Temp: Triple;
  Sec: Array of Integer;
begin
  RandSeed:= Clave;
  if not (Imagen.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Width:= Imagen.Width;
      Bitmap.Height:= Imagen.Height;
      Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
      Imagen.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
  Imagen.Bitmap.PixelFormat:= pf24bit;
  SetLength(Sec,Imagen.Bitmap.Height div 2);
  for i:= 0 to High(Sec) do
    Sec[i]:= Length(Sec) + i;
  for i:= 0 to High(Sec) do
  begin
    k:= Sec[i];
    j:= Random(High(Sec));
    Sec[i]:= Sec[j];
    Sec[j]:= k;
  end;
  for j:= 0 to High(Sec) do
  begin
    P1:= Imagen.Bitmap.ScanLine[j];
    P2:= Imagen.Bitmap.ScanLine[Sec[j]];
    for i:= 0 to Imagen.Bitmap.Width - 1 do
    begin
      Temp:= P1^;
      P1^:= P2^;
      P2^:= Temp;
      inc(P1); inc(P2);
    end;
  end;
end;

// El ejemplo de siempre
  Cifrar(Image1.Picture,1978);
  Image1.Refresh;

[[seoane]]

Ya solo nos queda aplicar otra vuelta de tuerca, y limitar el cifrado a un recuadro de la imagen, por ejemplo, para taparle la cara a alguien en una foto:

Código Delphi [-]
type
  Triple = array[1..3]of Byte;

procedure Cifrar(Imagen: TPicture; R: TRect; Clave: Longint);
var
  Bitmap: TBitmap;
  P1, P2: ^Triple;
  i, j, k, H, W: Integer;
  Temp: Triple;
  Sec: Array of Integer;
begin
  RandSeed:= Clave;
  if not (Imagen.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Width:= Imagen.Width;
      Bitmap.Height:= Imagen.Height;
      Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
      Imagen.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
  Imagen.Bitmap.PixelFormat:= pf24bit;
  IntersectRect(R,R,Rect(0,0,Imagen.Bitmap.Width - 1,Imagen.Bitmap.Height - 1));
  H:= R.Bottom - R.Top;
  W:= R.Right - R.Left;
  SetLength(Sec,H div 2);
  for i:= 0 to High(Sec) do
    Sec[i]:= Length(Sec) + i;
  for i:= 0 to High(Sec) do
  begin
    k:= Sec[i];
    j:= Random(High(Sec));
    Sec[i]:= Sec[j];
    Sec[j]:= k;
  end;
  for j:= 0 to High(Sec) do
  begin
    P1:= Imagen.Bitmap.ScanLine[R.Top + j];
    P2:= Imagen.Bitmap.ScanLine[R.Top + Sec[j]];
    inc(P1,R.Left);
    inc(P2,R.Left);
    for i:= 0 to W - 1 do
    begin
      Temp:= P1^;
      P1^:= P2^;
      P2^:= Temp;
      inc(P1); inc(P2);
    end;
  end;
end;

// Por ejemplo
procedure TForm1.Button1Click(Sender: TObject);
begin
  // Por ejemplo
  Cifrar(Image1.Picture,Rect(100,100,200,200),1978);
  Image1.Refresh;
end;

Bueno, por ahora no se me ocurre nada mas, el siguiente paso seria aplicar algoritmos de criptografía fuerte (AES, Serpent, ...) para cifrar los puntos de la imagen en vez de usar un simple Random.

Roman, ya me contaras si esto se ajusta a lo que buscabas, estabas pensando en otra cosa o incluso si necesitas ir mas allá.

[Casimiro Notevi]

Pero, hombre!!!, cena tranquilo, que se te va a atragantar el pavo y luego contesta, que no está bien estar en la cena con la familia y el portátil encima de la mesa

[[Delphius]]

Antes que nada, ¡Feliz año nuevo!....
Bueno, lo segundo: disculpen que me meta en el tema, pero pasaba por este hilo y me doy con algo que andaba buscando... encriptacion de imagenes. Y a lo mejor aqui puedan guiarme un poco.

Veran, ando hacienco un sistema de reconocimiento de caras a traves de imágenes (algo sencillo) como tema de tesis (mejor dicho Proyecto de Grado) y buscando técnicas de seguridad estaba implementando algoritmos de encriptación al estilo XOR como muestra el maestro Seoane. Tengo entendido, y no debo ser el único (espero..), que la "encriptación XOR" es débil. La verdad es que necesitaría una guia seria, didactica, tanto teórica como práctica sobre criptagrafia y encriptacion. Yo ya habia visitado algunos links hace un año (por curioso) y aprendi algo... pero no eran "serio" y se limitaban al texto. Yo necesitaria algo más cercano a la imagen.

Bueno... lo que necesito es fuente bibliográfica sobre este tema (encriptación). Ya sean links o si alguno conoce algún libro (y que sea un poco fàcil de encontrar...) le estaría agradecido. Preferiblemente libros... yo vería como lo adquiría, ya que no le gusta a la mesa examinadora ver demasiada bibliografia de la red...

Escucho recomendaciones.
Muchas gracias,

[[seoane]]

Empezado por Delphius

Tengo entendido, y no debo ser el único (espero..), que la "encriptación XOR" es débil

La encriptacion XOR no es que sea débil, lo que es débil es la función Random. Es una función que puede llegar a ser predecible, si utilizásemos una función capaz de generar secuencias de números menos predecibles la encriptacion seria segura. Pero estoy divagando ... tu preguntabas sobre libros sobre encriptacion, y en eso no puedo ayudarte, lo siento

De todas formas, ya metidos en el tema de tu proyecto. Me gustaría saber donde encaja la encriptacion dentro del mismo. Si el motivo es la seguridad, porque no utilizar alguno de los algoritmo probadamente seguros (por ahora) como AES, Serpent, etc y guardas los datos encriptados. Al algoritmo le da igual que se trate de imágenes, sonido o texto. Es verdad que las imágenes tienen el problema de contener grandes cantidades de datos iguales (el color de fondo, por ejemplo) lo que puede favorecer la aparición de patrones en los datos cifrados, pero supongo (y solo supongo, no soy matemático) que los algoritmos un poco serios no se ven afectados por esto.

Bueno, espero que alguien te pueda ayudar con esa bibliografía

[[Delphius]]

Empezado por seoane

Me gustaría saber donde encaja la encriptacion dentro del mismo. Si el motivo es la seguridad, porque no utilizar alguno de los algoritmo probadamente seguros (por ahora) como AES, Serpent, etc y guardas los datos encriptados.

Pues, asi es. Seguridad. Preferiría, no es una olbigación, que las imagenes que guarde el sistema (obvio... en una BD) estén comprimidas y encriptadas.

Algoritmos AES, Serpent... ok... gracias.. estaré viendo... uff.. tanta cosas que ando investigando a la vez... espero terminar.

Gracias,
Saludos,

[roman]

Empezado por Casimiro Notevi

Pero, hombre!!!, cena tranquilo, que se te va a atragantar el pavo y luego contesta, que no está bien estar en la cena con la familia y el portátil encima de la mesa

¡Caramba! La familia de Domingo ha de odiarme En mi defensa diré que desde un principio aclaré:

Empezado por roman

No se apuren en contestar que esto no es algo que necesite, sólo algo que tengo curiosidad.

Pero muchas gracias seoane, has satisfecho mi curiosidad y me pondré a jugar un rato con tu código; lo consideraré mi regalo de navidad

// Saludos