Ayuda con TListbox para sacar informacion
 

bueno amigos tengo un TlistBox en el que muestro unos 1,500 y tengo otro a donde debo pasar los registros seleccionados hasta hi todo bien, el problema radica en que no se como sacar de la cadena que muestro el id que identifica a cada cliente, tratare de poner el ejemplo

list1 muestro al informacion asi

CTRN-1 | PEDRO ALFONSO GALICIA NAVA
CTRN-2 | PABLO GALICIA NAVA
CTRN-3 | ADRIAN GALICIA NAVA

en list 2 necesito pasar los registros seleccionados, ahi no hay problema

y tengo un boton guardar que al precionar deberia hacer un determinado proceso de calculo, aqui es donde no se como recorrer la lista solo considerando la informacion antes del simbolo " | ", alguna idea de como poder hacerlo?


de antemano muchas gracias.

Hola,

Se me ocurre que utilices un "TListView" en lugar de un "TListBox". El primero te ofrece la posibilidad de mostrar "columnas", de manera que una columna podría contener "CTRN-1" y otra "PEDRO ALFONSO GALICIA NAVA". De esta forma, al recorrer el "TListView" podrás quedarte únicamente con la columna que necesites.

Además, me parece, el componente "TListView" te ofrece una apariencia más curiosa, puesto que con el "TListBox" debes "simular" las columnas (como haces con el caracter "|"), mientras que el "TListView" ya te ofrece esta posibilidad.

En efecto, siempre podrás encontrar una solución "copiando" antes y después de "|", por ejemplo, pero, creo que el "TListView" es más apropiado aquí que el "TListBox".

P.D. No olvides asignar a la propiedad "ViewStyle" del "TListView" el valor "vsReport".

Hola,

Abundando un poco en el asunto, echa un vistazo a este "ejemplo" que he preparado, a ver qué te parece:

ListViewSample.zip

Es sólo para que te hagas una idea, ¿eh? Por supuesto podrás hacer tantos cambios como veas oportunos.

Hola microbiano.

Totalmente de acuerdo con Dec, el TListView es un componente mucho más adecuado para lo que buscas hacer.

De todos modos si aún deseas utilizar un TListBox, podrías hacer:

Código Delphi [-]
...

implementation

type
  TClase = class
    cp1: string;
    cp2: string;
    cp3: string;
  end;

procedure TForm1.FormCreate(Sender: TObject);
var
  cl: TClase;
begin
  ListBox1.TabWidth:= 100; // (tab mayor a longitud del 1° campo)
  with DataSet do
  begin
    Open;
    while not DataSet.Eof do
    begin
      cl:= TClase.Create;
      cl.cp1:= FieldByName('ID').AsString;
      cl.cp2:= FieldByName('NOMBRE').AsString;
      cl.cp3:= cl.cp1;
      ListBox1.AddItem(Format('%s %s| %s',[cl.cp1, ^I, cl.cp2]) ,TObject(cl));
      Next;
    end;
  end;
end;

// Ejemplo: Agregar un ID a ListBox2 
procedure TForm1.btnAgregarUnoClick(Sender: TObject);
begin
  with ListBox1 do
    if ItemIndex > -1 then
      ListBox2.Items.Add(TClase(Items.Objects[ItemIndex]).cp3);
end;

// Ejemplo: Agregar todos los ID a ListBox2
procedure TForm1.btnAgregarTodosClick(Sender: TObject);
var
  i: Integer;
begin
  for i:= 0 to ListBox1.Items.Count-1 do
    ListBox2.Items.Add(TClase(ListBox1.Items.Objects[i]).cp3);
end;

...

// Liberar 
procedure TForm1.FormDestroy(Sender: TObject);
var
  i: Integer;
begin
  for i:= 0 to ListBox1.Items.Count-1 do
    ListBox1.Items.Objects[i].Free;
end;

Pero la presentación obtenida no se compara con lo que te sugiere Dec.

Saludos.

Dec es buena tu opción pero como puedo eliminar el primer TListView los registros que ya estan en el segundo con la finalidad de no repetir varias veces el mismo registro en el TListView 2, de antemano muchas gracias un saludo desde mexico por cierto estoy utilizando delphi 7 :-)

Hola,

No creas que soy un experto en el component "ListView", pero, en fin, he modificado el ejemplo anterior de manera que ahora evita que puedan añadirse elementos duplicados en la lista "de la derecha", y, por otro lado, elimina los elementos que se añadan a esta desde la lista "de la izquierda". Puedes descargar el ejemplo desde el siguiente enlace:

ListViewSample2.zip

Para lo primero he preparado esta función, que, igual puede mejorarse:

Código Delphi [-]
function TMainForm.ItemExistsOnTheList( item : TListItem ) : boolean;
var
  i : integer;
begin
  result := false;
  for i := 0 to RightListView.Items.Count - 1 do
  begin
    if RightListView.Items[ i ].Caption = item.Caption then
    begin
      result := true;
      break;
    end;
  end;
end;

Como ves, pasando un elemento a la función (el elemento de la lista de la izquierda que quiere añadirse a la lista de la derecha) se recorre la lista de la derecha para ver si ya existe o no. En este caso determinamos si existe o no el elemento utilizando su "Caption". Esta función es utilizada en la "acción" que se usa para añadir elementos desde la lista de la izquierda a la lista de la derecha. Este método también se ha modificado, de manera que ahora se elimina el elemento de la lista de la izquierda, si es que este se termina añadiendo a la lista de la derecha:

Código Delphi [-]
procedure TMainForm.MoveListItemActionExecute(Sender: TObject);
var
  i : integer;
begin
  for i := LeftListView.Items.Count - 1 downto 0 do
  begin
    if LeftListView.Items[ i ].Selected then
    begin
      if not Self.ItemExistsOnTheList( LeftListView.Items[ i ] ) then
      begin
        with RightListView.Items.Add do
        begin
          Caption := LeftListView.Items[ i ].Caption;
          SubItems.Add( LeftListView.Items[ i ].SubItems[ 0 ] );
        end;
        LeftListView.Items.Delete( i );
      end;
    end;
  end;
end;

he intentado tratar de cargar registro de una base de datos pero la verdad no he podido .-(

Hola microbiano.

Para poder orientarte sería de gran ayuda que especifiques por que motivo no has podido cargarlos, mensaje de error (si lo hay) y sería excelente si agregas el código con que realizas la carga.

Saludos. .)