Again con los 'Globos' (Hints estilo Balloon)
 

Gracias al compañero delphi.com.ar resolver el problema para colocar esos globitos con titulo y mensaje como si fueran los Hints en algunos componentes.

http://www.clubdelphi.com/foros/show...ighlight=Globo

Ahora que saque todo del baúl de los recuerdos, no puedo conseguir colocarle estos globitos a los botones de una ToolBar (uno para cada uno). Sé que para colocarle este estilo de hints ocupo el handle del componente, pero en estos botones no hayo la manera de asignarle su globo a un ToolButton.

P.D.
Debo estar olvidando un detalle por eso no me sale, seguire intentando (mal por supuesto).

Aquí hay que entender una cosa:

El ToolTip puede asociarse a un control o bien a un área de un control en cuyo caso el campo Rect del ToolInfo debe indicar dicha área y el campo hWnd el control que contiene el área.

En el caso que quieres, debes usar áreas ya que los botones de una ToolBar no son ventanas y por tanto no tienen "Handle".

Aquí te pongo un ejemplo de cómo usar un ToolTip para una ToolBar. Los hints de cada botón serán los hints que especificas en la propiedad Hint de cada ToolButton para facilidad, pero puedes asociarle el contenido de un StringList si deseas hints con varia líneas.

El ejemplo muestra también que no es necesario crear un ToolTip para cada botón y aún así desplegar un título distinto en cada uno. Recuerda que cada ToolTip es una ventana y entre más crees, más recursos del sistema gastas.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Controls, Forms,
  StdCtrls, ComCtrls, CommCtrl, ToolWin;

type
  TForm1 = class(TForm)
    ToolBar: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;

    procedure FormCreate(Sender: TObject);

  private
    ToolTipHandle: HWnd;
    ToolInfo: TToolInfo;
    
    // Para detectar cuándo se muestra el tooltip y así
    // cambiar el título de acuerdo al botón
    procedure WMNotify(var Message: TWMNotify); message WM_NOTIFY;

  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses
  ToolTip;

{$R *.dfm}

const
  TTS_BALLOON = $040;
  TTM_SETTITLE = WM_USER + 32;

procedure TForm1.FormCreate(Sender: TObject);
var
  Index: Integer;

begin
  ToolTipHandle := CreateWindowEx(
    WS_EX_TOPMOST,
    TOOLTIPS_CLASS,
    nil,
    WS_POPUP or TTS_NOPREFIX or TTS_ALWAYSTIP or TTS_BALLOON,
    Integer(CW_USEDEFAULT),
    Integer(CW_USEDEFAULT),
    Integer(CW_USEDEFAULT),
    Integer(CW_USEDEFAULT),
    Handle,
    0,
    HInstance,
    nil
  );

  SetWindowPos(
    ToolTipHandle,
    HWND_TOPMOST,
    0, 0, 0, 0,
    SWP_NOMOVE or SWP_NOSIZE or SWP_NOACTIVATE
  );

  ToolInfo.cbSize := SizeOf(TToolInfo);
  ToolInfo.uFlags := TTF_SUBCLASS;
  ToolInfo.hwnd := ToolBar.Handle;
  ToolInfo.hInst := HInstance;

  for Index := 0 to Pred(ToolBar.ButtonCount) do
  begin
    ToolInfo.uId := Index;
    ToolInfo.Rect := ToolBar.Buttons[Index].BoundsRect;
    ToolInfo.lpszText := PChar(ToolBar.Buttons[Index].Hint);
    SendMessage(ToolTipHandle, TTM_ADDTOOL, 0, Integer(@ToolInfo));
  end;

  // Parece ser necesario este título "falso" ya que de lo contrario
  // la primera vez que se muestra el ToolTip sólo aparece el título
  SendMessage(ToolTipHandle, TTM_SETTITLE, 0, Integer(PChar('fix')));
end;

procedure TForm1.WMNotify(var Message: TWMNotify);
var
  Title: String;

begin
  inherited;

  if Integer(Message.NMHdr.hwndFrom) = Integer(ToolTipHandle) then
    case Message.NMHdr.code of
      TTN_SHOW:
      begin
        Title := 'Título ' + IntToStr(Message.IDCtrl);
        SendMessage(ToolTipHandle, TTM_SETTITLE, 1, Integer(PChar(Title)));
      end;
    end;
end;

end.

Te recomiendo que consultes el sdk de Microsoft para mayor información acerca de los ToolTips.

// Saludos

Muchas gracias compatriota roman!!
Ya comence a analizar el ejemplo que adjuntas en tu mensaje.

Tambien por la recomendación por la SDK.

:D