Como crear calendario y reloj
 

Hola, quisiera saber como crear un calendario en Delphi 2 como el que se ve en windows y tambien como se hacia para que al abrir un form me muestre la hora actual, la verdad no me acuerdo de este lenguaje por eso tengo que preguntar porque estoy a contrareloj. Muchas gracias a quien me ayude.

Hola:

Acostumbrate a hacer una sola pregunta en cada hilo.


Mostrar la hora en un form:

Pones un Label y un Timer y en el evento OnTimer (el único que tiene) pones:

Label1.Caption := FormatDateTime('h:mm',Now);


Lo del calendario es simple, te doy las pautas, trabajatelo:

En un StringGrid de 7 columnas (y 7 filas).

//ver qué día de la semana es el día 1 del mes pedido (ojo con los anglosajones que primero descansan el domingo, y luego trabajan el resto de la semana)

//asigno valores iniciales de fila y columna en las variables respectivas

//relleno stringgrid con bucle for empezando en la posición adecuada, hasta total días que tiene el mes pedido

Gracias
 

Hola, gracias por el consejo, tratare de que en cada hilo solo exista una pregunta. El tema del reloj ya lo solucione anteriormente. igual gracias.
Lo del calendario, lo que me decis, solamente es para un mes en especial?, porque lo que necesito es un calendario como el que tiene windows, es decir seleciono un mes y me aparece sus dias correspondientes. Gracias de todas formas.

Hola:

Form (FMes) con:
- Label (LMesAno) para el mes y año
- StringGrid (SGMes) con 7 filas y 7 columnas, la primera fila para los nombres de los dias de la semana.
- ComboBox (CBMes) para los nombres de los meses
- SpinEdit (SPAnio) para el año

Y este código (la nota del examen la mitad para mi...).

Código Delphi [-]
procedure TFMes.FormCreate(Sender: TObject);
var
  i : integer;
begin
  //literal días de la semana en cabecera (coger de marzo de 2004 que empieza en lunes)
  for i := 0 to 6 do
    SGMes.Cells[i,0] := Copy(FormatDateTime('dddd',EncodeDate(2004,3,i+1)),1,7);
  //añadir al combo el literal de los meses (coger de cualquier año)
  for i := 1 to 12 do
    CBMes.Items.Add(FormatDateTime('mmmm',EncodeDate(2000,i,1)));
  //situarse en mes y año actual
  CBMes.ItemIndex := MonthOf(Date) - 1;
  SEAnio.Text := IntToStr(YearOf(Date));
end;

procedure TFMes.SEAnioKeyPress(Sender: TObject; var Key: Char);
begin
  //controlar entrada dígitos para año
  if ( StrScan('0123456789,'+chr(7)+chr(8), Key) = nil ) then
  begin
    Key := #0;
  end;
end;

//evento OnChange del ComboBox y del SpinEdit
procedure TFMes.SEAnioChange(Sender: TObject);
var
  iDiasemana : integer;
  i, j, iAnio: integer;
  iFila, iColum : integer;
begin
  //controlar entrada año no sea 0 ni blanco
  iAnio := StrToInt('0'+SEAnio.Text);
  if iAnio = 0 then
    iAnio := 1;
  //limpiar SGrid
  for i := 1 to 7 do
    for j := 1 to 7 do
      SGMes.Cells[j-1,i] := ' ' ;
  //mes y año en label título
  LMesAno.Caption := CBMes.Text + '  ' + IntToStr(iAnio);
  //ver qué día de la semana es el día 1 del mes pedido (restar 1 porque semana empieza en domingo)
  iDiasemana := DayOfWeek(EncodeDate(iAnio, CBMes.ItemIndex + 1, 1)) - 1;
  //porque domingo es el 7
  if iDiasemana = 0 then
    iDiasemana := 7;
  //valores iniciales de fila y columna
  iFila := 1;
  iColum := iDiasemana - 1 ;
  //relleno stringgrid con bucle for hasta total días que tiene el mes pedido
  for i := 1 to DaysInAMonth(iAnio, CBMes.ItemIndex + 1) do
    begin
      SGMes.Cells[iColum,iFila] := IntToStr(i);
      //controlar cambio de fila
      iColum := iColum + 1;
      if iColum = 7 then
        begin
          iFila := iFila + 1;
          iColum := 0;
        end;
    end;
end;

Gracias por tu ayuda, de todas formas termine implementando una solucion parecida.
Igualmente muchas gracias!