cargar a un DBImage un jpg
 

tengo esto en el codigo

DBImage1.Picture.Bitmap.LoadFromFile(OpenPictureDialog1.FileName);

y me cargar un bmp a la base de datos sin problemas. el tema esta en que no puedo cargar un JPG. cuando se abre el OpenPictureDialog y elijo un JPG y me salta el siguiente error "Project1.exe raised exception class EInvalidGraphic with message 'Bitmap image is not valid'", me imagino que de esta forma no soporta bmp, pero mi pregunta es como se hace para levantar un JPG? y guardarlo en la Base de datos?

¿Qué base de datos estás utilizando?
Haz una busqueda en los foros por "DBImage jpg" (sin comillas) y seuramente encontrarás lo que necesitas.

estoy utilizando SQLServer 2000 y el campo Foto es de tipo image

Esto me funciona con Firebird.

Código Delphi [-]
procedure TFFicha.cargafoto; 
var
  BS: TStream;
  Graphic: TGraphic;
begin
 if FDM.qunafichafoto.isnull then // FDM: TDataModule   
  Image1.picture.graphic:=nil     // Image1: Timage
else
  begin
    BS := FDM.ficha.CreateBlobStream(FDM.qunaficha.FieldByName('foto'), bmRead);
    try
      Graphic := TJPEGImage.Create;
      try
        Graphic.LoadFromStream(BS);
        Image1.Picture := nil;
        Image1.picture.graphic := Graphic;
      Finally
        Graphic.Free;
      end;
    Finally
      BS.free;
    end;
  end;
end;
procedure TFFicha.SpeedButton1Click(Sender: TObject);
begin
  if OpenPictureDialog1.execute then
   if OpenPicturedialog1.filename <> '' then
     begin
       Image1.Picture.LoadFromFile(OpenPicturedialog1.filename);
       if not (FDM.IBT1.InTransaction) then
         FDM.IBT1.StartTransaction;
       try
         FDM.MODIFOTO.Parambyname('mcod').asinteger:=FDM.Qfichascodigo.asinteger; // MODIFOTO: procedimiento almacenado
         FDM.MODIFOTO.Parambyname('mfoto').LoadFromFile(OpenPictureDialog1.filename,ftBlob);
         FDM.MODIFOTO.ExecProc;
         FDM.IBT1.Commit;
       except
         FDM.IBT1.Rollback;
         raise Exception.Create('Error al grabar foto');
       end;
       FDM.Qfichas.open;        
     end;
end;
procedure TFFicha.SpeedButton3Click(Sender: TObject);
begin
  Image1.Picture := nil;
  if not (FDM.IBT1.InTransaction) then
    FDM.IBT1.StartTransaction;
  try
    FDM.MODIFOTO.Parambyname('mcod').asinteger:=FDM.Qfichascodigo.asinteger;
    FDM.MODIFOTO.Parambyname('mfoto').value:=null;
    FDM.MODIFOTO.ExecProc;
    FDM.IBT1.Commit;
  except
    FDM.IBT1.Rollback;
    raise Exception.Create('Error al eliminar foto');
  end;
  FDM.Qfichas.open;
end;

Saludos.

gracias Loviedo!