[roman]

Hola, estuve revisando este tema. El problema con el método anterior es que el usuario podría tener abiertas otras instancias de la aplicación externa y no hay garantía de que FindWindow te regrese la ventana que tú abriste en lugar de otra.

Un método un poco más complicado consiste en abrir la aplicación directamente con CreateProcess para obtener el identificador del hilo de la aplicación:

Código Delphi [-]
{
  Abre la aplicación indicada en AppPath y
  devuelve el hilo de la nueva aplicación.
}
function ExecuteProcess(AppPath: String): Cardinal;
var
  StartInfo: TStartupInfo;
  ProcInfo: TProcessInformation;

begin
  FillChar(StartInfo, SizeOf(StartInfo), 0);
  StartInfo.cb := SizeOf(StartInfo);

  if not CreateProcess(
    PChar(AppPath), nil, nil, nil, false, 0, nil, nil, StartInfo, ProcInfo
  )
  then
    RaiseLastOSError;

  Result := ProcInfo.dwThreadId;
end;

Ahora la cuestión es obtener el identificador de la ventana principal asociada al hilo. El problema es que el concepto de ventana principal en realidad es poco claro. Hay aplicaciones, como Word, donde todas las ventanas abiertas son principales y simplemente la última en cerrarse es la que manda cerrar la aplicación.

De cualquier manera la siguiente función GetMainWindow que sigue te devolverá el identificador de la primera ventana que encuentre y que tenga "aspecto" de ser la principal:

Código Delphi [-]
function DoEnum(Handle: HWnd; Param: LParam): Bool; stdcall;
begin
  if
    IsWindowVisible(Handle)
    and IsWindowEnabled(Handle)
  then
  begin
    PInteger(Param)^:= Handle;
    Result := false;
  end
  else
    Result := true;
end;

{
  Recorre todas las ventanas principales asociadas
  al hilo hasta encontrar una que esté visible y activa.

  EnumThreadWindows llama a la función DoEnum para
  cada ventana encontrada.
}
function GetMainWindow(ThreadId: Cardinal): HWnd;
begin
  Result := 0;
  EnumThreadWindows(ThreadId, @DoEnum, Integer(Pointer(@Result)));
end;

Cuando quieras poner la aplicación como siempre visible usarías algo como

Código Delphi [-]
procedure MakeAppTopMost(ThreadId: Cardinal);
const
  Flags = SWP_NOMOVE or SWP_NOSIZE;

var
  WindowId: HWnd;

begin
  WindowId := GetMainWindow(ThreadId);

  BringWindowToTop(WindowId);
  if IsIconic(WindowId) then
    ShowWindow(WindowId, SW_RESTORE);

  SetWindowPos(WindowId, HWND_TOPMOST, 0, 0, 0, 0, Flags);
end;

pasándole el ThreadId obtenido con ExecuteProcess. La llamada a BringWindowToTop no parece ser necesaria para aplicaciones sencillas como el block de notas pero sí para aplicaciones como Word.

Posteriormente puedes usar el ThreadId obtenido para cerrar la aplicación externa:

Código Delphi [-]
procedure CloseApp(ThreadId: Cardinal);
var
  WindowId: HWnd;

begin
  WindowId := GetMainWindow(ThreadId);
  SendMessage(WindowId, WM_CLOSE, 0, 0);
end;

Nota que tanto MakeAppTopMost como CloseApp vuelven a calcular el identificador de ventana a partir del identificador de hilo. Esto es así porque el identificador de ventana puede cambiar a lo largo de la vida de la aplicación. Por ejemplo, en una aplicación hecha en Delphi, si durante la ejecución cambias el estilo del borde de la ventana, ésta se crea nuevamente dando un nuevo identificador. En cambio, el identificador de hilo permanece inmutable durante toda la ejecución de una aplicación.

// Saludos