Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Gráficos
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 23-04-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool Capturar Imagen Con WebCam

Hola a todos los foreros

Se ha debatido demasiado sobre como capturar una foto desde una WebCam, y la mayoria de las respuestas coinciden con la utilizacion de un componente llamado TWain que es muy dificil de encontrar sino imposible. Otros han propuesto la utilizacion de un componente de la JVCL de la paleta JEDI denominado TJAviCapture. He tenido la posibilidad de probarlo y ver que funciona en D2009 pero resulto un poco engorrosa su aplicacion y dicho componente esta desarrollado para hacer mucho mas que capturar solo una foto WebCam, por eso lo interesante de la sencillez del codigo descripto en este hilo. Solo pocos han preguntado como hacer una captura de una foto desde una WebCam sin objeto alguno. En este hilo tratare de explicar como se puede capturar una foto desde una WebCam utilizando unos comandos de la API de Windows cuyas principales funciones y procedimientos estan descriptos en este archivo WIN32S.HLP.
Por razones de practicidad vamos a encapsular todo el codigo necesario para realizar dicha tarea en una Unit.pas que nos definira un componente propio. El siguiente codigo deben colocarlo dentro de una unit.

Código Delphi [-]
 
unit Webcam;
interface
uses
  Windows, Messages;
type
  TWebcam = class
    constructor Create(
      const WindowName: String = '';
      ParentWnd: Hwnd = 0;
      Left: Integer = 0;
      Top: Integer = 0;
      Width: Integer = 0;
      height: Integer = 0;
      Style: Cardinal = WS_CHILD or WS_VISIBLE;
      WebcamID: Integer = 0);
    public
      const
        WM_Connect     = WM_USER + 10;
        WM_Disconnect  = WM_USER + 11;
        WM_GrabFrame   = WM_USER + 60;
        WM_SaveDIB     = WM_USER + 25;
        WM_Preview     = WM_USER + 50;
        WM_PreviewRate = WM_USER + 52;
        WM_Configure   = WM_USER + 41;
    public
      procedure Connect;
      procedure Disconnect;
      procedure GrabFrame;
      procedure SaveDIB(const FileName: String = 'webcam.bmp');
      procedure Preview(&on: Boolean = True);
      procedure PreviewRate(Rate: Integer = 42);
      procedure Configure;
    private
      CaptureWnd: HWnd;
  end;
implementation
function capCreateCaptureWindowA(
  WindowName: PChar;
  dwStyle: Cardinal;
  x,y,width,height: Integer;
  ParentWin: HWnd;
  WebcamID: Integer): Hwnd; stdcall external 'AVICAP32.dll';
{ TWebcam }
procedure TWebcam.Configure;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_Configure, 0, 0);
end;
procedure TWebcam.Connect;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_Connect, 0, 0);
end;
constructor TWebcam.Create(const WindowName: String; ParentWnd: Hwnd; Left, Top,
  Width, height: Integer; Style: Cardinal; WebcamID: Integer);
begin
  CaptureWnd := capCreateCaptureWindowA(PChar(WindowName), Style, Left, Top, Width, Height,
    ParentWnd, WebcamID);
end;
procedure TWebcam.Disconnect;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_Disconnect, 0, 0);
end;
procedure TWebcam.GrabFrame;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_GrabFrame, 0, 0);
end;
procedure TWebcam.Preview(&on: Boolean);
begin
  if CaptureWnd <> 0 then
    if &on then
      SendMessage(CaptureWnd, WM_Preview, 1, 0)
    else
      SendMessage(CaptureWnd, WM_Preview, 0, 0);
end;
procedure TWebcam.PreviewRate(Rate: Integer);
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_PreviewRate, Rate, 0);
end;
procedure TWebcam.SaveDIB(const FileName: String);
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_SaveDIB, 0, Cardinal(PChar(FileName)));
end;
end.

Salven la unit como WebCam

Como pueden observar el codigo esta basado puramente en la API de Win, y entendemos que se trata de enviar o recibir mensajes asi que esa parte no debe darnos problemas. La funcion especifica en cuestion es la denominada capCreateCaptureWindowA, que a continuacion veremos que dice la ayuda de la API.

The capCreateCaptureWindow function creates a capture window.
Código Delphi [-]
 
HWND VFWAPI capCreateCaptureWindow(
    LPCSTR lpszWindowName, 
    DWORD dwStyle, 
    int x, 
    int y, 
    int nWidth, 
    int nHeight, 
    HWND hWnd, 
    int nID 
   );
Parameters
lpszWindowName
Null-terminated string containing the name used for the capture window.
dwStyle
Window styles used for the capture window. Window styles are described with the CreateWindowEx function.
x and y
The x- and y-coordinates of the upper left corner of the capture window.
nWidth and nHeight
Width and height of the capture window.
hWnd
Handle of the parent window.
nID
Window identifier.

Return Values
Returns a handle of the capture window if successful or NULL otherwise.

A continuacion un ejemplo de como implementarla en una aplicacion desarrollada en Delphi.

Paso 1 - Creamos una nueva aplicacion
File -> New -> VCL Forms Applications - Delphi.

Paso 2 - Creamos nuestro objeto en una nueva unit
File -> New -> Unit - Delphi
Copiamos el codigo aqui descripto y luego salvamos esta Unit como WebCam

Paso 3 - Diseño de la Form1
En nuestra Form colocamos un TPanel, con las siguientes dimensiones with 640 heigh 480, una TImage y dos TButton, uno tendra en su caption Encender y el otro Tomar Foto.

Paso 4 - Codigo para hacer funcionar la captura
En el Uses agregaremos WebCam
Código Delphi [-]
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, ComCtrls, StdCtrls, Webcam;

En el evento OnCreate de nuestra Form pondremos lo siguiente.
Código Delphi [-]
 
.....
.....
.....
  private
    { Private declarations }
  public
    { Public declarations }
    camera: TWebcam;
  end;
var
  Form1: TForm1;
implementation
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  camera := TWebcam.Create('WebCaptured', Panel1.Handle, 0, 0,
    1000, 1000);
end;

Este codigo sera para el boton de encendido o apagado de la camara

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
const
  str_Connect = 'Encender la camara';
  str_Disconn = 'Apagar la camara';
begin
  if (Sender as TButton).Caption = str_Connect then  begin
    camera.Connect;
    camera.Preview(true);
    Camera.PreviewRate(4);
    (Sender as TButton).Caption:=str_Disconn;
  end
  else begin
    camera.Disconnect;
    (Sender as TButton).Caption:=str_Connect;
  end;
end;


Y este codigo para el boton de captura de la foto

Código Delphi [-]
 
procedure TForm1.Button2Click(Sender: TObject);
var
  PanelDC: HDC;
begin
if not Assigned(Image1.Picture.Bitmap) then
    Image1.Picture.Bitmap := TBitmap.Create
  else
  begin
    Image1.Picture.Bitmap.Free;
    Image1.picture.Bitmap := TBitmap.Create;
  end;
  Image1.Picture.Bitmap.Height := Panel1.Height;
  Image1.Picture.Bitmap.Width  := Panel1.Width;
  Image1.Stretch := True;
  PanelDC := GetDC(Panel1.Handle);
  try
    BitBlt(Image1.Picture.Bitmap.Canvas.Handle,
      0,0,Panel1.Width, Panel1.Height, PanelDC, 0,0, SRCCOPY);
  finally
    ReleaseDC(Handle, PanelDC);
  end;
end;

Aqui podemos observar que aparece una segunda funcion API de Win que hace el resto del trabajo, esta funcion es
Código Delphi [-]
BitBlt
y su explicacion es la siguiente

The BitBlt function performs a bit-block transfer of the color data corresponding to a rectangle of pixels from the specified source device context into a destination device context.
BOOL BitBlt(
HDC hdcDest, // handle to destination device context
int nXDest, // x-coordinate of destination rectangle's upper-left corner
int nYDest, // y-coordinate of destination rectangle's upper-left corner
int nWidth, // width of destination rectangle
int nHeight, // height of destination rectangle
HDC hdcSrc, // handle to source device context
int nXSrc, // x-coordinate of source rectangle's upper-left corner
int nYSrc, // y-coordinate of source rectangle's upper-left corner
DWORD dwRop // raster operation code
);

Parameters
hdcDest
Identifies the destination device context.
nXDest
Specifies the logical x-coordinate of the upper-left corner of the destination rectangle.
nYDest
Specifies the logical y-coordinate of the upper-left corner of the destination rectangle.
nWidth
Specifies the logical width of the source and destination rectangles.
nHeight
Specifies the logical height of the source and the destination rectangles.
hdcSrc
Identifies the source device context.
nXSrc
Specifies the logical x-coordinate of the upper-left corner of the source rectangle.
nYSrc
Specifies the logical y-coordinate of the upper-left corner of the source rectangle.
dwRop
Specifies a raster-operation code. These codes define how the color data for the source rectangle is to be combined with the color data for the destination rectangle to achieve the final color.
The following list shows some common raster operation codes:
Value Description
BLACKNESS Fills the destination rectangle using the color associated with index 0 in the physical palette. (This color is black for the default physical palette.)
DSTINVERT Inverts the destination rectangle.
MERGECOPY Merges the colors of the source rectangle with the specified pattern by using the Boolean AND operator.
MERGEPAINT Merges the colors of the inverted source rectangle with the colors of the destination rectangle by using the Boolean OR operator.
NOTSRCCOPY Copies the inverted source rectangle to the destination.
NOTSRCERASE Combines the colors of the source and destination rectangles by using the Boolean OR operator and then inverts the resultant color.
PATCOPY Copies the specified pattern into the destination bitmap.
PATINVERT Combines the colors of the specified pattern with the colors of the destination rectangle by using the Boolean XOR operator.
PATPAINT Combines the colors of the pattern with the colors of the inverted source rectangle by using the Boolean OR operator. The result of this operation is combined with the colors of the destination rectangle by using the Boolean OR operator.
SRCAND Combines the colors of the source and destination rectangles by using the Boolean AND operator.
SRCCOPY Copies the source rectangle directly to the destination rectangle.
SRCERASE Combines the inverted colors of the destination rectangle with the colors of the source rectangle by using the Boolean AND operator.
SRCINVERT Combines the colors of the source and destination rectangles by using the Boolean XOR operator.
SRCPAINT Combines the colors of the source and destination rectangles by using the Boolean OR operator.
WHITENESS Fills the destination rectangle using the color associated with index 1 in the physical palette. (This color is white for the default physical palette.)

Return Values
If the function succeeds, the return value is nonzero.
If the function fails, the return value is zero. To get extended error information, call GetLastError.
Remarks
If a rotation or shear transformation is in effect in the source device context, BitBlt returns an error. If other transformations exist in the source device context (and a matching transformation is not in effect in the destination device context), the rectangle in the destination device context is stretched, compressed, or rotated as necessary.
If the color formats of the source and destination device contexts do not match, the BitBlt function converts the source color format to match the destination format.
When an enhanced metafile is being recorded, an error occurs if the source device context identifies an enhanced-metafile device context.
Not all devices support the BitBlt function. For more information, see the RC_BITBLT raster capability entry in GetDeviceCaps.
BitBlt returns an error if the source and destination device contexts represent different devices.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #2  
Antiguo 23-04-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool Espero comentarios

Espero que este codigo les haya sido de utilidad y voy a estar esperando por correcciones, sugerencias y todo aquello que pueda ayudar a ampliar la info en este hilo para aquellos que realizan futuras busquedas sobre este tema.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #3  
Antiguo 23-04-2010
Avatar de Lord Delfos
Lord Delfos Lord Delfos is offline
Miembro
 
Registrado: ene 2008
Ubicación: Tandil, Argentina
Posts: 558
Poder: 17
Lord Delfos Va por buen camino
Cita:
Empezado por casacham Ver Mensaje
Espero que este codigo les haya sido de utilidad y voy a estar esperando por correcciones, sugerencias y todo aquello que pueda ayudar a ampliar la info en este hilo para aquellos que realizan futuras busquedas sobre este tema.
Pues como corrección no tengo ninguna, porque no lo puedo probar por no tener WebCam... (sí, ya sé que estamos en el siglo XXI, pero bueno ).

Lo que sí te quería comentar es que quizás esto etaría bueno ponerlo en la sección "trucos" o quizás hacerce un ejemplito y subirlo al FTP.
Responder Con Cita
  #4  
Antiguo 23-04-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Va a estar en Trucos

Este codigo puede ser descargado desde Directorio raíz » Delphi » Ejemplos, deben buscar con el nombre WebCamCapture - API.zip
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto

Última edición por casacham fecha: 23-04-2010 a las 23:32:08.
Responder Con Cita
  #5  
Antiguo 23-04-2010
Avatar de Caral
[Caral] Caral is offline
Miembro Premium
 
Registrado: ago 2006
Posts: 7.659
Poder: 25
Caral Va por buen camino
Hola
No tengo en este momento la cámara pero lo voy a probar.
Lo mas importante es el aporte, gracias.
Saludos
__________________
Siempre Novato
Responder Con Cita
  #6  
Antiguo 24-04-2010
Avatar de radenf
radenf radenf is offline
Miembro
 
Registrado: oct 2007
Ubicación: Viña del Mar,Chile
Posts: 608
Poder: 17
radenf Va por buen camino
Estimado casacham :

He probado múltiples componentes para captura de video desde una webcam y el mejor resultado lo obtuve con BasicVideo. Siempre he querido independizarme de este componente y utilizar las Api de windows. Había probado con el codigo que se encuentra publicado en Delphimagic.blogspot.com, sin embargo con mi webcam Microsoft NX-6000 siempre obtengo una ventana de captura vacía en negro. La cámara se enciende y no genera tampoco el preview. Los mismos resultados obtengo con el código que aquí has publicado, que es similar al que mencioné anteriormente, aunque el tuyo es más comprensible y separa en dos Unit los códigos, lo que me parece más ordenado.
¿Este código debiera funcionar con cualquier cámara?
¿Se requiere alguna instrucción especial dependiendo del tipo de cámara?
Agradezco enormemente tu aporte, aunque no me haya servido, porque me hizo revisar este tema, que a la fecha no he logrado solucionar.

Salu2 y muchas gracias

Última edición por radenf fecha: 24-04-2010 a las 14:23:08.
Responder Con Cita
  #7  
Antiguo 01-05-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool En algun punto esta la clave

Hola radenf, la verdad es que el codigo lo he probado solo con las camaras incorporadas a las notebooks, y en todas las maquinas que he probado el codigo ha funcionado muy bien, no tengo experiencia con camaras accesorias o externas, en teoria deberia funcionar de la misma manera siempre y cuando sea una sola la camara activa. Espero que resuelvas tu problema y lo comentes aqui con nosotros para ayudar a quien busque esta informacion.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #8  
Antiguo 05-05-2010
JXJ JXJ is offline
Miembro
 
Registrado: abr 2005
Posts: 2.475
Poder: 21
JXJ Va por buen camino
Forbidden

You don't have permission to access /clubdelphi/archivos/Delphi/Ejemplos/WebCamCapture - API.zip on this server.

Additionally, a 404 Not Found error was encountered while trying to use an ErrorDocument to handle the request.
Apache/2 Server at www.terawiki.com Port 80

no se que paso.. da error al querer descargar el ejemplo
http://www.terawiki.clubdelphi.com/a...%20-%20API.zip
Responder Con Cita
  #9  
Antiguo 05-05-2010
fsolispa fsolispa is offline
Miembro
 
Registrado: sep 2008
Posts: 28
Poder: 0
fsolispa Va por buen camino
buena aportación

desde hace mucho estoy buscando algo parecido a lo que a cabas de comentar, hoy mismo hago la prueba, de antemano felicitaciones por tu iniciativa
Responder Con Cita
  #10  
Antiguo 05-05-2010
fsolispa fsolispa is offline
Miembro
 
Registrado: sep 2008
Posts: 28
Poder: 0
fsolispa Va por buen camino
Ya realice una prueba

no me da error en la compilación, me da error cuando lo ejecuto me dice que el tipo de clase no es valido (Invalid class typedcast) trabajo con delphi 2010, win7 y una camara muy antigua de logitec
Responder Con Cita
  #11  
Antiguo 06-05-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool Rtas.

Rta para JXJ: Hoy mismo intente entrar al FTP del foro y no me ha dejado, a veces suele caerse ese servicio. Te sugiero que leas bien lo que escribi arriba y sigas las indicaciones alli puestas, de esa forma podras crear tu mismo la unit en cuestion y aplicarla en tu proyecto y probar si funciona.

Rta. para fsolispa: Parece que con camaras externas tiene problemas el codigo, personalmente lo he probado en varias notebooks de diferentes marcas y en todas ha funcionado correctamente, pero cabe aclarar que dichos aparatos traen una camra web incorporada. Creo que necesitamos de la ayuda de gente experta en el tema para descubrir ese punto flojo en este codigo, tal vez Caral nos pueda dar una mano con eso.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #12  
Antiguo 09-05-2010
Avatar de kurono
[kurono] kurono is offline
Miembro Premium
 
Registrado: jul 2007
Ubicación: Republica Dominicana
Posts: 1.126
Poder: 18
kurono Va por buen camino
tambien puede servir este otro manual que esta compuesto por 3 partes

http://delphimagic.blogspot.com/2008...-delphi-i.html

http://delphimagic.blogspot.com/2008...delphi-ii.html

http://delphimagic.blogspot.com/2008...elphi-iii.html

Última edición por kurono fecha: 09-05-2010 a las 06:07:30.
Responder Con Cita
  #13  
Antiguo 13-05-2010
Avatar de sercornejov
sercornejov sercornejov is offline
Miembro
 
Registrado: may 2003
Ubicación: Neiva - Colombia
Posts: 88
Poder: 21
sercornejov Va por buen camino
Hola. Yo lo probé con D2010, Win 7 ultimate y una webcam creative de hace años, de conexión USB. Funciona sí, pero no del todo...

Se compilo sin problemas
Se ejecuto de la siguiente forma:

Abre el form1 pero el Timage queda negro. al pulsar en encender una vez, no pasa nada, pero si le das clic de nuevo se enciende la cámara pero la imagen se ve solo en la esquina superior izquierda del Timage.

Al pulsar el botón TOMAR FOTO, no aparece la imagen tomada, pero en el Paso a Paso, se puede constatar que si genera la imagen

Lo que hice fue colocar el TImagen fuera del TPanel y la imagen aparece inmediatamente. También hice CASO, fui Obediente y coloque en el primer botón el Caption que dice Casacham y todo funciona a las 1000 maravillas.

Voy a probarlo con imagenes JPG, pues en mi caso necesito poder gusrdarlo en una base de datos y BMP, pues no...

GRACIAS A CASACHAM por este aporte, oo's gracias...
__________________
En Colombia hay muchos, pero muchos colombianos muy buenos. Los violentos son pocos y los vamos a controlar...
Responder Con Cita
  #14  
Antiguo 01-06-2010
Avatar de yapt
yapt yapt is offline
Miembro
 
Registrado: sep 2006
Ubicación: España
Posts: 258
Poder: 18
yapt Va por buen camino
Bueno, yo estoy probando en un:

- Windows Vista
- Portatil ACER con cámara Cristal Eye (incluida en el portatil).

Ejecuto la aplicación (el .exe) WebCamCapture.exe y la imagen sale en negro. Siempre.

Pero me sucede lo mismo con el ejemplo simple de:
Y lo mismo con la aplicación de sensor de movimiento de AJPDSoft:

http://www.ajpdsoft.com/modules.php?...rticle&sid=263

Debo decir que mi Skype funciona a las mil maravillas... :-( Sic...

Alguien tiene una "remota" idea de qué puede ser ?

Saludos.
Responder Con Cita
  #15  
Antiguo 02-06-2010
Avatar de yapt
yapt yapt is offline
Miembro
 
Registrado: sep 2006
Ubicación: España
Posts: 258
Poder: 18
yapt Va por buen camino
Bueno, parece que en el único ordenador del mundo en el que la "Ventana de captura" se ve mal, es el mio de desarrollo.

Incluso si capturo un "fotograma" del video de la webcam, se captura correctamente. Simplemente no se ve el movimiento en tiempo real.



Saludos.
Responder Con Cita
  #16  
Antiguo 16-06-2010
Nekopuka Nekopuka is offline
Registrado
 
Registrado: jun 2010
Posts: 2
Poder: 0
Nekopuka Va por buen camino
Actualizando las pruebas

Antes que nada, felicitaciones a casacham por el aporte, bueno les cuento lo que se:

Antes de toparme con este foro había probado varios componentes y tuve resultados con algunos de prueba en Windows XP 32 con Delphi 7. Después de migrar a Windows 7 64 y tras mucho respaldar archivos no logro encontrar dichos componentes. Ni modo a empezar otra vez .

He probado el código tal cuál dice casacham, al descomprimir el archivo todo el fuente y lo necesario está ahí. Ejecuto el exe que viene integrado y todo a las mil maravillas, pero al compilar yo mismo el código sin hacer cambio alguno, me da un error pero se soluciona con poner ";" después de stdcall en webcam.pas. Pero aún así sucede lo mismo del panel negro y nada de imagen ni de encendido de webcam .

Antes que modificar el código explico el porque del mal funcionamiento y como es que podría arreglarse para algunos, más no para mi todavía pués necesito utilizar una webcam externa.
Utilizo Delphi 2009 en Windows 7 Homepremium 64 en una Toshiba A505 (Laptop), ésta tiene una webcam integrada pero conecto además una webcam phillips CN700 algo ya viejita; hago notar que para que funcione en Windows 7 64 la webcam tiene que ser reconocida por el mismo windows Drivers y todo. Entonces ¿qué pasa con el código?

1. El Exe incluido funciona con ambas cámaras conectadas y manda un cuadro de diálogo en el cual podemos seleccionar el dispositivo al cual conectarnos .
2. El Exe generado de la recompilación no lo hace con ninguna, estando ambas conectadas .
3. Si desconectamos la webcam externa, cualquier Exe funciona y reconoce la cámara integrada en la laptop, pero ya no sale el cuadro de selección de dispositivo mencionado en el paso 1 .
4. Es obvio que no podemos quitar la cámara integrada sin desinstalar los drivers y es mucho rollo así que mejor no lo he intentado para probar con la cámara phillips externa únicamente.
5. De lo anterior podemos pensar que el problema radica en la llamada a la librería avicap32.dll.
6. ¿Habrá alguna forma de indicarle a la librería que queremos el dispositivo 0,1,2... (WebcamID supongo) en lugar de esperar a ver si reconoce cualquier dispositivo?, mejor aún, ¿qué valor es el que identifica cada dispositivo?, ya he probado los primeros valores 0..9 y nada y da lo mismo el valor que se introduzca si sólo hay una cámara en el equipo.

Espero podamos dar solución a esta interrogante.

Saludos a todos.
Responder Con Cita
  #17  
Antiguo 17-06-2010
Nekopuka Nekopuka is offline
Registrado
 
Registrado: jun 2010
Posts: 2
Poder: 0
Nekopuka Va por buen camino
Solucionado en Windows 7 64

Saludos a todos.

Pues con la nueva que después de desvelarme toda la noche buscando la solución al problema de la cámara, por fin pude encontrar el problema para recompilar el programa y que éste funcionara.

1. En Windows 7 es necesario dar privilegios de administrador al ejecutar Delphi 2009 (o la versión que usen). Por este pequeño detalle no servía nada de lo demás. Todo esto se cambia desde la UAC de windows, o simplemente dando click derecho sobre el exe de delphi, propiedades y activar la casilla Ejecutar este programa como administrador que se encuentra en la pestaña Compatibilidad.

2. Al parecer no basta con hacer esto, en algunos casos el archivo ejecutable generado por delphi tambien necesita de estos cambios y además de activar la casilla Ejecutar este programa en modo de compatibilidad para, y en el combobox de abajo seleccionar la opción Windows XP (Service Pack 2), que se encuentran en la misma pestaña Compatibilidad.

3. Si dan privilegios al archivo exe generado por delphi (nuestra aplicación), sin dar privilegios de administrador al Programa Delphi, se encontraran con una ventana molesta que no les dejará ejecutar el exe desde delphi, con el siguiente texto: Unable to create process: la operacion solicitada requiere elevación, o su equivalente en el idioma por defecto. Para solucionar esto hay que cerrar Delphi, asignarle derechos de asministrador al mismo Delphi y rearrancarlo; podrán darse cuenta que ya no sale la ventanita anterior y podrán ejecutar el exe con el clásico F9.

4. Una vez que Delphi y el exe de nuestra aplicación tienen derechos de administrador, podremos visualizar el contenido de la webcam externa o integrada del equipo.

Concluyendo:
Hechos estos cambios ya puedo recompilar la aplicación y el exe resultante funciona con ambas cámaras en mi laptop pero, cuando ambas están conectadas, ahora se selecciona la camara externa por default en lugar de la integrada.
Entonces la incógnita sigue siendo ¿Cómo indicarle al programa por código que quiero la cámara integrada o la externa teniendo ambas conectadas al equipo?

Creo que eso queda de tarea.

Hasta pronto.
Responder Con Cita
  #18  
Antiguo 11-08-2010
Fjchaveze Fjchaveze is offline
Registrado
 
Registrado: oct 2007
Posts: 2
Poder: 0
Fjchaveze Va por buen camino
stdcall external 'AVICAP32.dll';

en esta línea me marca error de syntaxis, al ponerle el punto y coma después de stdcall, ya no lo hace.

El problema es el siguiente en windows xp utilizando d2007, me marca un error de excepción al compilar y ejecutar el programa dentro del IDE.

De igual manera con vista y d2009 dentro del IDE.

El detalle es que si ejecuto directamente esta aplicación fuera del IDE funciona correctamente, habrá alguna forma de corregir este detalle?

Ya probe quitando el punto y coma,poniendolo también.
Responder Con Cita
  #19  
Antiguo 11-08-2010
Avatar de Caral
[Caral] Caral is offline
Miembro Premium
 
Registrado: ago 2006
Posts: 7.659
Poder: 25
Caral Va por buen camino
Hola

Saludos
__________________
Siempre Novato
Responder Con Cita
  #20  
Antiguo 30-01-2011
Avatar de MAXIUM
MAXIUM MAXIUM is offline
Miembro
 
Registrado: may 2005
Posts: 1.485
Poder: 20
MAXIUM Va camino a la fama
¿Se podrá capturar solo una porción de la imagen que se ve?

Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Webcam capturar imagen y adaptada ronald_tro Gráficos 18 14-12-2017 20:48:42
Capturar Fotografia desde Webcam ? martita Gráficos 11 13-12-2012 19:24:04
Capturar imagen webcam fmtidona Gráficos 4 25-11-2005 19:04:31
Capturar imagen de webcam en Monocromo fmtidona Gráficos 1 15-09-2005 23:18:49
Capturar imagen desde webcam wogshit Gráficos 1 03-06-2004 11:14:50


La franja horaria es GMT +2. Ahora son las 13:23:15.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi