Cita:
Empezado por GerTorresM
vamos a aplicar el TStringList !
|
Pero no puedes aplicarlo directamente. La clase TStrings no posee el método Find por lo cual no puedes usarlo ni siquiera através de un moldeo. Esto funcionaría si TStrings tuviera el método Find pero estuviera protegido (creo que en esto pensaba
Neftali).
En lo personal, si estás manejando listas relativamente cortas yo usaría un ListBox y su método IndexOf, que, aunque secuencial, será suficiente si la lista no es muy grande.
En caso de tener listas muy grandes, sería mejor optar por lo que apunta
AgustinOrtu, y puede hacerse de forma sencilla:
- Usas un ListBox en modo virtual (propiedad Style = lbVirtual)
- Usas un TStringList aparte. Éste podrías declararlo en tu formulario y crearlo y destruirlo con él:
Código Delphi
[-]
interface
type
TForm1 = class(TForm)
ListBox1: TListBox;
private
Lista: TStringList;
end;
implementation
procedure TForm1.FormCreate(Sender: TObject);
begin
Lista := TStringList.Create;
Lista.Sorted := true;
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
Lista.Free;
end;
- Al agregar un elemento usas el método Add del TStringList:
Código Delphi
[-]
procedure TForm1.Agregar(S: String);
begin
Lista.Add(S);
ListBox1.Count := Lista.Count;
end;
Observa que estás agregando directamente al TStringList y no al ListBox, pero debes actualizar la propiedad Count del ListBox para que éste sepa cuántos elementos debe dibujar.
- Para buscar un elemento, ahora sí, usas el método Find:
Código Delphi
[-]
procedure TForm1.Buscar(S: String);
var
I: Integer;
begin
if Lista.Find(S, I) then
ListBox1.ItemIndex := I;
end;
- Finalmente, para que el ListBox refleje la información del TStringList, usas su evento OnData:
Código Delphi
[-]
procedure TForm1.ListBox1Data(Control: TWinControl; Index: Integer; var Data: String);
begin
Data := Lista[Index];
end;
LineComment Saludos