El problema es que el control ListView de Delphi no expone los eventos necesarios para pintar los encabezados.
El HeaderControl sí expone el evento OnCustomDraw para tal efecto pero tratar de sustituir el encabezado de un ListView por uno propio puede tornarse muy complicado para sincronizarlo con las columnas.
La manera en que he visto que logran esto es haciendo uso del siguiente hecho: cuando Windows debe pintar el header, manda un mensaje WM_NOTIFY a la ventana padre- en este caso el ListView -con información relacionada a la etapa de dibujado.
Para captar este mensaje, lo ideal sería crear una componente derivada de TListView; pero para fines prácticos podemos usar el viejo truco de la "componente usurpadora":
Código Delphi
[-]
type
TListView = class(ComCtrls.TListView)
private
procedure WMNotify(var Msg: TWMNotify); message WM_NOTIFY;
end;
TForm1 = class(TForm)
ListView1: TListView;
...
end;
Esto es, se declara en la misma unidad que el formulario que contiene al ListView y antes de la declaración de éste, una clase del mismo nombre de la componente que nos interesa que descienda de ella. Esta nueva clase "usurpa" la original haciendo que la componente insertada en el formulario adquiera la nueva funcionalidad.
Para la implementación de WMNotify debemos incluir la unidad CommCtrl (no confundir con ComCtrls) para la definición de las estructuras de datos y constantes necesarias.
La implementación es sencilla:
Código Delphi
[-]
procedure TListView.WMNotify(var Msg: TWMNotify);
var
Header: HWnd;
CustomDraw: PNMCustomDraw;
begin
Header := Perform(LVM_GETHEADER, 0, 0);
if (Msg.NMHdr.code = NM_CUSTOMDRAW) and (Msg.NMHdr.hwndFrom = Header) then
begin
CustomDraw := PNMCustomDraw(Msg.NMHdr);
case CustomDraw.dwDrawStage of
CDDS_PREPAINT:
Msg.Result := CDRF_NOTIFYITEMDRAW;
CDDS_ITEMPREPAINT:
if CustomDraw.dwItemSpec = 1 then
Windows.SetBkColor(CustomDraw.hdc, $00FF8080);
end;
end;
end;
// Saludos