Envío de correos con INDY9
 

Hola amigos nuevamente recurriendo a ustedes.

Trabajo con: Delphi6, Indy9, FB2.0, Win11 64.

Problema: Estoy tratando de enviar correos usando Indy9 (desinstale los componentes anterior que vienen por default con delphi), gracias al club he logrado instalar los indy y tomar algo de codigo para hacer pruebas. Ya tengo un ratito (5 hrs) tratando de solucionar el siguiente problema.

Antes que nada colocaré el código q estoy usando para el envío de correo:

Código Delphi [-]
procedure TfrmImpEnvioTCK.btnEnviarClick(Sender: TObject);
begin
     idMessage1.Body.Clear();
     idMessage1.Recipients.Clear();
     idMessage1.Subject:='ENVIO TICKET - LAVANDERIA QUIJOTE';
     idMessage1.Body.AddStrings(Memo1.Lines);
     idMessage1.Recipients.EMailAddresses:=edMail.Text;
     idMessage1.From.Address:='[email protected]';
     idMessage1.From.Name:='LAVANDERIA ';

     with idSMTP1 do
     begin
          Port:=587;
          Host:='smtp.gmail.com';
          AuthenticationType := atLogin;
          Username:='[email protected]';
          Password := 'jaklsdfkasldfl';
          Connect();

          btnEnviar.Enabled := false;
          try
            Send(IdMessage1);
            ShowMessage('Correo enviado con éxito');
          finally
            btnEnviar.Enabled := true;
            Disconnect;
          end;
     end;
end;

Y me esta marcando este error: (imagen)

https://ibb.co/nbKvqfS

Me hace falta algo mas que configurar?

La cuenta de correo gmail esta configurada para 2 pasos, cree una contraseña de aplicación para lograr el envío de correos desde delphi...sabes como puedo resolver el error??

Muchas gracias por su tiempo amigos.

¿Qué valores has puesto en sslversion, usetls, etc.?

Revisa que la versión de las Indy que estás utilizando (que veo que estás con Delphi 6) soporte el TLS que necesita el servidor.
Hace poco se actualizaron versiones mínimas y es posible que necesites 1.2 al menos.

Creo que necesitará la version 10 de indy, al menos yo con la 9 no conseguí que funcionara, sin embargo con la 10 funciona perfectamente. También usando "contraseña de aplicación".

Hola Casimiro...en realidad es la primera vez que uso los Indy, entonces no sé q es SSLVERSION y USETLS...propiedades??.

La version 10 de Indy las puedo instalar en Delphi6??

Hola Germán...gracias por contestar.

Como puediera revisar que esta version q estoy usando soporta TLS...??.

Ahora he cambiado el puerto a 465 y me envia el siguiente error:

El codigo:

Código Delphi [-]
procedure TfrmImpEnvioTCK.btnEnviarClick(Sender: TObject);
begin
     idMessage1.Body.Clear();
     idMessage1.Recipients.Clear();
     idMessage1.Subject:='ENVIO TICKET';
     idMessage1.Body.AddStrings(Memo1.Lines);
     idMessage1.Recipients.EMailAddresses:=edMail.Text;
     idMessage1.From.Address:='[email protected]';
     idMessage1.From.Name:='LAVANDERIA';

     with idSMTP1 do
     begin
          Port:=465;
          Host:='smtp.gmail.com';
          AuthenticationType := atLogin;
          Username:[email protected]';
          Password := 'kadjkfljldjflkad';
          Connect();

          btnEnviar.Enabled := false;
          try
            Send(IdMessage1);
            ShowMessage('Correo enviado con éxito');
          except
          on E : Exception do
            if E is EIdConnClosedGracefully then
            begin
                btnEnviar.Enabled := true;
                Disconnect;
            end else
            begin
                raise
            end;

          end;
     end;
end;

Alguna idea??...

O definitivamente deberé desinstalar la 9 e instalar la 10 de Indy???...

A ver si te ayuda este hilo:
https://www.clubdelphi.com/foros/showthread.php?t=96482

En las especificaciones de la versión también debería especifocar algo sobre TLS

Gracias German.

Lo cheque..pero en realidad no entiendo mucho, instalar DLL, librerias...en algunas páginas que he consultado mencionan un EXE de instalación, super mas comodo, pero ya no está disponible la página, sería mas fácil la instalación.

En fin...se esta complicando un poco esto de envíar correos con delphi.

Seguiré buscando la solución.

Hola de nuevo...

Ya me conseguí los Indy10, pero ahora como se instalan??. En el foro hay unas instrucciones pero consulto el link que dice ahi y ya no hay nada....

https://www.clubdelphi.com/foros/showthread.php?t=66412

Del "tocayo" Román.

Y los pude bajar de aqui, pero no se como se instalan...con los Indy9 habia unos dpk, pero aqui en esta version nos los veo.

Vamos amigos...despues de 18 años aprox programando en Delphi, no me he atorado con nada....hasta ahora, espero que no. Hasta ahorita todo lo he resulto con Delphi, no quiero que esto de envío de correo sea el primero en no poderlo resolver con delphi.

Saludos.

Instalar las indy lleva su tiempo porque tienes que asegurarte antes de haber eliminado absolutamente todo lo que exista de la versión que tengas instalada.
Te aconsejo una buena copia de seguridad de lo que tienes antes de seguir.
La descarga y la documentación sobre la instalación las puedes encontrar aquí:
https://www.indyproject.org/download/v10/
La documentación está en varios formatos:
https://www.indyproject.org/documentation/
Te copio una captura de pantalla con los parámetros con los que está funcionando con gmail.

Si tienes cualquier duda, pregunta.

Y no olvides las DLL actualizadas también.
Aquí están.

Yo probaría antes con la que tienes instalada, la v9, porque vayas a estropear tu delphi 6 intentando instalar la v10 y te quedes sin una y sin la otra.
En mi caso la v10 está instalada en un delphi 2007

Hola Casimiro...demasiado tarde tu comentario. Ya desinstale la 9....

Espero poder reinstalar...

Y donde las debo de copiar/instalar...se copian solamente?...y en donde?

Casimiro...lamento decirte que los links ya no accesan a la documentación, me envía un aviso de error que dice "No se puede acceder a este sitio"...

Junto a tu ejecutable.

Pero también están en la página de github
https://github.com/IndySockets/Indy/wiki
Ahí a la derecha tienes la wiki, la documentación y la "updating indy", está todo, lo acabo de comprobar.

También te dije antes de nada: "Te aconsejo una buena copia de seguridad de lo que tienes antes de seguir."
:D

Espero que te sea leve el proceso.

Logré instalar nuevamente los componentes Indy9...

Pues...demasiado tarde para las 2 recomendaciones q me hiciste!..jajajaja

Bueno el caso es que estoy probando con la 9.

Reenvío el código que estoy usando, lo modifique de acuerdo a un post de DEC (del 2004!!, a ver si me funciona jajaja):

Código Delphi [-]
procedure TfrmImpEnvioTCK.btnEnviarClick(Sender: TObject);
var
  smtp : TidSMTP;
  mail : TIdMessage;

begin
     smtp := TIdSMTP.Create(Self);
     mail := TIdMessage.Create(Self);

     with smtp do
     begin
          Port := 25;
          Host := 'smtp.gmail.com';
          AuthenticationType := atLogin;
          UserId:='[email protected]';
          Password := 'fayhxquevflre';
          Connect();
     end;

     with mail do
     begin
          Recipients.Add;
          Recipients[0].Name:='CLIENTE';
          Recipients[0].Address:=edMail.Text;
          From.Name:='LAVANDERIA';
          From.Address:='[email protected];
          Subject:='Envío de nota 99999 - LAVANDERIA';
          Body.Text:=Memo1.Lines.Text;
     end;

     TIdAttachment.Create(mail.MessageParts, 'C:\prueba.txt');

     smtp.Connect;
     try
       try
         smtp.Send(mail);
       except
         on E: Exception do
            ShowMessage(E.Message);
       end;
     finally
       if smtp.Connected then
          smtp.Disconnect;
     end;
     mail.Free;
     smtp.Free;
end;

Y marcar el siguiente error: "Socket Error # 10060 connection timed out", si hay que "activar" algún socket, diganme como se hace....por fa.

Gracias por su tiempo. (No me dejen solo!!)

Este error me sale cuando el puerto es 25 y cuando el puerto es 465, es este error "Connection Closed Gracefully" y cuando es el 587 "EIdProtocolReplyError with message '530 5.7.0 specifications.....bla bla alfanumerico... - gsmtp'.

Busque el codigo de este último error...y tiene q ver con seguridad del servidor, pero no sé si tambien del componente delphi

https://sendlayer.com/docs/error-530...command-first/
https://support.google.com/a/answer/3726730?hl=es

Utiliza los parámetros que te he indicado, están funcionando actualmente en muchos sitios.

Si refieres a los de la pantalla q enviaste...como se los defino al componente?.

Intente esto:

Código Delphi [-]
         with smtp do
     begin
          Port := 587;
          Host := 'smtp.gmail.com';
          AuthenticationType := atLogin;
          UserId:='[email protected]';
          Password := 'fayhxquevbflre';
          IOHandler := SSL;
          UseTLS:=utUseExplicitTLS;
     end;

Me salen estos errores...
Ahora...si estos erroes tienen q ver con las DLL q me enviaste, como las actualizo o copio y en donde?

Gracias Casimiro.

Mira si te sirve de ejemplo:

Código Delphi [-]
// Es la función que nos permite enviar el Mail con Indy 10. 
// en la cabecera están definidos los parámetros 
function SendEmailIndy10(AEmailEnvio:string; AListaAdjuntos: TStringList; 
                         AHostSMTP: string; APortSMTP: Integer; 
                         AAsunto: string; ACuerpoMensaje: string; 
                         ANombreUsuario: string; APasswordUsuario: string; 
                         AFromText:string; 
                         AListaParametros:TStrings; 
                         AListaParamsDB:TStrings; 
                         AListaParamsIMG:TStrings; 
                         tls:TIdUseTLS; 
                         sslVersion:TIdSSLVersion; 
                         AFormatoPlano:boolean; 
                         var outMessage:String; 
                         procStatus:TidStatusEvent=nil): integer; 
var 
    ServidorSMTP: TIdSmtp; 
    sslHandler: TIdSSLIOHandlerSocketOpenSSL; 
    Mensaje: TIdMessage; 
    idText: TIdText; 
    i: Integer; 
    TS:TStrings; 
begin 
    // ini 
    Result := 0; 
    outMessage := ''; 
 
    // Creamos los objetos y componentes necesarios 
    ServidorSMTP := TIdSmtp.Create(nil); 
    sslHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil); 
    Mensaje := TIdMessage.Create(nil); 
 
    // proteccion para liberar 
    try 
        // Si la lista de paámetros está asignada, los sustituimos por los valores 
        if Assigned(AListaParametros) then begin 
          ACuerpoMensaje := SustituirParametros(ACuerpoMensaje, AListaParametros); 
        end; 
        // Si recibimos parámetros dinámicos de la BD, los sustituimos por los valores 
        if Assigned(AListaParamsDB) then begin 
          ACuerpoMensaje := SustituirParametros(ACuerpoMensaje, AListaParamsDB); 
        end; 
        // si recibimos alguna imagen en la lista, la sustituimos por sus urls 
        if Assigned(AListaParamsIMG) then begin 
          if not(AFormatoPlano) then  // si no es texto, sino que sí es html... 
            ACuerpoMensaje := SustituirParametrosImagen(ACuerpoMensaje, AListaParamsIMG); 
        end; 
        // 
        // Proteccion para liberar 
        try 
            // configuraciones básicas para el server SMTP 
            ServidorSMTP.Host := AHostSMTP; 
            ServidorSMTP.Port := APortSMTP; 
            ServidorSMTP.Username := ANombreUsuario; 
            ServidorSMTP.Password := APasswordUsuario; 
 
            // Timeout; Necesario para algunas versiones de las Indy 
            ServidorSMTP.ReadTimeout := 30000; 
 
            // Procedimientos de Callback (opcionales) 
            ServidorSMTP.OnStatus := procStatus; 
 
            //·································································· 
            // Podríamos llegar a usarlos, pero no es necesario... de momento 
            // ServidorSMTP..OnConnected :=IdSMTP1Connected; 
            // ServidorSMTP..OnDisconnected :=IdSMTP1Disconnected; 
            // ServidorSMTP..OnFailedRecipient :=IdSMTP1FailedRecipient; 
            // ServidorSMTP..OnStatus :=IdSMTP1Status; 
            // ServidorSMTP..OnTLSNotAvailable :=IdSMTP1TLSNotAvailable; 
            // ServidorSMTP..OnWork :=IdSMTP1Work; 
            //·································································· 
 
            // Cambios segun si el server soporta o no TSL 
            if (tls <> utNoTLSSupport) then 
            begin   // Valores estandard 
              sslHandler.Destination := AHostSMTP + ':' + IntToStr(APortSMTP); 
              sslHandler.Host := AHostSMTP; 
              sslHandler.Port := APortSMTP; 
              sslHandler.SSLOptions.Method := sslVersion; 
              sslHandler.ReadTimeout := 30000; 
              ServidorSMTP.IOHandler := sslHandler; 
              ServidorSMTP.UseTLS := tls; 
            end; 
 
            // Configuración básica del mensaje 
            Mensaje.From.Address := ANombreUsuario; 
            Mensaje.From.Text := AFromText; 
            Mensaje.Recipients.EMailAddresses := AEmailEnvio; 
            Mensaje.Subject := AAsunto; 
            Mensaje.ContentType := 'multipart/mixed'; 
 
            // Preparamos lo necesario para "montar" el cuerpo del mensaje 
            TS := TStringList.Create(); 
            // protección para liberar 
            try 
              TS.Text := ACuerpoMensaje; 
 
              // Si estamos en modo texto? 
              if (AFormatoPlano) then begin 
                idText := TIdText.Create(Mensaje.MessageParts, TS); 
                idText.ContentType := 'text/plain'; 
              end 
              else begin 
                idText := TIdText.Create(Mensaje.MessageParts, TS); 
                idText.ContentType := 'text/html'; 
                idText.ContentTransfer := '7bit'; 
                Mensaje.ContentTransferEncoding := 'text/html'; 
              end; 
            finally 
              FreeAndNil(TS); 
            end; 
 
            // Asignada la lista de ficheros Adjuntos? 
            if Assigned(AListaAdjuntos) then begin 
              // recorer la lista y añadir los ficheros... 
              for i := 0 to (AListaAdjuntos.Count - 1) do begin 
                // si existe, lo añadimos... 
                if FileExists(AListaAdjuntos[i]) then begin 
                  TIdAttachmentFile.Create(Mensaje.MessageParts, AListaAdjuntos[i]); 
                end; 
              end; 
            end; 
 
            // proteccion para la conexion 
            try 
              ServidorSMTP.Connect;                          // PASO 1: conexion 
              // proteccion para el envio 
              try 
                ServidorSMTP.Send(Mensaje);                 // PASO 2 : envío 
                //-Debug- showmessage('El mensaje se envió correctamente'); 
                Result := Result + ID_ENVIO_OK;  // OK 
              except 
                on E:Exception do begin 
                  //-Debug- showmessage('Se produjo un fallo durante el envío del mensaje; ' + sLineBreak + E.Message); 
                  Result := ID_ENVIO_ERROR_ENVIO {-20}; 
                  outMessage := rsErrorAlEnviar + E.Message; 
                end; 
              end; 
            except 
              on E:Exception do begin 
                //-Debug- showmessage('Se produjo un fallo durante la conexión con el servidor; ' + sLineBreak + E.Message); 
                Result := ID_ENVIO_ERROR_CONEXION {-10}; 
                outMessage := rsErrorAlConectar + E.Message; 
              end; 
            end; 
 
            //si nos hemos conectado correctamente, al finalizar, desconectamos,... 
            if (ServidorSMTP.Connected) then begin 
              ServidorSMTP.Disconnect;                    // PASO3: desconexion 
            end; 
        finally 
          // Liberar los componentes creados 
          Mensaje.Free; 
          sslHandler.Free; 
          ServidorSMTP.Free; 
        end; 
      except 
        // en caso de excepción "desconocida" devolvemos esto... 
        on E:exception do begin 
          Result := -1; // desconocido 
          outMessage := rsErrorDesconocido + E.Message; 
        end; 
    end; 
end;

Muchas gracias por el ejemplo. Pero de momento estaré tratando de resolver el problema de los errores del post anterior.

Saludos.

Retomando el tema
 

Amigos, retomando el tema:

Instalé en una Maquina virtual win7 32 bits, instalé Delphi7, Desinstalé Indy9 e Instalé Indy10.

Lo anterior para hacer pruebas de envío de correo.

CASIMIRO me paso unas DLL que ya bajé y copié al mismo directorio donde esta mi ejecutable.

Envía el siguiente error

https://ibb.co/dJS2vMn

CODIGO

Código Delphi [-]
procedure TForm1.btnEnviarClick(Sender: TObject);
begin
    SMTP.Port     :=587;
    smtp.Host     :='smtp.gmail.com';
    smtp.AuthType :=atDefault;
    smtp.Username :='[email protected]';
    smtp.Password :='fayhxquevfbflre';
    smtp.IOHandler:=IdSSLIOHandlerSocketOpenSSL1;
    smtp.UseTLS   :=utUseExplicitTLS;

     with correo do
     begin
          Recipients.Add;
          Recipients[0].Name:='CLIENTE';
          Recipients[0].Address:='[email protected]';
          From.Name:='LAVANDERIA';
          From.Address:='[email protected]';
          Subject:='Envío de nota 99999 - LAVANDERIA';
          Body.Text:='CORREO DE PRUEBA';
     end;

     smtp.Connect;
     try
       try
         smtp.Send(correo);
         ShowMessage('Correo enviado satisfactoriamente');
       except
         on E: Exception do
            ShowMessage(E.Message);
       end;
     finally
       if smtp.Connected then
          smtp.Disconnect;
       correo.Free;
       smtp.Free;
     end;

end;

Agradeciendo sus aportes y comentarios de antemano, muchas gracias. Como puedo corregir este error??

p.d.1 Casimiro, gracias por último aporte -código- q me enviaste en este hilo, si me ayudó.
p.d.2 También copie las DLL en Windows\System32

Saludos y Gracias.

Le cambié el puerto a 465 y marcó este error...

Ahora marca este error....

https://ibb.co/XWKjnQk

Las dll que te pasé funcionan en win64, seguramente ese es el problema que tienes.
Hay otros hilos donde puedes descargar esas mismas dll en distintas versiones, prueba con varias de ellas, seguro que es eso.

Ok. Gracias.

Baje desde este link https://github.com/IndySockets/OpenS...i386-win32.zip algunos ZIP's con las DLL para Win32, pero me sigue marcando error...

Saludos

Es necesario saber exactamente en cada ocasión qué parámetros estás usando, qué código, el mensaje de error exacto, etc.

Ok Casimiro, aqui los detalles.

CODIGO:

Código Delphi [-]
procedure TForm1.btnEnviarClick(Sender: TObject);
begin
    SMTP.Port     :=465;
    smtp.Host     :='smtp.gmail.com';
    smtp.AuthType :=atDefault;
    smtp.Username :='[email protected]';
    smtp.Password :='fayhxquevftflre';
    smtp.IOHandler:=IdSSLIOHandlerSocketOpenSSL1;
    smtp.UseTLS   :=utUseExplicitTLS;

     with correo do
     begin
          Recipients.Add;
          Recipients[0].Name:='CLIENTE';
          Recipients[0].Address:='[email protected]';
          From.Name:='LAVANDERIA';
          From.Address:='[email protected]';
          Subject:='Envío de nota 99999 - LAVANDERIA';
          Body.Text:='CORREO DE PRUEBA';
     end;

     smtp.Connect;
     try
       try
         smtp.Send(correo);
         ShowMessage('Correo enviado satisfactoriamente');
       except
         on E: Exception do
            ShowMessage(E.Message);
       end;
     finally
       if smtp.Connected then
          smtp.Disconnect;
       correo.Free;
       smtp.Free;
     end;

end;

COMPONENTES:

Me falta algún componente?
Q componente debe ir relacionado con q otro?

Tengo relacionado TIdSMTP en su propiedad IOHandler a TIdSSLIOHandlerSocketOpenSSL

MENSAJE DE ERROR

PROPIEDADES DEL COMPONENTE TIdSSLIOHandlerSocketOpenSSL
https://ibb.co/5hPx17s

Gracias. Saludos.

Por qué no pruebas con los datos que te he dado antes, como te he comentado, está funcionando en muchas empresas.

Hola.
He probado el código que has puesto (porque me parece correcto) y compilandolo tanto con Delphi 12 como con Delphi 7, me envía correo a través de GMail correctamente.
Hay varias cosas importantes:

1) La primera que afecta a ambos, es que he tenido que definr DOBLE autentificación en la cuenta de GMail, para que me deje definir contraseña por aplicación.
Para crear la contraseña por aplicación lo he tenido que hacer desde aquí:
https://myaccount.google.com/apppasswords

Accediendo a la cuenta del correo.

2) Lo segundo importante es dar con las DLL's de SSL apropiadas para cada versión.

Este es el código que he utilizado (como ves es el tuyo) en delphi 12:

Código Delphi [-]
procedure TFormMain.Button1Click(Sender: TObject);
begin

  // INi                                                                     begin
    SMTP.Port     :=465;
    smtp.Host     :='smtp.gmail.com';
    smtp.AuthType :=satDefault;
    smtp.Username :='[email protected]';       // Cuenta de correo de envío
    smtp.Password :='1111t 4567g fyfs fjda ';             // Contraseña NO de acceso a GMail, sino la que genera desde: https://myaccount.google.com/apppasswords
    smtp.IOHandler:=IdSSLIOHandlerSocketOpenSSL1;
    smtp.UseTLS   :=utUseExplicitTLS;

     with correo do
     begin
          Recipients.Add;
          Recipients[0].Name:='CLIENTE';
          Recipients[0].Address:='[email protected]';
          Recipients.Add;
          Recipients[1].Name:='Wolters';
          Recipients[1].Address:='[email protected]';
          From.Name:='LAVANDERIA Desde Delphi 12';
          From.Address:='[email protected]';
          Subject:='Envío de nota 99999 - LAVANDERIA';
          Body.Text:='CORREO DE PRUEBA';
     end;

     smtp.Connect;
     try
       try
         smtp.Send(correo);

         ShowMessage('Correo enviado satisfactoriamente');
       except
         on E: Exception do
            ShowMessage(E.Message);
       end;
     finally
       if smtp.Connected then
          smtp.Disconnect;
       correo.Free;
       smtp.Free;
     end;
  mmLog.Clear;
end;

Ahora te adjunto el código de ambos proyectos incluyendo las DLLs de SSL que me funcionan con cada uno.
Están en el FTP de club:

EnviarMailIndyDelphi12.zip
EnviarMailIndyDelphi7.zip


Prueba y ya dirás...

Me pareció leer unos mensajes más arriba que ya estaba usando contraseña de aplicación, pero por lo visto no estaba usando esa contraseña, ese es el problema.

O versión de las DLLs, que siempre dan problemas.
Estas son sobre Windows 11 64bits, para ambas versiones de Delphi (supongo que también funcionarán sobre Windows 10)

Gracias Neftalí!...ya jalo!. Se pudo enviar el correo.

Que fué lo que hice:

1.- La contraseña de aplicación me fijé que no lo escribí con los espacios en blanco, cuando la generé me la mostró con espacios y en mi código no se los puse, esto apartir de tu ejemplo q me enviaste, se los
agregue por cada grupo de 4 caracteres va 1 espacio en blanco.
2.- Copié las DLL q adjuntaste en tu link de "EnviarMailIndyDelphi7.zip".
3.- Agregue en el USES -despues de "Implementation"- el "IdGlobal" y "IdEmailAddress".
4.- Lo compilé, ejecuté y se envío el correo.

Muchas gracias a los 2 por su tiempo (Casimiro y Neftalí) y por los ejemplos que me enviaron.

Saludos y nuevamente gracias.

p.d. Funcionó en Win7-32bits-D7-VMachine