¿Cómo poner varias imágenes en un TImage (En Delphi)?

[Ines Rodriguez]

Estoy utilizando Delphi y se que para poner una imagen en un TImage sería:

Código Delphi [-]
Image1.LoadFormFile("C:\imagen.jpg");

Pero lo que yo quiero es poner varias imágenes a la vez en el TImage, debido a que en el TImage igual dibuje líneas, entre otras figuras. ¿Podrían ayudarme? Por favor

[ecfisa]

Hola Ines Rodriguez.

Un componente TImage sólo puede contener una imágen. De modo que si deseas mostrar varias imágenes en él, deberás componer una imágen a partir de las demás y luego asignar la imágen compuesta al TImage.

A partir del gráfico no puedo entender que es lo que queres lograr. Si nos dijeras con todo detalle lo que estas buscando, con seguridad podamos darte respuestas mas concretas a tu consulta.

Saludos

[[nlsgarcia]]

Ines Rodriguez,

Empezado por Ines Rodriguez

...¿Cómo poner varias imágenes en un TImage (En Delphi)?...debido a que en el TImage igual dibuje líneas, entre otras figuras...

Pregunto: ¿Has considerado usar el TCanvas para dibujar y TImage solo para visualizar?.

Revisa esta información:

1- Dibujando con la clase TCanvas (I)

2- Dibujando con la clase TCanvas (II)

3- Dibujando con la clase TCanvas (y III)

4- Delphi Drawing (Parte 1, 2, 3 y 4)

5- Delphi Canvas Demonstration

6- ¿Cómo dibujar figuras parecidas a los quesitos del trivial?

Espero sea útil

Nelson.

[Ines Rodriguez]

Hola, si lo que quiero hacer es dibujar un diagrama como el que adjunto, creando lineas con:

Código Delphi [-]
  Image1.Canvas.MoveTo(x1,y1);
  Image1.Canvas.LineTo(x2,y2);

y usando MOUSEDOWN y MOUSEUP para sus coordenadas pero bueno aparte de eso quiero insertar las imágenes (descargadas de google NO dibujadas) como la computadora, el router etc. por medio de los botones, bueno por ejemplo si le doy en el boton linea pues dibujo una linea que seria representación del cable y así sucesivamente si le doy en el boton computadora me muestre dicha imagen y así sucesivamente con la impresora, el switch etc. hasta ir formando todo mi diagrama.

Les adjunto igual mi código por si no me supe explicar jeje Gracias por la ayuda de antemano

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, jpeg, Buttons;

type
  TForm1 = class(TForm)
    ScrollBox1: TScrollBox;
    Image1: TImage;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button7: TButton;
    Label1: TLabel;
    Label2: TLabel;
    Edit1: TEdit;
    SpeedButton1: TSpeedButton;
    Label3: TLabel;
    procedure SpeedButton1Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Image1MouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Image1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var   //variables globales
  Form1: TForm1;
  i,j,x1,y1,x2,y2 : Integer;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject); //FIBRA
begin
  Image1.Canvas.Pen.Color := RGB(250,150,0);  //Color naranja
  Image1.Canvas.Pen.Width := 5; //Ancho
  Image1.Canvas.MoveTo(x1,y1); //crea linea  segun coordenadas apuntadas
  Image1.Canvas.LineTo(x2,y2);

end;

procedure TForm1.Button2Click(Sender: TObject); //CABLE
begin
  Image1.Canvas.Pen.Color := RGB(50,50,50);  //Color negro
  Image1.Canvas.Pen.Width := 3; //Ancho
  Image1.Canvas.MoveTo(x1,y1); //crea linea  segun coordenadas apuntadas
  Image1.Canvas.LineTo(x2,y2);

end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  Image1.Picture.LoadFromFile('computadora.jpg');
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
Edit1.Text := '0';
Image1.Canvas.Rectangle(0,0,1000,1000);

for I := 1 to 20 do  //crea malla color gris
for J := 1 to 20 do
Image1.Canvas.Pixels[i*50,j*50] := RGB(150,150,150);
end;

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  x1 := X;
  y1 := Y;
end;

procedure TForm1.Image1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  x2 := X;
  y2 := Y;
end;

procedure TForm1.SpeedButton1Click(Sender: TObject);
begin
//SpeedButton1.Glyph.LoadFromFile('computadora.jpg');
end;

end.

[ecfisa]

Hola Inés.

Por favor cuando incluyas código delphi, enciérralo entre las etiquetas correspondientes de este modo:


(ya las agregué a tu mensaje)

Saludos y gracias por tu colaboración

[ecfisa]

Hola Inés.

Un ejemplo de como pienso que podrías implementar lo que estas buscando sobre el manejo de las imágenes.
El mismo usa un TImage por cada elemento a insertar (server, terminal, router, etc) que residen en un TScrollBox y como destino contenedor un TPanel.

Código Delphi [-]
...
implementation 

uses Contnrs;

var
  List: TObjectList;

procedure TForm1.FormCreate(Sender: TObject);
begin
  List := TObjectList.Create;
end;

procedure TForm1.ImageMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if ssCtrl in Shift then           // ¿ Presionó Ctrl ?
    TImage(Sender).BeginDrag(True); // Comenzar arrastre
end;

procedure TForm1.Panel1DragDrop(Sender, Source: TObject; X,
  Y: Integer);
var
  new: TImage;
begin
  new := TImage.Create(nil);
  new.Picture.Bitmap.Assign(TImage(Source).Picture.Bitmap);
  new.Parent := Panel1;
  new.Stretch:= True;
  new.Left   := X;
  new.Top    := Y;
  List.Add(new)
end;

procedure TForm1.Panel1DragOver(Sender, Source: TObject; X, Y: Integer;
  State: TDragState; var Accept: Boolean);
begin
  Accept := (Source is TImage);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  List.Free;
end;

El resultado es este:


Como mencionaste que usas la clase TCanvas para dibujar las conexiones, previamente deberás interponer la clase TPanel y publicar la propiedad Canvas para poder usarla en él:

Código Delphi [-]
...

type
  // Aquí :
  TPanel = class(ExtCtrls.TPanel)
  public
    property Canvas; 
  end;

  TForm1 = class(TForm)
    ScrollBox1: TScrollBox;
    Panel1: TPanel;
    Image1: TImage;
    Image2: TImage;
    Image3: TImage;
    ...

Saludos

[Ines Rodriguez]

Hola ecfisa.
Me has ayudado demasiado enserio muchas gracias. Bonita noche.