Ver Mensaje Individual
  #1  
Antiguo 10-10-2012
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Reputación: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Archivos INI con codificación Unicode, UTF8, etc.

Hola,

Sólo quería aportar algo que quizá sea de conocimiento común. Se trata de trabajar con archivos INI en una codificación de caracteres diferente a la predeterminada, esto es, "ANSI". La clase "TIniFile" (Implementada en la unidad "IniFiles") no soporta (a fecha de hoy) otra codificación diferente a la referida, empero, en la misma unidad que dicha clase existe otra de nombre "TMemIniFile", que nos permite especificar, desde el mismo constructor, la codificación que queremos utilizar al trabajar con el archivo INI.

Supón que estás usando un archivo INI para guardar "búsquedas" que realiza el usuario de tu programa. Si tu programa usa una versión Delphi con soporte para Unicode (a partir de Delphi 2009) el usuario podrá utilizar caracteres Unicode para realizar sus búsquedas, y, el archivo INI deberá guardar dichos caracteres, de manera que no se "pierdan" al tener que reducirse a la codificación "ANSI". Pues bien, este es un ejemplo en el que la clase "TMemIniFile" nos vendrá de perillas. Por lo demás, esta clase "funciona" exactamente igual a "TIniFile".

Si acaso añadir un pequeño detalle más que, al menos en Delphi XE2, ocurre. La clase "TIniFile" "guarda" el archivo INI cuando se libera el objeto correspondiente, sin embargo, la clase "TMemIniFile" no lo hace así. Pero, para esto existe un método (en ambas clases además) de nombre "UpdateFile", que, podrás utilizar para que la clase "TMemIniFile" actualize el archivo INI con el que esté asociada. También me gustaría añadir que deberás usar (tal vez no estrictamente, pero, sí por lo general, me atrevería a decir) la misma codificación de caracteres, tanto cuando abras el archivo INI para leerlo, como cuando escribas en el mismo.

A continuación un sencillo ejemplo de uso de la clase "TMemIniFile":

Código Delphi [-]
class procedure TInterfaceConfig.LoadConfig();
begin
  with TMemIniFile.Create( self.GetInterfaceIniFilePath(), TEncoding.Unicode ) do
  try
    Language := ReadString( I18N_SECTION, LANGUAGE_VALUE, DEFAULT_LANGUAGE );
    ActiveTheme := ReadString( THEME_SECTION, NAME_VALUE, DEFAULT_THEME_NAME );
    EditorTab := ReadInteger( OPTIONSFORM_SECTION, EDITOR_TAB_VALUE, DEFAULT_EDITOR_TAB );
    OptionsTab := ReadInteger( OPTIONSFORM_SECTION, OPTIONS_TAB_VALUE, DEFAULT_OPTIONS_TAB );
    MainFormTop := ReadInteger( MAINFORM_SECTION, TOP_VALUE, DEFAULT_MAINFORM_TOP );
    MainFormLeft := ReadInteger( MAINFORM_SECTION, LEFT_VALUE, DEFAULT_MAINFORM_LEFT );
    MainFormWidth := ReadInteger( MAINFORM_SECTION, WIDTH_VALUE, DEFAULT_MAINFORM_WIDTH );
    MainFormHeight := ReadInteger( MAINFORM_SECTION, HEIGHT_VALUE, DEFAULT_MAINFORM_HEIGHT );
    MainFormWindowState := ReadInteger( MAINFORM_SECTION, WINDOW_STATE_VALUE, DEFAULT_MAINFORM_WINDOW_STATE );
  finally
    Free();
  end;
end;

class procedure TInterfaceConfig.SaveConfig();
begin
  with TMemIniFile.Create( self.GetInterfaceIniFilePath(), TEncoding.Unicode ) do
  try
    WriteString( I18N_SECTION, LANGUAGE_VALUE, Language );
    WriteInteger( MAINFORM_SECTION, TOP_VALUE, MainFormTop );
    WriteInteger( MAINFORM_SECTION, LEFT_VALUE, MainFormLeft );
    WriteInteger( MAINFORM_SECTION, WIDTH_VALUE, MainFormWidth );
    WriteInteger( MAINFORM_SECTION, HEIGHT_VALUE, MainFormHeight );
    WriteInteger( MAINFORM_SECTION, WINDOW_STATE_VALUE, MainFormWindowState );
    WriteString( THEME_SECTION, NAME_VALUE, TStyleManager.ActiveStyle.Name );
    WriteInteger( OPTIONSFORM_SECTION, EDITOR_TAB_VALUE, EditorTab );
    WriteInteger( OPTIONSFORM_SECTION, OPTIONS_TAB_VALUE, OptionsTab );
    UpdateFile();
  finally
    Free();
  end;
end;

Espero que este truco pueda resultar útil a alguien en algún momento.
Responder Con Cita