THTTPRIO.HTTPWebNode.ClientCertificate

[_Io]

Buenas tardes.

Cuando asigno un certificado mediante su número de serie, funciona bien:

Código Delphi [-]
PrioInt.HTTPWebNode.ClientCertificate.SerialNum:='xxxxxxxxxxxxxxxxxxxxxxxxx'

Pero si quiero asignarlo mediante un stream

Código Delphi [-]
  PrioInt.HTTPWebNode.ClientCertificate.Stream:=aStream;
  PrioInt.HTTPWebNode.ClientCertificate.Password:='123456';

Obtengo el siguiente error:

Error sending data: (12185) No había credenciales disponibles en el certificado de cliente

Y si intento hacerlo desde un archivo

Código Delphi [-]
PrioInt.HTTPWebNode.ClientCertificate.FileName:='c:\......\cert.pfx';
PrioInt.HTTPWebNode.ClientCertificate.Password:='123456';

Error opening certificate file: (-2146885629) Error al leer o escribir en un archivo

Aunque el archivo está perfectamente localizado.

Alguien carga el certificado mediante stream o filename sin pegas?

Muchas Gracias.

[Garada]

Mirando el código dónde se supone que usa la información del certificado (D12)

Código Delphi [-]
unit System.Net.HttpClient.Win;

...

procedure TWinHTTPRequest.SetWinCertificate;
var
  LStore: HCERTSTORE;
  LCertContext: PCCERT_CONTEXT;
  LBlob: CRYPT_DATA_BLOB;
  LBytes: TBytes;
begin
  if (FClientCertPath = '') and (FClientCertificate = nil) then
    Exit;

  if FClientCertPath <> '' then
    LStore := CertOpenStore(PAnsiChar(CERT_STORE_PROV_FILENAME), X509_ASN_ENCODING or PKCS_7_ASN_ENCODING,
      0, CERT_STORE_OPEN_EXISTING_FLAG or CERT_STORE_READONLY_FLAG, PChar(FClientCertPath))
  else
  begin
    LBlob.cbData := FClientCertificate.Size;
    SetLength(LBytes, LBlob.cbData);
    FClientCertificate.Position := 0;
    FClientCertificate.Read(LBytes, LBlob.cbData);
    LBlob.pbData := PByte(@LBytes[0]);
    LStore := PFXImportCertStore(@LBlob, PChar(FClientCertPassword), 0);
  end;
  if LStore = nil then
    raise ENetHTTPRequestException.CreateResFmt(@SNetHttpCertFileOpenError,
      [GetLastError, SysErrorMessage(GetLastError, TWinHttpLib.Handle)]);
  try
    LCertContext := nil;
    if CheckWin32Version(6, 2) then
      LCertContext := CertFindCertificateInStore(LStore, X509_ASN_ENCODING or PKCS_7_ASN_ENCODING,
        0, CERT_FIND_HAS_PRIVATE_KEY, nil, nil);
    if LCertContext = nil then
      LCertContext := CertFindCertificateInStore(LStore, X509_ASN_ENCODING or PKCS_7_ASN_ENCODING,
        0, CERT_FIND_ANY, nil, nil);
    if LCertContext = nil then
      raise ENetHTTPRequestException.CreateResFmt(@SNetHttpCertNotFoundError,
        [GetLastError, SysErrorMessage(GetLastError, TWinHttpLib.Handle)]);
    try
      WinHttpSetOption(FWRequest, WINHTTP_OPTION_CLIENT_CERT_CONTEXT,
        LCertContext, SizeOf(CERT_CONTEXT));
    finally
      CertFreeCertificateContext(LCertContext);
    end;
  finally
    CertCloseStore(LStore, 0);
  end;
end;

Si le pasas un nombre de fichero, no espera un PFX sino un fichero con un almacen de certificados (funcion CertOpenStore)
https://learn.microsoft.com/es-es/wi...-certopenstore
Mira los formatos que acepta en la ayuda

En cambio si pasas un Stream, sí que espera que sea un PFX. Ese debería de funcionarte.
Cosas que se me ocurren que porqué no va el stream, prueba a poner Position a cero antes de usarlo y revisa que estás grabando bien el PFX en el stream.

[_Io]

Buenos días.

Muchas gracias por tu respuesta.

He estado fuera y no te he podido responder antes.

Empezado por Garada

Mirando el código dónde se supone que usa la información del certificado (D12)
Si le pasas un nombre de fichero, no espera un PFX sino un fichero con un almacen de certificados (funcion CertOpenStore)
https://learn.microsoft.com/es-es/wi...-certopenstore
Mira los formatos que acepta en la ayuda

No Lo sabía, la ayuda en D12 sobre esto es nula, estaba equivocado

Empezado por Garada

En cambio si pasas un Stream, sí que espera que sea un PFX. Ese debería de funcionarte.
Cosas que se me ocurren que porqué no va el stream, prueba a poner Position a cero antes de usarlo y revisa que estás grabando bien el PFX en el stream.

En este caso, creo que lo hago bien, porque si lo utilizo en facturae (paso stream y password) funciona correctamente, pero utilizando los secure blackbox.
He hecho lo que me indicas de poner s 0 el Position y da el mismo error.

Muchas Gracias.

[Garada]

Acabo de hacer una prueba y funciona sin problemas.

He usado D12CE, el servicio de la AEAT para consultar los NIF, un archivo PFX generado por Windows y un TFileStream

El problema debe estar en otro lado.

Si responde "No había credenciales disponibles en el certificado de cliente" el PFX está mal montado y no tiene clave privada.
De hecho, he forzado errores como una contraseña errónea o un fichero que no es un PFX y los errores que devuelve explica claramente el fallo (contraseña errónea o formato incorrecto).

Si no das con el problema pon algo de código que a veces es un punto y coma mal puesto. 😉

[_Io]

Empezado por Garada

Acabo de hacer una prueba y funciona sin problemas.

He usado D12CE, el servicio de la AEAT para consultar los NIF, un archivo PFX generado por Windows y un TFileStream

El problema debe estar en otro lado.

Si responde "No había credenciales disponibles en el certificado de cliente" el PFX está mal montado y no tiene clave privada.
De hecho, he forzado errores como una contraseña errónea o un fichero que no es un PFX y los errores que devuelve explica claramente el fallo (contraseña errónea o formato incorrecto).

Si no das con el problema pon algo de código que a veces es un punto y coma mal puesto. 😉

Juerrr, que bien.

Ahora estoy liado pero en cuanto pueda por supuesto que lo pongo.

Muchas Gracias !!!!!

[_Io]

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
const
  CERTIFICATE ='D:\PROYECTOS\D12\04 VERI-FACTU\04 DOCUMENTOS\Cerificados\Pruebas AEAT\Certificado_RPJ_A39200019_CERTIFICADO_ENTIDAD_PRUEBAS_4_Pre.p12';
  PASSWORD = '1234';

var
  Nif :VNifV2;
  NifEnt :VNifV2Ent;
  NifSal :VNifV2Sal;
  PrioInt :THTTPRIO;
  Cert :TFileStream;
  j:integer;
begin

  // Cargamos Certificado
  Cert:=TFileStream.Create(CERTIFICATE,fmOpenRead);
  try

    // Configuramos comunicación con la AEAT
    PrioInt:=THTTPRIO.Create(nil);
    PrioInt.URL:='https://www1.agenciatributaria.gob.es/wlpl/BURT-JDIT/ws/VNifV2SOAP';
    PrioInt.HTTPWebNode.ClientCertificate.Stream:=Cert;
    PrioInt.HTTPWebNode.ClientCertificate.Password:=PASSWORD;
    Nif:=(PrioInt as VNifV2);

    // Preparamos consulta
    setlength(NifEnt,1);
    NifEnt[0]:=Contribuyente.Create;
    NifEnt[0].Nif:='**7242***';
    NifEnt[0].Nombre:='*O*E *AR**A G*L*C*A';

    // Lanzamos consulta
    NifSal:=Nif.VNifV2((NifEnt));

  // Cargamos respuesta
    for j:=0 to length(NifSal) -1 do
    begin

      if assigned(NifSal[j]) then
      begin

        memo2.Lines.Add(NifSal[j].Nif);
        memo2.Lines.Add(NifSal[j].Nombre);
        memo2.Lines.Add(NifSal[j].Resultado);

      end;

    end;

  finally

    Cert.Free;

  end;

end;

Buenos días.

El Certificado es uno de pruebas de la AEAT, lo utilizo en FACe y funciona bien.
Este código da el error Error sending data: (12185) No había credenciales disponibles en el certificado de cliente

Ya me dices si ves algo raro.

Muchas Gracias.