Simular dos radiobuttons con Checkbox
 

Necesito simular el efecto de seleccion unica que poseen los radiobutton con un par de checkbox (Ch1 y Ch2), y no consigo que funcionen :confused::

Código Delphi [-]
procedure TForm1.Ch1Click(Sender: TObject);
begin
  Ch1.Checked:=True;
  if Ch2.Checked then Ch2.Checked:=False;
end;

procedure TForm1.Ch2Click(Sender: TObject);
begin
  Ch2.Checked:=True;
  if Ch1.Checked then Ch1.Checked:=False;
end;

Desde ya muchas gracias por vuestra ayuda...

Un abrazo...

TriloCba

Intenta así:

Código Delphi [-]
procedure TForm1.CheckBox1Click(Sender: TObject);
begin
  if CheckBox1.Checked then
  begin
    CheckBox2.OnClick := nil;
    CheckBox2.Checked := false;
    CheckBox2.OnClick := CheckBox2Click;
  end;

  CheckBox1.Checked := true;
end;

procedure TForm1.CheckBox2Click(Sender: TObject);
begin
  if CheckBox2.Checked then
  begin
    CheckBox1.OnClick := nil;
    CheckBox1.Checked := false;
    CheckBox1.OnClick := CheckBox1Click;
  end;

  CheckBox2.Checked := true;
end;

// Saludos

Vamos a ver que te parece esta solución. Usamos un solo evento OnClick para los dos checkbox, y dento colocamos esto:

Código Delphi [-]
procedure TForm1.Ch1Click(Sender: TObject);
begin
  // Solo hay problemas cuando los dos estan marcados
  if Ch2.Checked and Ch1.Checked  then
    // Desmarcamos el checkbox que no nos llamo
    if Sender = Ch1 then
      Ch2.Checked:= FALSE
    else
      Ch1.Checked:= FALSE;
end;

PD: ¿Porque no usas radiobuttons? si quieres tener la opción de no marcar ninguno, siempre puedes añadir otro radiobutton con el caption "Ninguno de las anteriores" :)

¿Y si no quiere? Es decir, tal como pones, no se imita exactamente el comportamiento de dos radiobuttons ya que justamente puedes desmarcar ambos. Quizá sólo sea una razón estética.

// Saludos

Honor a quien honor merece, Roman, eres un maestro.

Me pongo de pie.

Saludos.

:rolleyes: Parece que estamos exigentes, pero si es una razón estética ya no digo mas. Mi confusión se debió a que no entendía porque alguien querría agregar código solo para que un control se comportara como otro, pero si los radiobutton os parecen feos adelante.

Bueno, es que yo no sé si es una cuestión estética. Es sólo que en el código que él intentó, explícitamente pone en true el checkbox que llama. Por eso supuse que no quería dejar que se desmarcara.

Ahora, tratando de encontrar un código compacto como el de seoane, lo más que me acerco es a esto:

Código Delphi [-]
{$writeableconst on}
procedure TForm1.CheckBoxClick(Sender: TObject);
const
  Checando: Boolean = false;

begin
  if Checando then exit;

  Checando := true;
  if Sender = CheckBox1
    then CheckBox2.Checked := false
    else CheckBox1.Checked := false;

  TCheckBox(Sender).Checked := true;
  Checando := false;
end;
{$writeableconst off}

usando un sólo evento para ambos.

// Saludos

Si hablamos de hacerlo chiquito o compacto :D:D

Código Delphi [-]
procedure TForm1.CheckBox1Click(Sender: TObject);
begin
  if TCheckBox(Sender).Name = CheckBox1.Name then
    CheckBox2.Checked:= not TCheckBox(sender).Checked
  else
    CheckBox1.Checked:= not TCheckBox(sender).Checked;
end;

Saludos

Pero así tiene un efecto extraño: cuando haces click sobre el que está marcado, la marca pasa al otro.

// Saludos

Saludos
Creí que queria un comportamiento similar al Radiobutton
Ya no entiendo:confused:

Ooh ya, se me ha chispoteado el asunto, tienes razón roman

El punto es que cuando se cambia la propiedad checked por código, se genera un evento OnClick y una recursividad que da al traste con el stack. Por ello es que no he visto forma de hacerlo como no sea controlando de una u otra manera cuando se está dentro del evento.

// Saludos

En su momento tambien me desconcertó ese funcionamiento, así que derivé de Tcheckbox y me creé el mio propio:

Código Delphi [-]

unit CheckBoxNoClick;

interface

uses
  Windows, Messages, SysUtils, Classes, Controls, StdCtrls;

type
  TCheckBoxNoClick = class(tcheckBox)
  private
    { Private declarations }
  protected
    { Protected declarations }
  public
    { Public declarations }
  published
    { Published declarations }
    procedure SetChecked(Value:Boolean);
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Standard', [TCheckBoxNoClick]);
end;

{ TCheckBoxNoClick }

procedure TCheckBoxNoClick.SetChecked(Value: Boolean);
begin
  try
    clicksdisabled := True;
    inherited;
  finally
    ClicksDisabled:= False;
  end;
end;

end.

Cuando no se quiere que desencadene el evento OnClick por código, se usa SetChecked.
Cuando se necesita el comportamiento normal, se usa como siempre.

Saludos

Muy buenas respuestas... pero sigue faltando una que no entiendo, y que el único que puede responder es el autor de este hilo:

¿porqué no quieres usar RadioButtons?

Muchas gracias a todos por vuestras rapidas respuestas...!!!

Me pone orgulloso que un tema tan modesto haya juntado a los grandes del foro !!!:D

Para despejar dudas, la utilizacion de los checkbox en lugar de radiobutton responde a dos situaciones:

1ra. Forman parte de un form que tiene como fondo una imagen especifica sobre la cual no puedo poner ningun componente como el Tpanel ó el TRadioGroup que no traiga la propiedad Transparent; y en el mismo formulario ya poseeo una serie de RadioButtons para otra función.

y 2da., aunque menos importante, me agradan visualmente mas los checkboxs sobre los radiobuttons.

Probare los ejemplos enviados, y de nuevo muchas gracias.

Un abrazo.

No me ha funcionado :confused:. Algo se me escapa

Saludos

En qué delphi lo has probado vtdeleon?

En Delphi 6 Enterprise lo he usado con éxito.

Como ves los de Borland ya pensaron en ello y precisamente por eso tienen una variabla protected/private (no recuerdo) llamada ClickDisabled.

Ahora mismo en Delphi 6 no puedo mirarlo. En BDS2006 la cosa ha cambiado:

Código Delphi [-]
procedure TCustomCheckBox.SetState(Value: TCheckBoxState);
begin
  if FState <> Value then
  begin
    FState := Value;
    if HandleAllocated then
      SendMessage(Handle, BM_SETCHECK, Integer(FState), 0);
    if not ClicksDisabled then Click; <-------------------------
  end;
end;

Ahora es el procedimiento SetState.

Saludos

Por ahí andaban los tiros.

Ahora no lo puedo probar, no tengo el delphi a mano.
Saludos

Perfecto... El primer codigo que planteo Roman es lo que necesitaba !!!:)

Muchas gracias a todos por la ayuda...

Un abrazo.

TriloCba