Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Otros temas > Trucos
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Los mejores trucos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 25-07-2007
Avatar de MaMu
MaMu MaMu is offline
Miembro
 
Registrado: abr 2006
Ubicación: Argentina
Posts: 863
Poder: 18
MaMu Va por buen camino
Copiar archivos con barra de Progreso

Dado que siempre hay alguien que busca como copiar archivos con barra de progreso (Progressbar), aqui les dejo un ejemplo de uso de la WinApi CopyFileEx.
Si lo quieren probar, creen un formulario y ponga 2 botones y una barra de progreso, las demas cosas queda a criterio del lector.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    ProgressBar1: TProgressBar;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  CancelCopy: Boolean; 

implementation
function CopyFileProgress(TotalFileSize, TotalBytesTransferred, StreamSize, 
  StreamBytesTransferred: LARGE_INTEGER; dwStreamNumber, dwCallbackReason, 
  hSourceFile, hDestinationFile, lpData: DWORD): DWORD; stdcall; 
begin
  Application.ProcessMessages; 
  if CancelCopy = True then 
  begin 
    ShowMessage('Cancelado'); 
    result := PROGRESS_CANCEL;
    Exit;
  end; 
  case dwCallbackReason of 
    CALLBACK_CHUNK_FINISHED: 
      begin
        Form1.ProgressBar1.Position := TotalBytesTransferred.QuadPart; 
        result := PROGRESS_CONTINUE; 
      end; 
    CALLBACK_STREAM_SWITCH: 
      begin 
        Form1.ProgressBar1.Max := TotalFileSize.QuadPart; 
        result := PROGRESS_CONTINUE; 
      end; 
  end; 
end; 

{$R *.dfm}

//Ejemplo de llamada y copia
procedure TForm1.Button1Click(Sender: TObject);
var
  Cancel: PBOOL;
  origen,destino:string;
begin 
  CancelCopy := False;
  Cancel := nil;
  origen:='C:\miruta\archivo.dat';
  destino:='C:\miotraruta\archivo.dat';
  CopyFileEx(pChar(origen), pChar(destino),@CopyFileProgress, nil, Cancel, 0); 
end;

//Cancelamos la copia
procedure TForm1.Button2Click(Sender: TObject);
begin
  CancelCopy := True;
end;

end.
Responder Con Cita
  #2  
Antiguo 12-08-2007
Avatar de cHackAll
[cHackAll] cHackAll is offline
Baneado?
 
Registrado: oct 2006
Posts: 2.159
Poder: 20
cHackAll Va por buen camino
El uso de un ProgressBar con el tamaño total de un archivo funciona siempre y cuando éste no sobrepase los 2147483647 bytes, (~2 Gb), dejo mis correcciónes aconsejando usar un hilo para no "perjudicar" al hilo principal:

Código Delphi [-]
...

implementation

{$R *.dfm}

var Cancel: LongBool;

function ProgressRoutine(TotalFileSize, TotalBytesTransferred, StreamSize, StreamBytesTransferred: Int64; dwStreamNumber, dwCallbackReason, hSourceFile, hDestinationFile: Cardinal; lpData: Pointer): Cardinal; stdcall;
var Value: Cardinal;
begin
 Application.ProcessMessages;
 case dwCallbackReason of
  CALLBACK_CHUNK_FINISHED: Form1.ProgressBar1.Position := (TotalBytesTransferred * 100) div TotalFileSize;
//  CALLBACK_STREAM_SWITCH: Form1.ProgressBar1.Max := 100;
 end;
 Result := PROGRESS_CONTINUE;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
 CopyFileEx('F:\DVD\Prince of Persia\Prince of Persia (The two thrones).mdf', 'e:\Dummy.mdf', @ProgressRoutine, nil, @Cancel, 0);
 ShowMessage(SysErrorMessage(GetLastError));
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
 Cancel := True;
end;

end.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro


La franja horaria es GMT +2. Ahora son las 08:26:56.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi