Foros Club Delphi - Pid Correcto Con El GetProcessID

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)

- Varios (https://www.clubdelphi.com/foros/forumdisplay.php?f=11)

- - Pid Correcto Con El GetProcessID (https://www.clubdelphi.com/foros/showthread.php?t=62558)

Pid Correcto Con El GetProcessID

Hola.. ya me habran visto con el mismo tema.. pero puesto a varios inconvenientes.. tuve que crear otro hilo "Expresandome Mejor"

Esta ves quiero resolver este problema, aunque no sea algo urgente y ahora no es para la universidad... deseo ver mi proyecto andando y sirviendo :)

Aver mi proyecto ya varios saben de que trata.. pero solo tengo un error, es al elegir el proceso a editar en este caso "Tester.exe"

yo elijo los procesos con este code "GetProcessID"

Código Delphi [-]function GetProcessID(Const ExeFileName: string; var ProcessId: integer;
Const ProcessNo :Integer): boolean;
var
  ContinueLoop: BOOL;
  FSnapshotHandle: THandle;
  FProcessEntry32: TProcessEntry32;
begin
  result := false;
  FSnapshotHandle := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  FProcessEntry32.dwSize := Sizeof(FProcessEntry32);
  ContinueLoop := Process32First(FSnapshotHandle, FProcessEntry32);
  while integer(ContinueLoop) <> 0 do begin
  if (StrIComp(PChar(ExtractFileName(FProcessEntry32.szExeFile)), PChar(ExeFileName)) = 0)
     or (StrIComp(FProcessEntry32.szExeFile, PChar(ExeFileName)) = 0)  then begin
     ProcessId:= FProcessEntry32.th32ProcessID;
     result := true;
     break;
  end;
  ContinueLoop := Process32Next(FSnapshotHandle, FProcessEntry32);
  end;
  CloseHandle(FSnapshotHandle);
end;

ajam ... esa funcion "GetProcessID" solo elige un proceso.. por lo cual el

WriteProcessMemory editara solo el primer proceso de los dos procesos que tiene el "Tester.exe"

el problema ocurre alli.. porque tengo que editar el PID correcto (el Tester.exe correcto)

porque Obviamente hay 2 procesos de igual nombre

entonces.. como haria para hacer que este codigo el "GetProcessID" elija el PID correcto? o almenos edite el 2do proceso que es el que contiene lo que deseo editar.

Ojala me haya expresado bien, y me halla dado a entender.

Bueno esperando vuestra ayuda me despido.

Gracias por todo.

Saludos :).

Tu mismo te respondes, si lo que quieres es obtener el segundo proceso, una solución sería ignorar de alguna manera al primero que consiga.

Bueno, como te veo demasiado perdido respecto al tema, y parece ser que tienes miedo a investigar un poco, me he tomado la molestia de reformarte la función para que te permita obtener el PID que deseas:

Código Delphi [-]Function GetProcessID(Const ExeFileName: string; var ProcessId: integer;
                      Const ProcessNo :Integer = 1): boolean;
var
  ContinueLoop: BOOL;
  FSnapshotHandle: THandle;
  FProcessEntry32: TProcessEntry32;
  Temp: Integer;
begin
  {Inicializamos result y temp}
  result := false;
  temp:=1;
  
  {Obtenemos cada proceso uno por uno}
  FSnapshotHandle := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  FProcessEntry32.dwSize := Sizeof(FProcessEntry32);
  ContinueLoop := Process32First(FSnapshotHandle, FProcessEntry32);
  
  {Si no es el final de la lista, comparamos el nombre del proceso con 'exefilename'}
  while integer(ContinueLoop) <> 0 do
  begin {1}
   if (StrIComp(PChar(ExtractFileName(FProcessEntry32.szExeFile)), PChar(ExeFileName)) = 0)
     or (StrIComp(FProcessEntry32.szExeFile, PChar(ExeFileName)) = 0)  then
     begin {2}
       {Hemos encontrado un proceso con ese nombre, verificamos que es el que queremos con 'ProcessNo'}
       If Temp = ProcessNo then
       begin {3}
        ProcessId:= FProcessEntry32.th32ProcessID;
        result := true;
        break;
       end {3} else inc(Temp);
     end; {2}
   {Obtenemos el siguiente proceso}
   ContinueLoop := Process32Next(FSnapshotHandle, FProcessEntry32);
  end; {1}
  CloseHandle(FSnapshotHandle);
end;

Un ejemplo de como usarlo:

Código Delphi [-]procedure TForm1.Button1Click(Sender: TObject);
var PID: Integer;
begin
 PID:= 0;
 If GetProcessID('svchost.exe', PID, 3) then
  ShowMessage(IntToStr(PID));
end;

En el tercer parámetro de GetProcessID indicas el número del proceso que quieres si tienen un mismo nombre de ejecutable, de forma que por defecto será 1; el 2 sería el segundo proceso que encontrase con un nombre igual, el 3, 4, 5... .

Investigar no hace daño.
Por cierto, tu post ha mejorado pero solo un poco ;) tienes que practicar más.

Un saludo.

Edito: Feliz año a todos :).

Valla Valla Muchisimas Gracias

(Ahora si comprendo :rolleyes:) que pena no? :p

Gracias..

Ŧєℓιz Иανι∂α∂ & Pяσšρєяσ 2009