[[nlsgarcia]]

ZayDun,

Empezado por ZayDun

...tengo un listview con 3 columnas [Usuario] - [Puntos] - [Fecha]...muestro la lista de usuarios y cuando quiero cargar los puntos no se como indicarle que los cargue en el SubItems "[Puntos]"...

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    ListView1: TListView;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin

   ListView1.ViewStyle := vsReport;

   ListView1.Columns.add;
   ListView1.Columns[0].caption := '';
   ListView1.Columns[0].Width := 0;

   ListView1.Columns.add;
   ListView1.Columns[1].caption := 'Usuarios';
   ListView1.Columns[1].Width := 200;

   ListView1.Columns.add;
   ListView1.Columns[2].caption := 'Puntos';
   ListView1.Columns[2].Width := 200;

   ListView1.Columns.add;
   ListView1.Columns[3].caption := 'Fechas';
   ListView1.Columns[3].Width := 200;

end;

procedure TForm1.Button1Click(Sender: TObject);
var
   i : Integer;
begin

   ListView1.Clear;
   for i := 1 to 10 do
      with ListView1.Items.Add do
      begin
         Subitems.Add('Usuario-' + IntToStr(i));
         Subitems.Add('');
         Subitems.Add('');
      end;

end;

procedure TForm1.Button2Click(Sender: TObject);
var
   i : Integer;

begin

   for i := 0 to ListView1.Items.Count - 1 do
      with ListView1.Items[i]do
      begin
         Subitems.Strings[1] := 'Punto-' + IntToStr(i+1);
         Subitems.Strings[2] := 'Fecha-' + IntToStr(i+1) + '  ' + DateToStr(Now);
      end;

end;

end.

El código anterior crea tres columnas en un componente TListView, cargando primero los datos de la columna 1 (Usuarios) y luego los datos de las columnas 2 y 3 (Puntos y Fechas).

Espero sea útil

Nelson.