Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Servers
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 04-09-2014
Avatar de Roll462011
Roll462011 Roll462011 is offline
Registrado
NULL
 
Registrado: jul 2011
Posts: 7
Poder: 0
Roll462011 Va por buen camino
Como saber si un libro Excel ya está abierto

Una de las librerias menos documentadas del entorno Delphi (al menos hasta la versión 7) es precisamente la de los Servers y las complicaciones se agudizan cuando tratas de utilizar métodos de estos componentes para operaciones sencillas como por ejemplo Abrir un libro de excel, habrán notado la cantidad de argumentos que hay que ponerle, quizas alguno de esos argumentos resuelva el problema que estoy teniendo:

- Necesito conocer si el libro de excel en el que voy a poner datos ya está abierto, si es así utilizarlo sino es así abrirlo para utilizarlo

Les agradesco si me pudieran ayudar, con ejemplos, documentación, etc. Ya he revizado los ejemplos que se linking desde este foro. Gracias es vital para mi evaluación.

Un saludo

Roll462011
Responder Con Cita
  #2  
Antiguo 04-09-2014
Avatar de ecfisa
ecfisa ecfisa is offline
Moderador
 
Registrado: dic 2005
Ubicación: Tres Arroyos, Argentina
Posts: 10.508
Poder: 36
ecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to behold
Hola Roll462011.

No trabajo con Excel, pero fijate si te sirve lo comentado en este enlace: Determine when an Excel workbook has closed with Delphi.

Y aquí encontré algo de documentación que tal vez te pueda ser útil: Automating Microsoft Excel

Saludos
__________________
Daniel Didriksen

Guía de estilo - Uso de las etiquetas - La otra guía de estilo ....
Responder Con Cita
  #3  
Antiguo 05-09-2014
Avatar de nlsgarcia
[nlsgarcia] nlsgarcia is offline
Miembro Premium
 
Registrado: feb 2007
Ubicación: Caracas, Venezuela
Posts: 2.206
Poder: 21
nlsgarcia Tiene un aura espectacularnlsgarcia Tiene un aura espectacular
Roll462011,

Cita:
Empezado por Roll462011
...Necesito conocer si el libro de Excel en el que voy a poner datos ya está abierto, si es así utilizarlo sino es así abrirlo para utilizarlo ...


Revisa este código:
Código Delphi [-]
 unit Unit1;
 
 interface
 
 uses
   Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, StdCtrls;
 
 type
   TForm1 = class(TForm)
     Button1: TButton;
     procedure Button1Click(Sender: TObject);
   private
     { Private declarations }
   public
     { Public declarations }
   end;
 
 var
   Form1: TForm1;
 
 implementation
 
 {$R *.dfm}
 
 uses ComObj, ActiveX;
 
 // Determina si Excel esta Instalado en la máquina
 function IsObjectAvailable(const ClassName: string): Boolean;
 var
   ClassID: TCLSID;
 begin
   Result := Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), ClassID));
 end;
 
 // Determina si Excel tiene una Instancia Activa en la máquina
 function IsObjectActive(const ClassName: string): Boolean;
 var
   ClassID: TCLSID;
   Unknown: IUnknown;
 begin
   Result := False;
   if Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), ClassID)) then
     Result := Succeeded(GetActiveObject(ClassID, nil, Unknown));
 end;
 
 // Realiza Operaciones de Verificación, Apertura y Cierre en una Instancia de Excel
 procedure TForm1.Button1Click(Sender: TObject);
 var
    Excel : Variant;
    FileExcel : String;
    i : Integer;
    MsgApp : String;
    FileExcelOpen : Boolean;
 
 begin
 
    // Verifica si Excel esta instalado en la máquina
    if not IsObjectAvailable('Excel.Application') then
    begin
       MsgApp := 'Excel no esta Instalado en esta Máquina';
       MessageDlg(MsgApp,mtInformation,[mbOK],0);
       Exit;
    end;
 
    FileExcel := ExtractFilePath(Application.ExeName) + 'TestExcel.xlsx';
    FileExcelOpen := False;
 
    // Crea una instancia de Automatización de Excel
    if IsObjectActive('Excel.Application') then
       Excel := GetActiveOleObject('Excel.Application')
    else
       Excel := CreateOleObject('Excel.Application');
 
    // Configura parámetros de ejecución de Excel
    Excel.DisplayAlerts := True;
    Excel.Visible := True;
 
    if (Excel.Workbooks.Count > 0) then
    begin
       for i := 1 to Excel.Workbooks.Count do
       begin
          if Excel.Workbooks[i].Name = ExtractFileName(FileExcel) then
          begin
            MsgApp := Format('El Libro de Excel %s esta Abierto y sera Cerrado',[FileExcel]);
            MessageDlg(MsgApp,mtInformation,[mbOK],0);
            // Cierra el libro de Excel referenciado en el String FileExcel
            Excel.Workbooks[i].Close(True);
            FileExcelOpen := True;
            Break;
          end
       end
    end;
 
    if not FileExcelOpen then
    begin
       // Abre el libro de Excel referenciado en el String FileExcel
       if FileExists(FileExcel) then
       begin
          Excel.Workbooks.Open(FileExcel);
          MsgApp := Format('El Libro de Excel %s Fue Abierto',[FileExcel]);
          MessageDlg(MsgApp,mtInformation,[mbOK],0);
       end
       else
       begin
          MsgApp := Format('El Libro de Excel %s No Existe',[FileExcel]);
          MessageDlg(MsgApp,mtInformation,[mbOK],0);
       end;
    end;
 
    // Finaliza la automatización de Excel y libera recursos
    MsgApp := Format('Excel sera Finalizado',[FileExcel]);
    MessageDlg(MsgApp,mtInformation,[mbOK],0);
    Excel.Quit;
    Excel := Unassigned;

 end;
 
 end.
El código anterior en Delphi 7 sobre Windows 7 Professional x32, realiza diversas operaciones de verificación, apertura y cierre en una instancia de Excel 2010 por medio de Automatización en Excel.

Revisa esta información:
Espero sea útil

Nelson.

Última edición por nlsgarcia fecha: 05-09-2014 a las 04:15:32.
Responder Con Cita
  #4  
Antiguo 04-11-2014
Avatar de Roll462011
Roll462011 Roll462011 is offline
Registrado
NULL
 
Registrado: jul 2011
Posts: 7
Poder: 0
Roll462011 Va por buen camino
Wuaohhhh. Gracias amigo, cojonuda la Unit

Estimado Nelson
He adaptado la Unit que publicastes en el mensaje anterior a mis necesidades y creeme que me ha sido de gran utilidad. Cuando sea millonario (y lo pretendo), jajajajaja no olvidaré tu aporte.
Un saludo

Roll
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
ClientdataSet como saber si esta abierto? Coco_jac Varios 4 13-04-2012 20:36:43
Cómo detectar si un formulario ya está abierto? mbguantay Varios 8 10-02-2011 18:20:56
Como saber si un fichero está abierto RaulChemical API de Windows 13 30-12-2008 18:31:42
Saber si un puerto esta abierto Besto Varios 12 10-10-2007 17:30:00
Saber si esta abierto un documento Word Investment Servers 2 13-05-2004 13:02:26


La franja horaria es GMT +2. Ahora son las 07:34:08.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi