Grabar y leer datos desde un fichero

[Jere_84]

Disculpen gente, se que esto puede ser extremadamente simple pero estoy muy acostumbrado a trabajar con DataSet. Necesito hacer un ABM simple de Codigo, Nombre, Domicilio y Localidad de una persona trabajando con ficheros archivos.txt.
La verdad que nunca he trabajado de manera como le comente siempre utilizo BD relacionales. Saben en donde puedo tener ejemplos o alguna sugerencia rapida, ya que lo tengo que hacer en un par de horas.

Saludos y gracias por leer.

[Casimiro Notevi]

¿Es una broma?

[Jere_84]

Por supuesto que es una broma,feliz dia de los inocentes!

[Casimiro Notevi]

Falta mucho para el 28 de diciembre.
Entonces lo paso al foro de "humor".

[Jere_84]

Aclare que nunca utilice text file gracias igual por el sarcasmo pero estoy haciendo esto

Código Delphi [-]
  AssignFile(MiFichero, 'C:\Users\USUARIO\Desktop\Examen\Ejercicio2Delphi\Test.txt');
  ReWrite(MiFichero);

  ReadLn(MiFichero, Registro.Numero);
  ReadLn(MiFichero, Registro.Nombre);
  ReadLn(MiFichero, Registro.Sexo);
  ReadLn(MiFichero, Registro.Domicilio);
  ReadLn(MiFichero, Registro.Localidad);

Lo que necesito es recorrer el text file linea por linea.. como es la forma mas optima?

[Jere_84]

Recorrerlo como si fuera un DataSet con Next y Prior

[ecfisa]

Hola Jere_84.

Si es un archivo de Texto no podes usar un registro, al menos del modo que lo estas usando con el procedimiento Readln.

Te hice un ejemplo rápido, sin mucho detalle (y que no funciona), tal como se esperaría en este foro .

Bueno, ahora en serio...

Código Delphi [-]
program Project2; {$APPTYPE CONSOLE}

uses
  SysUtils;

const
  PATH = 'C:\tmp\';
  SPC30 = '                              ';
var
  arch: Text;

procedure Initialize;
begin
  AssignFile (arch, PATH + 'ABM.TXT' );
  try
    Reset(arch);
  except
    Rewrite(arch);
  end;
  CloseFile (arch);
end;

function ExistsCode(const cod: string): Boolean;
var
  str: string;
begin
  Result := False;
  Reset ( arch );
  while not Eof ( arch ) and not Result do
  begin
    Readln ( arch, str );
    Result := Copy ( str, 1, 4 ) =  cod;
  end;
  CloseFile ( arch );
end;

procedure ReadCode(var cod: string);
begin
  Write('Codigo: ');
  Readln(cod);
  cod := Copy('0000', 1, 4 - Length(cod)) + cod;
end;

procedure ReadRest(var nom, dom, loc: string);
begin
  Write('Nombre: ');
  Readln(nom);
  Write('Domicilio: ');
  Readln(dom);
  Write('Localidad: ');
  Readln(loc);
  nom := nom + Copy(SPC30, 1, 30-Length(nom));
  dom := dom + Copy(SPC30, 1, 30-Length(dom));
  loc := loc + Copy(SPC30, 1, 30-Length(loc));
end;

procedure AddLine;
var
  cod, nom, dom, loc: string;
begin
  ReadCode ( cod );
  if not ExistsCode(cod) then
  begin
    ReadRest ( nom, dom, loc );
    Append ( arch );
    Writeln( arch, cod + nom + dom + loc );
    Close ( arch );
  end;
end;

procedure ModifyLine;
var
  aux: Text;
  cod, nom, dom, loc, str: string;
begin
  ReadCode ( cod );
  if (cod <> '') and ExistsCode ( cod ) then
  begin
    ReadRest(nom, dom, loc);
    Assign ( aux, PATH + 'AUXILIAR.TXT');
    Rewrite ( aux );
    Reset ( arch );
    while not Eof ( arch ) do
    begin
      Readln ( arch, str );
      if Copy(str, 1, 4) = cod then
        Writeln( aux, cod + nom + dom + loc )
      else
        Writeln( aux, str );
    end;
    CloseFile( arch );
    CloseFile ( aux );
    Erase ( arch );
    Rename ( aux, PATH + 'ABM.TXT' );
  end;
end;

procedure DeleteLine;
var
  aux: Text;
  cod, str: string;
begin
  ReadCode ( cod );
  if (cod <> '') and ExistsCode ( cod ) then
  begin
    Assign ( aux, PATH + 'AUXILIAR.TXT');
    Rewrite ( aux );
    Reset ( arch );
    while not Eof ( arch ) do
    begin
      Readln ( arch, str );
      if Copy(str, 1, 4) <> cod then
        Writeln( aux, str );
    end;
    CloseFile ( arch );
    CloseFile ( aux );
    Erase ( arch );
    Rename ( aux, PATH + 'ABM.TXT' );
  end;
end;

procedure ListLines;
var
  str: string;
begin
  Reset ( arch );
  while not Eof ( arch ) do
  begin
    Readln( arch, str);
    Writeln ( str);
  end;
  CloseFile ( arch );
end;


var
  op: Integer;
begin
  Initialize;
  repeat
    Writeln ( '-----------------' );
    Writeln ( '1.- Agregar linea' );
    Writeln ( '2.- Modificar linea' );
    Writeln ( '3.- Borrar linea' );
    Writeln ( '4.- Listar lineas' );
    Writeln ( '5.- Terminar' );
    Writeln ( '-----------------' );

    repeat
      op := 0;
      Readln(op);
    until op in [1..5];

    Writeln;
    case op of
      1: AddLine;
      2: ModifyLine;
      3: DeleteLine;
      4: ListLines;
    end;
    Writeln;
  until op = 5;
end.

Se puede simplificar usando otras librerias, pero lo hice ajustándome a las funciones y procedimientos estandar Pascal.

Saludos

[[AgustinOrtu]]

Y porque tenes que trabajar con un .txt? Para evitar instalar un RDBMS?

No podes usar firebird embedded?

O SQlite?

[Jere_84]

Es un examen laboral para una empresa, es todo por Internet. Se que un txt es algo simple pero nunca ni me puse a hacer un ABM con archivos .txt. Es mas en los tutoriales que he leído como la cara oculta cuando veía que explicaban en .txt ni lo leía porque es algo viejo de antaño!
Igual ya me puse y es fácil pero es laburar al pedo! perdón por la expresión

[ecfisa]

Hola Jere_84.

Empezado por Jere_84

Es un examen laboral para una empresa, es todo por Internet. Se que un txt es algo simple pero nunca ni me puse a hacer un ABM con archivos .txt.

En realidad no es tan así, el ejemplo que te hice es simplicísimo. Hacer un ABM que funcione decentemente con un archivo de texto, en ningún caso es mas eficiente que hacerlo mediante un SGDB, pero tampoco menos complejo.

ni lo leía porque es algo viejo de antaño!

Cierto , desde la facultad que no usaba esas funciones (tuve que recurrír al F1 en mas de una ocasión).

...
pero es laburar al pedo! perdón por la expresión.

Bueno depende como se mire. Si de eso depende conseguir el trabajo o no...

Saludos

[[AgustinOrtu]]

Realmente trabajar con archivos de texto para diseñar un ABM en el 2015...

Y que pasa si guardas la informacion como si fueran registros. Que el archivo de texto te quede asi, literalmente

Código Delphi [-]
FILESTART: PERSONAS
Codigo: ABC123
Nombre: Pepe
Domicilio: Calle 123
Localidad: Una ciudad
# // o alguna marca que se te ocurra como "separadora de registro"
Codigo: DEF456
Nombre: Carlos
Domicilio: Calle 456
Localidad: Otra ciudad
#
FILEEND

Podes laburar con un TStringList? Sino con el Readln y Writeln tambien puede servir, pero me gusta mas TStringList.
Vas leyendo hasta FILEEND, y en cada "#" significa que cambiaste de persona y ya tenes sus datos. Yo los cargaria en un tipo Record para que al menos tengas una estructura en la que puedas acceder por campo.

Desde una lista o array manejar la informacion creo que es mucho mas comodo que el archivo, tomalo como estas usando una transaccion, y el commit seria usar como indice los campos "inicio" y "fin" y grabar ahi los cambios


Saludos

[[nlsgarcia]]

Jere_84,

Empezado por Jere_84

...Necesito hacer un ABM simple de Codigo, Nombre, Domicilio y Localidad de una persona trabajando con ficheros archivos.txt...

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    edtCodigo: TEdit;
    edtNombre: TEdit;
    edtDomicilio: TEdit;
    edtLocalidad: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button8: TButton;
    ListBox1: TListBox;
    Label5: TLabel;
    Button7: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button7Click(Sender: TObject);
    procedure Button8Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TData = record
     Codigo : Array[0..9] of Char;
     Nombre : Array[0..29] of Char;
     Domicilio : Array[0..29] of Char;
     Localidad : Array[0..29] of Char;
     CRLF : Array[0..1] of Char;
  end;

var
  Form1: TForm1;
  F : TFileStream;
  RegData : TData;
  FileName : String = 'FileData.txt';
  PosReg : Integer;
  FoundReg : Boolean;

implementation

{$R *.dfm}

// Inicializa App
procedure TForm1.FormCreate(Sender: TObject);
begin
   edtCodigo.MaxLength := 10;
   edtNombre.MaxLength := 30;
   edtDomicilio.MaxLength := 30;
   edtLocalidad.MaxLength := 30;
end;

// Adiciona un Registro
procedure TForm1.Button1Click(Sender: TObject);
begin

   if FileExists(FileName) then
   begin
      F := TFileStream.Create(FileName, fmOpenWrite, fmShareExclusive);
      F.Position := F.Size;
   end
   else
      F := TFileStream.Create(FileName, fmCreate, fmShareExclusive);

   StrPCopy(RegData.Codigo,Format('%-10s',[edtCodigo.Text]));
   StrPCopy(RegData.Nombre,Format('%-30s',[edtNombre.Text]));
   StrPCopy(RegData.Domicilio,Format('%-30s',[edtDomicilio.Text]));
   StrPCopy(RegData.Localidad,Format('%-30s',[edtLocalidad.Text]));
   RegData.CRLF := #13#10;

   F.Write(RegData, SizeOf(RegData));

   F.Free;

end;

// Consulta un Registro
procedure TForm1.Button2Click(Sender: TObject);
var
   Codigo : String;

begin

   if FileExists(FileName) then
   begin

      Codigo := InputBox('Código a Consultar', 'Código', '1');

      F := TFileStream.Create(FileName, fmOpenRead, fmShareDenyNone);

      FoundReg := False;

      while F.Position < F.Size do
      begin
         F.Read(RegData, SizeOf(RegData));
         if Trim(RegData.Codigo) = Trim(Codigo) then
         begin
            edtCodigo.Text := Trim(RegData.Codigo);
            edtNombre.Text := Trim(RegData.Nombre);
            edtDomicilio.Text := Trim(RegData.Domicilio);
            edtLocalidad.Text := Trim(RegData.Localidad);
            PosReg := F.Position - SizeOf(RegData);
            FoundReg := True;
            Break;
         end;
      end;

      if not FoundReg then
         MessageDlg('No Existe el Registro Solicitado',mtInformation,[mbOk],0);

      F.Free;

   end
   else
      MessageDlg('El Archivo de Datos No Existe',mtInformation,[mbOk],0);

end;

// Actualiza un Registro
procedure TForm1.Button3Click(Sender: TObject);
begin

   if FileExists(FileName) then
   begin

      if not FoundReg then
      begin
         MessageDlg('No Se ha Buscado Ningún Registro para Actualizar',mtInformation,[mbOk],0);
         Exit;
      end;

      F := TFileStream.Create(FileName, fmOpenWrite, fmShareExclusive);
      F.Seek(PosReg, soFromBeginning);

      StrPCopy(RegData.Codigo,Format('%-10s',[edtCodigo.Text]));
      StrPCopy(RegData.Nombre,Format('%-30s',[edtNombre.Text]));
      StrPCopy(RegData.Domicilio,Format('%-30s',[edtDomicilio.Text]));
      StrPCopy(RegData.Localidad,Format('%-30s',[edtLocalidad.Text]));
      RegData.CRLF := #13#10;

      F.Write(RegData, SizeOf(RegData));

      F.Free;

      MessageDlg('Registro Actualizado',mtInformation,[mbOk],0);

   end
   else
      MessageDlg('El Archivo de Datos No Existe',mtInformation,[mbOk],0);

   FoundReg := False;

end;

// Elimina un Registro
procedure TForm1.Button4Click(Sender: TObject);
begin

   if FileExists(FileName) then
   begin

      if not FoundReg then
      begin
         MessageDlg('No Se ha Buscado Ningún Registro para Eliminar',mtInformation,[mbOk],0);
         Exit;
      end;

      F := TFileStream.Create(FileName, fmOpenWrite, fmShareExclusive);
      F.Seek(PosReg, soFromBeginning);

      StrPCopy(RegData.Codigo,Format('%-10s',[EmptyStr]));
      StrPCopy(RegData.Nombre,Format('%-30s',[EmptyStr]));
      StrPCopy(RegData.Domicilio,Format('%-30s',[EmptyStr]));
      StrPCopy(RegData.Localidad,Format('%-30s',[EmptyStr]));
      RegData.CRLF := #13#10;

      F.Write(RegData, SizeOf(RegData));

      F.Free;

      MessageDlg('Registro Eliminado',mtInformation,[mbOk],0);

   end
   else
      MessageDlg('El Archivo de Datos No Existe',mtInformation,[mbOk],0);

   FoundReg := False;

end;

// Consulta Global de Registros
procedure TForm1.Button5Click(Sender: TObject);
begin

   if FileExists(FileName) then
   begin

      ListBox1.Clear;

      F := TFileStream.Create(FileName, fmOpenRead, fmShareDenyNone);

      while F.Position < F.Size do
      begin
         F.Read(RegData, SizeOf(RegData));
         if Trim(RegData.Codigo) <> EmptyStr then
         begin
            ListBox1.Items.Add(Trim(RegData.Codigo) + ' ' +
                               Trim(RegData.Nombre) + ' ' +
                               Trim(RegData.Domicilio) + ' ' +
                               Trim(RegData.Localidad)
                              );
         end;
      end;

      F.Free;

   end
   else
      MessageDlg('El Archivo de Datos No Existe',mtInformation,[mbOk],0);

end;

// Elimina el Archivo de Disco
procedure TForm1.Button6Click(Sender: TObject);
begin
   if FileExists(FileName) then
      DeleteFile(FileName);
end;

// Elimina los Registros Eliminados (Registros en Blanco)
procedure TForm1.Button7Click(Sender: TObject);
var
   TFileName : String;
   T : TFileStream;

begin

    if not FileExists(FileName) then
       Exit;

    TFileName := 'FileName.tmp';

    F := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
    T := TFileStream.Create(TFileName, fmCreate or fmShareDenyNone);

    while F.Position < F.Size do
    begin
       F.Read(RegData, SizeOf(RegData));
       if Trim(RegData.Codigo) <> EmptyStr then
          T.Write(RegData, SizeOf(RegData));
    end;

    T.Free;
    F.Free;

    DeleteFile(FileName);
    RenameFile(TFileName,FileName);

end;

// Reset Form
procedure TForm1.Button8Click(Sender: TObject);
var
   i : Integer;

begin

   for i := 0 to ComponentCount - 1 do
      if Components[i] is TEdit then
         TEdit(Components[i]).Text := EmptyStr;

end;

end.

El código anterior en Delphi 7 sobre Windows 7 Professional x32, Implementa un ABM rudimentario basado en TextFile, como se muestra en la siguiente imagen:



Nota :

1- La aplicación permite códigos duplicados, los cuales se pueden evitar por medio de una función de chequeo previa a la adición.

2- No se implemento validación de campos, la idea era mostrar el uso de archivos de texto por medio de TFileStream.

3- El código del ejemplo esta disponible en : TextFile ABM.rar

Espero sea útil

Nelson.

[Neftali [Germán.Estévez]]

Empezado por Jere_84

Es un examen laboral para una empresa, es todo por Internet.

Como los de la Empresa visiten Clubdelphi va a ser divertido... o no.


Cargar datos de un TXT a un TDataset (utilizando ADO)
Cargar datos de un TXT a un TDataset (utilizando ADO) – Parte 2

[Jere_84]

Si espero que no sean usuarios de este foro jeje Bueno gracias por las respuestas la verdad que es muy útil el foro y es un muy lindo grupo el que hay acá.. viva delphi! jaja