Realizar un "Post HTTP" con la clase "TIdHttp" de Indy
 

Realizar un "Post HTTP" con la clase "TIdHttp" es relativamente sencillo. El método "Post" de dicha clase está sobrecargado, y aquí nos limitaremos a explotar una de sus posibilidades.

Creo que los comentarios al código fuente lo dicen todo. Tú también puedes comentar lo que te parezca respecto al mismo.

Código Delphi [-]
uses
  {
    Indy Components

    Unidades necesarias para utilizar las clases
    implicadas en la tarea que nos ocupa.
  }
  IdHTTP, IdMultipartFormData;

{
  Evento "Click" de un supuesto botón "btnPost" que
  utilizamos a modo de ejemplo para realizar la tarea.
}
procedure TfrmPrincipal.btnPostClick(Sender: TObject);
var
  idHttp: TIdHTTP;
  datosPost: TIdMultiPartFormDataStream;
begin
  {
    Creamos una instancia de la clase TIdMultiPartFormDataStream
    que nos sirve para determinar luego los distintos pares
    "claves=valor" de que se compone un supuesto "Post HTTP"
  }
  datosPost := TIdMultiPartFormDataStream.Create;
  try
    {
      Como puede verse añadir pares "clave=valor" no resulta
      nada complicado. Pueden añadirse tantas como sean precisas.
    }
    datosPost.AddFormField('NombreCampo1', 'ValorCampo1');
    datosPost.AddFormField('NombreCampo2', 'ValorCampo2');
    //datosPost.AddFormField('NombreCampo3', 'ValorCampo3');

    {
      Instanciamos un objeto de la clase "TIdHttp"
    }
    idHttp := TIdHTTP.Create(Self);
    try
      {
        Y en la siguiente línea se lleva a cabo el "Post HTTP"
        y además se obtiene su respuesta, que viene dada por el
        propio método "Post" de la clase "TIdHttp".
      }
      mRespuestaPost.Text := idHttp.Post('http://www.url.com/', datosPost);

    finally
      idHttp.Free;
    end;
  finally
    datosPost.Free;
  end;
end;

En todo caso, es posible que la respuesta, el resultado del método "Post" no nos satisfaga. Por ejemplo, hace poco me he topado con la necesidad de hacer un "Post HTTP" en cierto programa y, la respuesta no es, precisamente, una cadena, sino un archivo...

Es decir, que el resultado del método "Post" no me servía de mucho en este caso concreto que estoy refiriendo. ¿Qué hacer, pues, si la respuesta es un archivo, por ejemplo, y no una cadena?

Yo he utilizado el propio componente "IdHttp". Este tiene una propiedad "Response", que a su vez cuenta con una propiedad de nombre "ContentStream". En el evento "OnWorkEnd" del componente "TIdHttp" dicha propiedad "ContentStream" contiene el archivo que se sirvió como respuesta del método "Post".

Es decir, que sí, que en este truco se ha mostrado una de las formas de realizar un "Post HTTP" con el componente "IdHttp", pero, que, obviamente, dicho componente da no poco de sí, y pone a nuestra disposición no pocas posibilidades de personalizar la "pregunta al Servidor" (Request) y también bastantes propiedades que nos informan de la respuesta (Response) del mismo.

Hola muy buen aporte me sirvio muxo ^^, tengo una pregunta como obligo a la respuesta q me de un resultado unicode, pues la página a la cual hago el post da como respuesta unos datos con caracteres unicode, los cuales al no tener ningun content type o demás lo da como ansi, pero con los respectivos problemas del mismo, la perdida de caracteres o por ej la á la muestra como á... y si le forzo como UTF8 la misma á me la muestra como C! ... me podes ayudar muchas gracias!

Pues no sé yo demasiado sobre el tratamiento de diferentes "juegos de caracteres" en Delphi... sé que es posible (a partir de cierta versión de Delphi y teniendo ciertas precauciones) el tratamiento de UTF-8, pero, yo probaría con lo que dices de "forzar" que el resultado me llegara en UTF-8 (creo que esto es más sencillo de conseguir).

Luego vería qué estoy haciendo con lo que me llega como respuesta... si lo estoy "tratando" con alguna función que no esté preparada para ese juego de caracteres... tendrías que buscar un poco en los Foros y en Google, si quieres: desde luego es posible en Delphi tratar con UTF-8, ya te digo que es cuestión (según he leído) de seguir ciertas pautas, como usar unas funciones que reemplazan a "las anteriores", que no estaban preparadas para ese juego de caracteres.

Echa un vistazo al tipo "WideString" en Delphi y, como te digo, busca por ahí que seguro encuentras información sobre el tema. Yo no puedo decirte más ahora mismo y bien que lo siento.

OK Muchas gracias!

Hola,

Otra forma de hacer lo que nos ocupa sin utilizar el tipo "TIdMultiFormPartDataStream" podría ser la siguiente:

Código Delphi [-]
uses
  IdHttp;

procedure TForm1.Button1Click(Sender: TObject);
var
  http: TIdHttp;
  params: TStrings;
  respuesta: string;
begin
  http := TIdHTTP.Create(Self);
  params := TStringList.Create;
  try
    params.Add('variable1=valor1');
    params.Add('variable2=valor2');
    respuesta := http.Post('http://dec.clubdelphi.com/temporales/pruebas-post.php', params);
    ShowMessage('Respuesta: ' + respuesta);
  finally
    http.Free;
    params.Free;
  end;
end;

Un ejemplo de Script PHP que respondiera a la llamada anterior podría ser este:

Hola,

en un momento dado que tendria que hacer en caso de que quisiera enviar un POST pero a una direccion de tipo HTTPS, ya que si intento enviar un archivo, me manda un mensaje de error IOHandler.

Gracias de antemano

Hola, eh utilizado este ejemplo para un trabajo que estoy haciendo, pero me muestra una pantalla con un mensaje 'Unknown Protocol.' Sabes como corregir eso, te agradeceria mucho tu ayuda.