Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Otros temas > Trucos
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Los mejores trucos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 05-02-2015
Avatar de AgustinOrtu
[AgustinOrtu] AgustinOrtu is offline
Miembro Premium
NULL
 
Registrado: ago 2013
Ubicación: Argentina
Posts: 1.858
Poder: 15
AgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en bruto
Unidad de Roman para FMX: Evitar mas de una instancia de tu aplicacion

Buenas, sencillamente era para dejar la brillante UIApp de Roman, que permite evitar que mas de una instancia de la misma aplicacion sea ejecutada. Esta es una adaptacion para la plataforma FMX. Creo que es medio chanchullo, pero no encontre otra forma de hacerlo (ver parte resaltada)

Código Delphi [-]
{*
    http://romansg.clubdelphi.com/
    Creditos a Roman del ClubDelphi, todo este codigo es obra suya
    
    Con sólo agregar esta unidad al comienzo de la cláusula uses del archivo dpr de tu proyecto, evitarás que la aplicación pueda ejecutarse más de una vez al mismo tiempo.

    Cuando una segunda instancia comienza a ejecutarse, el código de la unidad la cancela y activa automáticamente la instancia anterior
    
    Fuentes originales: http://romansg.clubdelphi.com/descarga.php?id=uiapp (version para VCL)
    Mas informacion: http://romansg.clubdelphi.com/index.php?pg=uiapp
    
    Esta unit es una adaptacion para que funcione en la plataforma FireMonkey (FMX)
    
    Probado en Delphi XE7
*}

unit UIApp_fmx;

interface

implementation

uses
  Windows, SysUtils, FMX.Forms, FMX.Platform.Win;

const
  { Cadenas para registrar el mutex y el mensaje }
  sMutex   = '10D73234-C9F7-4C2D-BC7E-39B5820AF456';
  sActivar = '3F154732-CCDE-4BC7-9439-AFCD3BCFA84D';

var
  mActivar    : Cardinal; { Mensaje para activar la instancia anterior }
  Mutex       : Cardinal; { Mutex                                      }
  PrevWndProc : TFarProc; { Procedimiento de ventana original          }


function AppWndProc(Handle: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LongInt; stdcall;
var
  FgThreadId  : DWORD; { Hilo de la app. que tenga el foco }
  AppThreadId : DWORD; { Hilo de nuestra aplicación        }

begin
  if Msg = mActivar then
  begin
    { Si está minimizada basta restaurarla }
    if IsIconic(Handle) then
      ShowWindow(Handle, SW_RESTORE)
    else
    begin
      { Obtener los hilos }
      FgThreadId  := GetWindowThreadProcessId(GetForegroundWindow, nil);
      AppThreadId := GetWindowThreadProcessId(Handle, nil);

      { Anexar el hilo de nuestra app. al de la  que tenga el foco }
      AttachThreadInput(AppThreadId, FgThreadId, true);

      { Ahora sí, activar la applicación }
      SetForegroundWindow(Handle);

      { Separar el hilo de nuestra app de la otra }
      AttachThreadInput(AppThreadId, FgThreadId, false);
    end;

    Result := 0;
  end
  else
    { Dejar que el procedimiento original se encargue de los otros mensajes }
    Result := CallWindowProc(PrevWndProc, Handle, Msg, wParam, lParam);
end;

procedure Activar;
begin
  { Mandamos el mensaje a todas las ventanas }
  SendMessage(HWND_BROADCAST, mActivar, 0, 0);
end;

procedure Registrar;
var _HWND: cardinal;
begin
  mActivar := RegisterWindowMessage(sActivar);
  Mutex    := CreateMutex(nil, true, sMutex);

  { Si ya existe el mutex lanzamos una excepción silenciosa }
  if GetLastError = ERROR_ALREADY_EXISTS then
  begin
   Mutex := 0;
   abort;
  end
  else
  begin
    { Sustituimos el procedimiento de ventana }
        Application.MainForm:= TCommonCustomForm.Create(NIL);
        _HWND := WindowHandleToPlatform(Application.MainForm.Handle).Wnd;
        Application.MainForm.Free;
        PrevWndProc := TFarProc(GetWindowLong(_HWND, GWL_WNDPROC));
        SetWindowLong(_HWND, GWL_WNDPROC, LongWord(@AppWndProc));
  end;
end;

initialization
  try
    Registrar;
  except
    Activar;
    Halt;
  end;

finalization
  if Mutex <> 0 then ReleaseMutex(Mutex);
end.

En la unit original Roman obtenia el HWND de la ventana actual accediendo mediante

Código Delphi [-]
  _HWND := Application.Handle;

Propiedad inexistente en FMX. El "chanchullo" aqui, no se me ocurrio otra cosa que crear el MainForm de la aplicacion, obtener el handle, y luego liberar el form. Feo pero funcional

En fin, si a alguien se le enciende la mejor por el bien de todos

Un saludo!
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Evitar doble instancia de nuestra aplicacion en ubuntu sierraja Lazarus, FreePascal, Kylix, etc. 2 02-05-2012 17:32:03
problema con las multiples sesiones de la unidad de Roman :( ivantj24 Varios 28 28-10-2011 20:08:00
Evitar 2 ejecuciones de mi aplicación. Unidad UIApp rafita Varios 8 16-01-2008 20:42:37
unidad equivalente para aplicacion CLX ctronx Varios 4 20-07-2004 03:37:09


La franja horaria es GMT +2. Ahora son las 16:33:29.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi