Pintar DBGrid
 

Hola a todos.

Como eterno novato me ha surgido un problema que no encuero como solucionar.

Tengo un DBGrid el cual cargo con una tabla de Access a través de ADO.

Para hacer mas fácil la interpretación de los datos pinto las lineas una si otra no en gris, y la celda seleccionada la pinto en azul.
todo esto lo hago a través de DrawColumnCell del DBGrid.
usando el codigo.

Código Delphi [-]
rocedure TfrmWebpost.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  grid : TDBGrid;
  row : integer;
begin
 if length(Column.Field.AsString) > Column.Field.Tag then
  begin
    Column.Field.Tag := length(Column.Field.AsString);
    Column.Field.DisplayWidth := Column.Field.Tag + 1;
  end;
  grid := sender as TDBGrid;
  row := grid.DataSource.DataSet.RecNo;
   if Odd(row) then
    grid.Canvas.Brush.Color := clSilver
   else
    grid.Canvas.Brush.Color := clwhite;
    grid.DefaultDrawColumnCell(Rect, DataCol, Column, State) ;

  if (gdSelected in State) then
   begin
    Grid.Canvas.Brush.Color := clAqua;
    Grid.SelectedRows.CurrentRowSelected := true;
   end;

  Grid.DefaultDrawColumnCell(Rect, DataCol, Column, State);
end;

El problema surge que no siempre al iniciar el select lo posiciona en la primera celda. sino que lo coloca en la primera columna pero en una fila intermedia. cuando pulso en alguna celda no me lo indica correctamente, lo que hace es moverse dentro de la fina en que se encuentra.

Pero lo mas curioso es que cuando selecciono una celda que se encuentra por debajo de donde esta la marca de selección. ya empieza realizar todo correctamente.

Alguna idea o sugerencia???????

Un saludo y gracias de antemano.

Como no se si me he explicado muy bien.

tengo un pequeño ejemplo para cargar tanto Excel como Access. en el cual se puede ver el efecto.

Veo que utilizas dos métodos de DBGrid que no deben utilizarse juntos...

De la ayuda de Delphi 6:
Note: If the Columns property has a State property of csDefault, the OnDrawDataCell event occurs before the OnDrawColumnCell. The OnDrawDataCell event is obsolete, and only included for backward compatibility. Do not set both an OnDrawDataCell event handler and an OnDrawColumnCell event handler.

Por otro lado, llamas a DefaultDrawColumnCell solo si se cumple la última condición.
Creo que esto deberías dejarlo fuera de la condición.

Código Delphi [-]
procedure TFrmPrincipal.DBGrid1DrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);
Var
  Grid         : TStringGrid; // Esto debería ser TDBGrid(Sender)
  Texto        : String;
  Rectangulo   : TRect; // Esto no se necesita. Es lo mismo que el parametro Rect
begin
  //************** Auto Ancho *********************//
  if length(Column.Field.AsString) > Column.Field.Tag then
  begin
    Column.Field.Tag := length(Column.Field.AsString);
    Column.Field.DisplayWidth := Column.Field.Tag + 1;
  end;

  if (gdSelected in State) then
  begin
    // Color Celda Seleccionada
    DBGrid1.Canvas.Font.Color := clWhite;
    DBGrid1.Canvas.Brush.Color := clNavy;
    DBGrid1.Canvas.FillRect(Rect);
    DBGrid1.Canvas.TextOut(Rect.Left, Rect.Top,Column.Field.AsString);
  end
  else
  begin
    // Color resto de celdas
    if Column.FieldName = ComboBox2.Text then
      (Sender as TDBGrid).Canvas.Font.Color := clRed;

    (Sender as TDBGrid).Canvas.TextRect(Rect, Rect.Left + 2, Rect.Top + 2, Column.Field.AsString);

    // Codigo de DBGrid1DrawDataCell
    Rectangulo := Rect; // Esto no se necesita. Es lo mismo que el parametro Rect

    Grid := TStringGrid(Sender); // Esto debería ser TDBGrid(Sender)

    if Column.Field.IsBlob then
    begin
      Grid.Canvas.FillRect(Rect);
      Texto := Column.Field.AsString;
      DrawText(Grid.Canvas.Handle,
               PChar(Texto),
               StrLen(PChar(Texto)),
               Rectangulo, // Esto no se necesita. Es lo mismo que el parametro Rect
               DT_WORDBREAK);
    end;
    //***************************************************************************//

    if FrmData.ADOQuery1.FieldByName(ComboBox3.Text).AsString = Edit1.Text then
    begin
      DBGrid1.Canvas.Font.Color := clNavy;
      // DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State);
    end;
  end;

  // Siempre debe ejecutarse
  DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State);
end;

Estuve haciendo pruebas y esto es lo que hace que falle:
Estableces el DisplayWidth durante el pintado de la celda.
Lo he quitado y veo que todo va bien.
Si deseas mantener esa funcionalidad, deberías pasarla al sitio donde se abren/cargan los datos (ComboBox1Change).

Como regla general, no deberías modificar datos/propiedades durante la visualización.

Paso 1:

1. Cargar
2. Validar/Calcular/Limitar/Filtrar/etc.
3. Dar formato

Paso 2:
Visualizar

Código Delphi [-]
procedure TFrmPrincipal.DBGrid1DrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);
Var
  Grid         : TStringGrid; // Esto debería ser TDBGrid(Sender)
  Texto        : String;
  Rectangulo   : TRect; // Esto no se necesita. Es lo mismo que el parametro Rect
begin
  {
  //************** Auto Ancho *********************//
  if length(Column.Field.AsString) > Column.Field.Tag then
  begin
    Column.Field.Tag := length(Column.Field.AsString);
    Column.Field.DisplayWidth := Column.Field.Tag + 1;
  end;
  }

  if (gdSelected in State) then
  begin
  ...

Muchas gracias duilioisola.

Tras tu primer post también realice pruebas y llegue a la misma conclusión.

tendré que buscar como añadir la función de auto ajuste. pues en este tipo de tablas que cargan ficheros diferentes es muy cómodo para una buena visualización.

Una forma simple de hacerlo es la siguiente:
Asumo 6 pixels por letra (O calcular con TextWidth('w') el largo de la letra w en la fuente actual).
Multiplico la cantidad de letras por 6
Si no quiero que las columnas queden muy anchas, puedo limitar el ancho máximo (300 pixels en mi ejemplo).

Código Delphi [-]
procedure TFrmPrincipal.ComboBox1Change(Sender: TObject);
Var
 I : Integer;
begin
 FrmData.ADOQuery1.Close;
 FrmData.ADOQuery1.SQL.Text := 'Select * From ['+ComboBox1.Text+']';
 FrmData.ADOQuery1.Open;
 ComboBox2.Items.Clear;
 ComboBox3.Items.Clear;
 for I:=0 to FrmData.ADOQuery1.FieldCount-1 do
    Begin
     ComboBox2.Items.Add(FrmData.ADOQuery1.Fields[i].FieldName);
     ComboBox3.Items.Add(FrmData.ADOQuery1.Fields[i].FieldName);
     ComboBox3.ItemIndex := 0;
    End;

 // Ajusto ancho de columnas
 for I:=0 to DBGrid1.Columns.Count-1 do
 begin
    // Asigno 6px por letra
    DBGrid1.Columns[i].Width := DBGrid1.Columns[i].Field.DisplayWidth * 6;

    // Evito que la columna se pase de 300px
    if (DBGrid1.Columns[i].Width > 300) then
       DBGrid1.Columns[i].Width := 300;
 end;
end;

Muchas gracias duilioisola.

trabajare un poco en ello y os cuento.