Webservice regresa PDF como string en base64
 

Hola amigos, buenas noches

Estoy diseñando una aplicación que se comunica con un Webservice, el cual en un Responsedata me regresa un string codificado en Base64 que en realidad es un PDF que lógicamente para factibilidad del weservice así me lo manda; si logro almacenar la información en el string, pero hasta ahí llego, de ahí ya no se cómo decodificar y guardar el string como pdf, según por lo que he visto, se usan stream y streammemory pero para este caso no tengo ni idea y según yo primero hay que decodificar el string. Si alguien me pusiera apoyar con esto. Gracias

¿Una pregunta? Si miras el fichero desde un editor de texto, tiene unas marcas/tags similares a estos:

<FACB64>
</FACB64>
<FIRB64>
</FIRB64>

¿Aunque no ponga el fichero, puedes poner un ejemplo de la estructura que tiene?

Que paso amigo, mira, he bajado el string que me regresa el webservice y no tiene estructura alguna, pongo un pedaso mas abajo, pero como te decia, no tiene una estructura; en la documentacion de la pagina solo me dice que siempre me regresa todo codificado en base64. saludos

Es el inicio del codigo

Ok. En tu caso veo que no hay etiquetas, porque eso es todo el fichero.
A veces al contener más cosas se "dividen" las partes utilizando etquetas.

Lo primero es comprobar que esos datos es algo "con sentido". Para hacer la prueba fácil puedes probar alguna de las múltiples Webs online que te permiten "decodificar" ese churro de caracteres. Para ello busca en Google "Decode Base64" y encontrarás muchas.
Por ejemplo, si pruebas aquí, con el texto que has colocado, verás que la decodificación devuelve el siguiente texto:

Que tiene pinta de ser cláramente un PDF. Prueba con algunos textos y deberías poder grabar el resultado en un PDF y abrirlo sin problemas.

Una vez que hayas comprobado que se traduce correctamente, hay que conseguir hacerlo desde Delphi. Al igual que hay muchas páginas de Decede Base64, también hay bastantes "códigos" en Delphi para hacerlo.

Si colocas un formulario con 2 memos y un botón, puedes probar un código como este:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Memo2: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
const
  CRYPT_STRING_BASE64 = 1;  {Irene. prueba de desencriptado}  

procedure StrToStream(Str: String; Stream: TStream);

implementation

{$R *.dfm}

// Irene. Prueba de desencriptado...
function CryptBinaryToString(pbBinary: PByte; cbBinary: DWORD; dwFlags: DWORD;
  pszString: PChar; var pcchString: DWORD): BOOL; stdcall;
  external 'Crypt32.dll' name 'CryptBinaryToStringA';

function CryptStringToBinary(pszString: PChar; cchString: DWORD; dwFlags: DWORD;
  pbBinary: PByte; var pcbBinary: DWORD; pdwSkip: PDWORD;
  pdwFlags: PDWORD): BOOL; stdcall;
  external 'Crypt32.dll' name 'CryptStringToBinaryA';

procedure StrToStream(Str: String; Stream: TStream);
var
  Buffer: PByte;
  Count: DWORD;
begin
  Count:= 0;
  if CryptStringToBinary(PChar(Str),Length(Str),CRYPT_STRING_BASE64,nil,Count,
    nil,nil) then
  begin
    GetMem(Buffer,Count);
    try
      if CryptStringToBinary(PChar(Str),Length(Str),CRYPT_STRING_BASE64,Buffer,
        Count,nil,nil) then
        Stream.WriteBuffer(Buffer^,Count);
    finally
      FreeMem(Buffer);
    end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TFileStream;
  NUevoFich:string;
begin
  // decode
  NuevoFich := 'r:\test.pdf';
  Stream:= TFileStream.Create(NuevoFich, fmCreate);
  try
    StrToStream(Memo1.Lines.Text, Stream);

  finally
    Stream.Free;
  end;

  // Sin embargo la firma no...
  Memo2.Lines.LoadFromFile(NuevoFich);
end;

end.

El memo1 con el trexto original, el que has puesto más arriba, por ejemplo, y en el botón la llamada a la decodificación.