Hints en DBEdits
 

Buenas, he mirado la ayuda y no encuentro algún caso parecido, así que os detallo mi problema y os pongo un "fotomontaje" para clarificarlo.

Mi problema es que tengo una aplicación en el que el tamaño de los edits no dá más de si, además se añade la complicación de que se necesitan trabajar con todos los decimales (sean los que sean), así pues es fácil deducir que en bastantes casos al crear un registro nuevo o simplemente al desplazarse por los registros, los DBEdits no muestran toda la información que contiene el campo y se me había ocurrido poder mostrar HINTS con el contenido al pasar el ratón por encima del Edit (en modo edición o en modo lectura).

Lo que quiero se puede ver en el siguiente fotomontaje:



Y no encuentro la manera para que muestre esto siempre que se pase el curson por encima del edit.

Espero haber explicado todo con el suficiente detalle.

P.D.: Acepto sugerencias de mostrar el contenido de otro modo

Gracias por vuestro tiempo ;)

¿No tienen una propiedad "hint"? Si es así, lo que puedes hacer es asignar el "text" al "hint" cada vez que aquel cambie ("onModify/onChange" Es que no recuerdo el nombre y estoy vago...).

Hola.

Una opción alternativa a la mencionada por Ñuño es:

Código Delphi [-]
..
type
  TDBEdit = class(DBCtrls.TDBEdit)
    procedure CMMouseEnter(var Msg: TMessage); message CM_MouseEnter;
    procedure CMMouseLeave(var Msg: TMessage); message CM_MouseLeave;
  end;
  TForm1 = class(TForm)
    ...
    DBEdit1: TDBEdit;
    DBEdit2: TDBEdit;
    ...
  end;
...
implementation

procedure TDBEdit.CMMouseEnter(var Msg: TMessage);
begin
  Hint:= ' ' + Field.AsString + ' ';  // aca dale el formato que gustes
end;

procedure TDBEdit.CMMouseLeave(var Msg: TMessage);
begin
  Hint:= '';
end;
...

Un saludo.

Pero creo que las soluciones que me dais no me sirven cuando el formulario esta en modo de lectura, sin añadir ni modificar ningún registro. Y ahí es precisamente cuando más falta me hace que se pueda ver el contenido del DBEDIT.

Si no es así, no os termino de comprender.

Gracias de nuevo

Hola Kubelo.

En realidad la opción que te puse, funciona sin importar el modo en que esté el DataSet.

Por supuesto es necesario que el DataSet esté abierto y los DBEdits involucrados, tengan su propiedad ShowHint igual True.


Un saludo.

Pues no se si haré algo mal o no será lo correcto, pero no consigo dar con la solución... :confused:

Hola Kubelo.

Te pongo un ejemplo que sé que podés reproducir exáctamente; voy a utilizar la tabla Country.db de DBDEMOS que viene con Delphi.

Las propiedades necesarias las voy a asignar en el evento OnCreate del form para evitar confuciones, así sólo tenés que copiar y pegar.
Ahí también ajusté valores para el Hint por si acaso tenés un valor muy alto de retardo.

Agregá :
1) TTable : Table1.
1) TDataSource: DataSource1.
1) TDBEdit: DBEDit1.

Codigo:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, DBTables, StdCtrls, Mask, DBCtrls, Grids, DBGrids;

type
  TDBEdit = class(DBCtrls.TDBEdit)
    procedure CMMouseEnter(var Msg: TMessage); message CM_MouseEnter;
    procedure CMMouseLeave(var Msg: TMessage); message CM_MouseLeave;
  end;

  TForm1 = class(TForm)
    Table1: TTable;
    DBEdit1: TDBEdit;
    DataSource1: TDataSource;
    procedure FormCreate(Sender: TObject);
  private
  public
  end;

var
  Form1: TForm1;

implementation {$R *.dfm}

procedure TDBEdit.CMMouseEnter(var Msg: TMessage);
begin
   Hint:= ' ' + Field.AsString + ' ';
end;

procedure TDBEdit.CMMouseLeave(var Msg: TMessage);
begin
  Hint:= '';
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.HintPause:= 200;
  Application.HintHidePause:= 3000;
  Table1.DataBaseName:= 'DBDEMOS';
  Table1.TableName:= 'Country.db';
  DataSource1.DataSet:= Table1;
  DBEdit1.DataSource:= DataSource1;
  DBEdit1.DataField:= 'Population';
  DBEdit1.Width:= 40;       // limitar área de mostrado
  DBEdit1.ShowHint:= True;
  Table1.Open;
end;

end.

Dejá el cursor del mouse sobre el DBEdit y tiene que aparecer el hint con el valor del campo.

Cualquier inconveniente me comentás.

Un saludo.

Sigue sin funcionarme.

Al final he tenido que hacer los edits más grandes, he cambiado el aspecto con pestañas y arreglado. No podía perder más tiempo con esto.

Gracias a tod@s por vuestro tiempo.