Procedure SetVisible... ; override
 

procedure SetVisible(Value: Boolean); override

Puse esto en un componente descendiente de TPanel para que realice unas operaciones antes de cambiar su propiedad "Visible". Sin embargo esto me da un error de compilación diciendo que el procedimiento SetVisible no existe en la clase base. ¿Alguien sabe porqué o como puedo hacer que haga algo antes de hacerse visible?

Otra cosa que intenté es dejarlo sin override pero a la propiedad visible publicada ponerle:
property Visible: Boolean read FVisible write SetVisible
pero no le hace caso

Podrías valerte del Custom Message CM_VISIBLECHANGED

Un ejemplo funcional:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, Buttons;

type
  TMiPanel = class(TPanel)
  private
    procedure CMVisibleChanged(var Message: TMessage); message CM_VISIBLECHANGED;
  end;


  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    FMiPanel: TMiPanel;
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TMiPanel }

procedure TMiPanel.CMVisibleChanged(var Message: TMessage);
begin
  Caption := DateTimeToStr(Now);
  inherited;
end;

{ TFrom1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  FMiPanel := TMiPanel.Create(Self);
  FMiPanel.Parent := Self;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FMiPanel.Visible := not FMiPanel.Visible;
end;

end.

SetVisible es un metodo estatico de modo que no puede ser sobreescrito.

Para hacer lo que quieres tienes que reescribir el metodo:
VisibleChanging
que si esta definido como dinamico.

Este metodo es llamado por el metodo SetVisible y esta pensado para ser sobreescrito en objectos derivados.

Saludos

Gracias a ambos...