Asignación de un evento en tiempo de ejecución.
Programar eventos desde el IDE es muy fácil. Basta ir al Inspector de Objetos en la pestaña de Eventos y hacer doble-click sobre el evento deseado del objeto en cuestión. Pero, también es muy fácil asignar eventos en tiempo de ejecución. Veámoslo con un ejemplo.
Vamos a asignarle un mismo evento al evento OnClick de tres TButton distintos.
Sobre un formulario nuevo, depositad 1 TLabel y 3 TButton. En la parte privada, haremos la declaración de nuestro evento personal al que llamaremos MiOnClick. En el evento OnCreate del formulario, es donde asignaremos nuestro nuevo evento. La declaración del formulario quedará tal que así:
Código Delphi
[-]
TForm1 = class(TForm)
Button1: TButton;
Button2: TButton;
Button3: TButton;
Label1: TLabel;
procedure FormCreate(Sender: TObject);
private
procedure MiOnClick(Sender: TObject);
end;
La parte de código será:
Código Delphi
[-]
procedure TForm1.MiOnClick(Sender: TObject);
begin
Label1.Caption:= (Sender as TButton).Caption;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
Button1.OnClick:= MiOnClick;
Button2.OnClick:= MiOnClick;
Button3.OnClick:= MiOnClick;
end;
Pero, qué pasa si nuestro evento no es el OnClick. Para resolver esto, hay que ir a la ayuda del Delphi y comprobar la declaración del evento que queremos crear. Por ejemplo, imaginaos el evento OnDragDrop. Vamos a la ayuda y encontramos:
Código Delphi
[-]
TDragDropEvent = procedure(Sender, Source: TObject; X, Y: Integer) of object;
Sólo hay que declarar en la parte privada del formulario algo parecido a:
Código Delphi
[-]
procedure MiDragDrop(Sender, Source: TObject; X, Y: Integer);
Y ya se lo podremos asignar a cualquier componente:
Código Delphi
[-]
Button1.OnDragDrop:= MiDragDrop;
El evento nuevo, normalmente se declarará en la parte privada. Pero si lo cambiamos a la parte donde están declarados los eventos asignados desde el IDE, lo podremos asignar en tiempo de diseño también. Para probar lo que digo, eliminad la palabra "private" del ejemplo anterior. Id al Inspector de Objetos y pinchad en el combo perteneciente al evento OnClick de cualquier botón. Podréis comprobar que aparece allí nuestro evento.
Por lo tanto, se le puede asignar a tantos botones como deseemos en el mismo tiempo de diseño.