Como declarar una función
 

Posiblemente para muchos de ustedes esta debe ser una pregunta muy estúpida pero bueno, la verdad que es una cosa que no logro entender del todo. Como hago para declarar una función, por ejemplo, esta de acá? Muchas gracias :)

Hola Juan_An, bienvenido a Club Delphi :)

Como a todos los que se inician te invitamos a que leas nuestra guía de estilo.

Declaración de una funcion:
Lo que no está en negrita es opciónal, un ejemplo de declaración (y definición) de función:

Código Delphi [-]
function Factorial(Num:Integer): Longint;
begin
  if Num = 1 then
    Result := 1
  else
    Result := num * Factorial(Num-1);
end;

El alcance (o scope) de las funciónes, al igual que el de las variables, depende de la posición y la sección en que se las declare.

Tomando en cuenta la posición y de forma somera, se podría decir que todo el código que está debajo de la definición de la función tiene acceso a la misma:

Código Delphi [-]
...
Procedure xyz(n:Integer); 
begin
  Factorial(n); // Error: Factorial no es visible para xyz
end;

function Factorial(Num:Integer): Longint;
begin
  if Num = 1 then
    Result := 1
  else
    Result := num * Factorial(Num-1);
end;

function zzz: Longint; 
begin
  Result := Factorial(5); // Correcto, Factorial visible para zzz
end;

El otro aspecto a tomar en cuenta, es si la declaración de la función se encuentra en la sección de interface(interfaz) o de implementation(implementación) estándo en una Unit (unidad).

Si está en la primera sección, es visible por cualquier codigo que esté por debajo de la inclusión de dicha unidad a su uses(uso):

Código Delphi [-]
unit Unit1;

interface
...

function Factorial(Num:Integer): Longint; // Conocida por quien use esta unidad

implementation

function Factorial(Num:Integer): Longint;
begin
  if Num = 1 then
    Result := 1
  else
    Result := num * Factorial(Num-1);
end;
end.
//---------------------------------------------------------------
program xxx;

uses ..., Unit1; // Inclusión 

begin
   Factorial(10); // Correcto
   ...

De otro modo, si la declaración no está incluída en la interface (y está definida en la sección de implementación), sólo puede ser usada dentro de propia unidad (siempre respetando la posición).

Si no he sido suficientemente claro, no dudes en volver a preguntar.

Saludos. :)

Juan_An,

Revisa estos links:
Espero sea útil :)

Nelson.

Don nlsgarcia...tirese un enlace ahora...:D