permutaciones
 

Hola, sigo con la aplicacion de los numeros aleatorios, ya funciona como debe, solo que ahora necesito hayar las permutaciones en funcion de la combinación generada por los 6 numeros que mas se repiten.
Ejemplo:

Supongamos que el listview se llena con 10.000 filas de 6 columnas de numeros. De entre todos esos, busca los 6 que mas veces salen generando una combinacion tal que n (donde n puede ser 42 16 5 18 23 8). Pues bien, esos 6 numeros los meto de forma manual (de momento) en 6 componentes tedit. Y a partir de ahí genera las permutaciones, que para ser seis grupos de numeros, deben salir 720 formas de mostrar esa combinacion, eso si, sin repeticiones. Luego cada una de esas 720 posibles formas de mostrar la combinacion, se compara linea a linea con el listview y si en alguna de esas 10.000 lineas aparece, entonces será la combinacion que juegue! XD

Mirando por la web, encontre en la pagina de rosetta code, el siguiente codigo para Pascal o aplicacion de consola:

Código Delphi [-]
program TestPermutations;
 
{$APPTYPE CONSOLE}
 
type
  TItem = Integer;                // declare ordinal type for array item
  TArray = array[0..3] of TItem;
 
const
  Source: TArray = (1, 2, 3, 4);
 
procedure Permutation(K: Integer; var A: TArray);
var
  I, J: Integer;
  Tmp: TItem;
 
begin
  for I:= Low(A) + 1 to High(A) + 1 do begin
    J:= K mod I;
    Tmp:= A[J];
    A[J]:= A[I - 1];
    A[I - 1]:= Tmp;
    K:= K div I;
  end;
end;
 
var
  A: TArray;
  I, K, Count: Integer;
  S, S1, S2: ShortString;
 
begin
  Count:= 1;
  I:= Length(A);
  while I > 1 do begin
    Count:= Count * I;
    Dec(I);
  end;
 
  S:= '';
  for K:= 0 to Count - 1 do begin
    A:= Source;
    Permutation(K, A);
    S1:= '';
    for I:= Low(A) to High(A) do begin
      Str(A[i]:1, S2);
      S1:= S1 + S2;
    end;
    S:= S + '  ' + S1;
    if Length(S) > 40 then begin
      Writeln(S);
      S:= '';
    end;
  end;
 
  if Length(S) > 0 then Writeln(S);
  Readln;
end.

El problema es que yo parto del contenido de 6 tedit que de primeras son strings. Entonces, de que forma puedo generar las 720 posibles formas de mostrar la
combinacion antes indicada. No sé como hacer referencia al contenido de esos tedit. Alguna idea? no pido codigos que me lo den todo mascado, solo vuestras
ideas o consejos de como hacerlo.

Un saludo y gracias.

Hola.
Creo que podrías hacer:

Código Delphi [-]
procedure combinatoria(v: array of Integer; Serie: TStrings);
var
  a,b,c,d,e,f: Integer;
begin
  if Length(v) <> 6 then
    raise Exception.Create('Error: Deben ser 6 elementos');
  for a := Low(v) to High(v) do
    for b := Low(v) to High(v) do
      for c := Low(v) to High(v) do
        for d := Low(v) to High(v) do
         for e := Low(v) to High(v) do
           for f := Low(v) to High(v) do
              if not(
  (v[a]=v[b])or(v[a]=v[c])or(v[a]=v[d])or(v[a]=v[e])or(v[a]=v[f])or
  (v[b]=v[c])or(v[b]=v[d])or(v[b]=v[e])or(v[b]=v[f])or
  (v[c]=v[d])or(v[c]=v[e])or(v[c]=v[f])or
  (v[d]=v[e])or(v[d]=v[f])or
  (v[e]=v[f])) then
    Serie.Add(Format('%d %d %d %d %d %d',[v[a], v[b], v[c], v[d], v[e], v[f]]));
end;

Ejemplos de uso:

Código Delphi [-]
  ...
  Combinatoria([0, 1, 2, 3, 4, 5], Memo1.Lines);
  Combinatoria([42, 16, 5, 18, 23, 8], ListBox1.Items);
  ...

Saludos :)

Hola ecfisa,

gracias por responder tan rapido, funciona perfectamente, ahora me estoy peleando para colocar cada cifra de 1 o 2 numeros en cada columna del lisview. Trato de hacerlo así:

Código Delphi [-]
listview1.Items.Add.SubItems.Add(combinatoria[0]);

pero no me sale. me dice "[dcc32 Error] loteria.pas(393): E2035 Not enough actual parameters"
un saludo.

Hola danielmj.

Fijate que el procedimiento combinatoria lo declaro con dos parámetros:

Código Delphi [-]
procedure combinatoria(v: array of Integer; Serie: TStrings);

Sin embargo en tu código estas citando a combinatoria como si fuese un arreglo y quisieras acceder al elemento 0 del mismo:

Código Delphi [-]
listview1.Items.Add.SubItems.Add(combinatoria[0]);

Saludos :)

Por favor, no olvides poner títulos descriptivos a tus preguntas :rolleyes:

Hola ecfisa,
Bueno sin adornos.. por mucho que miro el codigo y toco, cambio y reescribo cosas, no se como meter esos valores en grupos de dos por cada columna del listview. Me da apuro decirlo pero es la verdad :confused: así que por hoy lo dejo por que ya me estoy agobiando. Cuando una cosa no me sale, tiendo a frustrarme. Gracias por todo y en cuanto vuelva con el que sera (conociendome) en un rato, te comento.

Un saludo.

Hola, a ver.. en la linea:

Código Delphi [-]
SubItems.Add(IntToStr(combinatoria([0],...)

Ese indice 0 hace referencia a la primera posicion del vector? ¿ese 0 está bien colocado ahi? en cuanto a la serie, sigo sin saber que tengo que llamar ahí. Ponga lo que ponga el mensaje es el mismo..
http://pasteall.org/pic/index.php?id=107891
Un saludo.

Hola danielmj.

Los valores los recibis en un TStringList y de que modo los vuelques en el TListView, dependerá de como lo tengas configurado y la estructura le hayas dado. Al desconocer esto último lo mejor que puedo hacer es darte un ejemplo genérico:

Código Delphi [-]
procedure TForm1.btnLoadClick(Sender: TObject);
var
  TS: TStrings;
  li: TListItem;
  i : Integer;
begin
  ListView1.ViewStyle := vsList;
  TS := TStringList.Create;
  ListView1.Items.BeginUpdate;
  try
    combinatoria([0,1,2,3,4,5], TS);
    for i := 0 to TS.Count-1 do
    begin
      li := ListView1.Items.Add;
      li.Caption := TS[i];
    end;
  finally
    TS.Free;
    ListView1.Items.EndUpdate;
  end;
end;

Que produce esta salida:


Saludos :)

Hola ecfisa, lo primero graacias por la ayuda, siempre ayudando, se agradece.

He modificado tu código para acomodarlo a mi formulario, pero en mi caso, la lista que debe mostrar las permutaciones no muestra nada.
Mi modificacion de tu codigo es esta:

Código Delphi [-]
procedure TForm1.Button5Click(Sender: TObject);
var
  i, cont: integer;
  TS: TStrings;
  li: TListItem;

begin
  TS := TStringList.Create;
  lista2.ViewStyle:= vsReport;
  Lista2.Items.BeginUpdate;
  try
  Combinatoria([StrToInt(edit1.Text), StrToInt(edit2.Text), StrToInt(edit3.Text),
  StrToInt(edit4.Text), StrToInt(edit5.Text), StrToInt(edit6.Text)], ListBox1.Items);

  for i := 0 to listbox1.Count-1 do
  begin
    li := Lista2.Items.Add;
    li.Caption := TS[i];
  end;
  finally
    TS.Free;
    Lista2.Items.EndUpdate;
  end;
      label12.Caption:= IntToStr(i);
end;

Esto no lo entiendo, a "li" se le pasa ¿que cosa? y en que momento se cargan todas las permutaciones en la lista2. En listBox, si se cargan las permutaciones pero en el listview (lista2) no se carga nada.
Y aquí un ejemplo en video de que hace en mi caso..
https://youtu.be/944Cga7mJYw

Antes de ver tu codigo, y llevado en cierto modo por la frustracion :) tome un atajo, y era crear el listview (lista2) con solo dos columnas, una para el orden de la fila y otra para la permutacion. Por otra parte, en una variable metía toda la fila de la lista1 excepto la columna que hace referencia al orden y comparaba esa variable con el contenido de la columna permutaciones de la lista2. Esto es, comprobar las 720 permutaciones por cada linea de la lista1 (que previamente se había metido en una variable) pero es un proceso muy lento, tanto que me desespera, a parte de que me dio algun problema y al final, lo deseché.

Un saludo.

Un comentario al margen :):

[margen]

¿Para qué quieres mostrar todas las sextetas, permutaciones y demás en un ListView? Según entiendo, tú quieres hacer un análisis, comparaciones, etc. de dichas sextetas y para ello no requieres mostrarlas. Usar un control visual, además de requerir más recursos, consume más tiempo y hace que te confundas al apartarte de lo esencial ya que intentas lidiar simultáneamente con un problema que tiene que ver sólo con número enteros y con uno que tiene que ver con cadenas y la forma de disponerlas en un control.

Yo, en tu lugar, comenzaría definiendo una estructura de datos ad hoc a tu problema, por ejemplo:

Código Delphi [-]
type
  TSexteta = array[0..5] of Integer;
  TListaSextetas = array of TSexteta;

TListaSextetas será una matriz o arreglo bidimensional con un número de columnas fijo (seis) y un número de filas indeterminado o abierto. Todos tus cálculos, comparaciones, permutaciones, etc. las haces con esas estructuras y una vez que obtengas la sexteta de la suerte la muestras, ahora sí, en controles visuales.

Incluso, si decides que de-todas-formas quieres ver tus millones de sextetas, bastará que uses un ListView en modo virtual para "conectarlo" a tu estructura de datos, pero el problema aritmético en sí, seguirá separado de lo visual.

[/margen]

LineComment Saludos

hola roman,

creo que entiendo lo que dices, pero hacerlo todo visualmente me resulta mas fácil, ten en cuenta que hace mucho que no hacia nada de esto y me esta costando mucho tiempo y ayuda (del foro) para terminarlo. Solo busco la forma mas fácil para mi aunque lleve mas recursos y tiempo del pc.
Una vez lo tenga terminado, puedo intentarlo de ese otro modo que me propones ¿por que no? pero intentaré terminar esta "version" antes.

Un saludo.

He modificado el codigo y me he acercado..
http://pasteall.org/pic/index.php?id=107929

Pero en cada columna deberia aparecer solo cifra de dos o un numero y no toda la combinacion. eso me trae frito. Además usa la columna que esta reservada para el orden de cada fila.
¿alguna sugerencia? gracias.

Hola.

Basándome en la imágen que pusiste, fijate si este ejemplo es similar a lo que buscas.

Código Delphi [-]
...
procedure combinatoria(v: array of Integer; Serie: TStrings);
var
  a,b,c,d,e,f: Integer;
begin
  if Length(v) <> 6 then
    raise Exception.Create('Error: Deben ser 6 elementos');
  for a := Low(v) to High(v) do
    for b := Low(v) to High(v) do
      for c := Low(v) to High(v) do
        for d := Low(v) to High(v) do
         for e := Low(v) to High(v) do
           for f := Low(v) to High(v) do
              if not(
  (v[a]=v[b])or(v[a]=v[c])or(v[a]=v[d])or(v[a]=v[e])or(v[a]=v[f])or
  (v[b]=v[c])or(v[b]=v[d])or(v[b]=v[e])or(v[b]=v[f])or
  (v[c]=v[d])or(v[c]=v[e])or(v[c]=v[f])or
  (v[d]=v[e])or(v[d]=v[f])or
  (v[e]=v[f])) then
    Serie.Add(Format('%d %d %d %d %d %d',[v[a], v[b], v[c], v[d], v[e], v[f]]));
end;


procedure TForm1.FormCreate( Sender: TObject );
var
  i: Integer;
  lv: TListView;
begin
  lv := ListView1;
  lv.GridLines := True;
  for i := 1 to 7 do lv.Columns.Add;
  lv.Columns[0].Caption := 'FILA';
  lv.Columns[1].Caption := 'COL. 1';
  lv.Columns[2].Caption := 'COL. 2';
  lv.Columns[3].Caption := 'COL. 3';
  lv.Columns[4].Caption := 'COL. 4';
  lv.Columns[5].Caption := 'COL. 5';
  lv.Columns[6].Caption := 'COL. 6';
end;


procedure TForm1.btnLoadClick( Sender: TObject );
var
  lv: TListView;
  li: TListItem;
  Series, aux: TStrings;
  i : Integer;
  vn : array[0..5] of Integer;
begin
  // Podes poner tus valores en un arreglo
  vn[0] := 15; vn[1]:= 17; vn[2]:= 41; vn[3]:= 43; vn[4]:= 5; vn[5]:= 37;
  // y enviarlo como argumento: combinatoria( v, Series);

  // o enviar los valores directamente: combinatoria( [15, 17, 41, 43, 5, 37], Series);

  lv := ListView1;
  Series := TStringList.Create;
  lv.Items.BeginUpdate;
  try
    combinatoria(vn, Series );
    for i := 0 to Series.Count - 1 do
    begin
      aux := TStringList.Create;
      try
        ExtractStrings( [' '], [], PChar(Series[i] ), aux );
        li := lv.Items.Add;
        li.Caption := IntToStr(i + 1);
        li.SubItems.AddStrings( aux );
      finally
        aux.Free;
      end;
    end;
  finally
    Series.Free;
    lv.Items.EndUpdate;
  end;
end;

Salida:


Saludos :)

Hola ecfisa,

Buenas madrugadas, me pillas en el trabajo y no tengo el pc conmigo para mirar el código, pero así de primeras parece que si es eso. Luego cuando llegue a casa me pongo con ello y te comento. Ahora mismo
Tengo una versión digamos que a parte en la que he optado por una lista con seis columnas para los números aleatorios y un listbox para las permutaciones más una variable de tipo string que almacena el contenido de las seis columnas y se compara con cada fila del listbox. Pero ya digo que esa versión no me gusta mucho. Lo que quiero es comparar línea a línea listview1 y lustview2. Así que luego lo miraré.
Ahora mismo justo antes de salir de casa, había llegado a 1.000.000 de combinaciones y ahora debe estar comparando ese millón con cada una de las permutaciones de los números más repetidos. El hacer ese millón de combinaciones ha tardado aproximadamente 8h, no es mucho para un i7 a 4 GHz y 16gb de RAM?

Por cierto, soy de mente inquieta, así que estoy empezando a plantearme el mismo programa pero para consola, sin componentes visuales.. En parte por lo que me dijo roman y en parte por qué se me antoja verlo en un estilo msdos.

Un saludo y gracias por tu ayuda.