Duda con TTreeView
 

buenas tardes,

espero me puedan ayudar con mi duda, tengo un TTreeView y necesito que NO se abra (expand) ni se cierre (Collapse) el arbol con el doble clic, hay alguna forma de evitar eso, es q lanzo un evento en el doble clic y no quiero que se habra o se cierre el arbol, gracias.

Hola, primero debes mostrar tu treeview ya expandido y en el evento OnCollapsing, pones lo siguiente:

Código Delphi [-]
procedure TForm1.TreeView1Collapsing(Sender: TObject; Node: TTreeNode;
  var AllowCollapse: Boolean);
begin
 AllowCollapse := False;
end;

Saluditos :(

Hola Caro :),

ya intente eso pero como puedo saber si se esta expandiendo o cerrando por un doble clic ? si primero se lanza el evento OnCollapsing y despues el evento OnDblClick

lo que quiero es q si se pueda expander o cerrar pero dandole clic al boton que tiene el arbol para eso, no con doble clic :confused:

No sé si haya una forma sencilla de hacer esto. Como dices, los eventos OnExpanding y OnCollapsing se lanzan antes del evento OnDblClick, y de hecho, antes que cualquier evento del ratón.

Sin embargo, lo que sí parece ejecutarse antes de estos eventos es el mensaje WM_LBUTTONDBLCLK que recibe el TreeView. Así que, lo único que se me ha ocurrido hasta el momento es crear un descendiente del TreeView que levante una bandera al momento de recibir dicho mensaje, para que el OnExpanding detecte que se ha lanzado como consecuencia de un doble clic.

Al crear un derivado de un control, más que con los eventos, se acostumbra trabajar con los métodos que lanzan esos eventos, que en este caso son CanExpand y CanCollapse.

También, para no tener que crear e instalar un nuevo componente, podemos "sobreescribir" el original declarando la nueva clase con el mismo nombre y antes de la declaración del formulario.

En resumen, así:

Código Delphi [-]
type
  TTreeView = class(ComCtrls.TTreeView)
  private
    DoubleClicked: Boolean;
    procedure WMLButtonDblClk(var Msg: TWMLButtonDblClk); message WM_LBUTTONDBLCLK;
  protected
    function CanExpand(Node: TTreeNode): Boolean; override;
    function CanCollapse(Node: TTreeNode): Boolean; override;
  end;

  TForm1 = class(TForm)
    TreeView1: TTreeView;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TTreeView }

function TTreeView.CanExpand(Node: TTreeNode): Boolean;
begin
  Result := inherited CanExpand(Node) and not DoubleClicked;
  DoubleClicked := false;
end;

function TTreeView.CanCollapse(Node: TTreeNode): Boolean;
begin
  Result := inherited CanExpand(Node) and not DoubleClicked;
  DoubleClicked := false;
end;

procedure TTreeView.WMLButtonDblClk(var Msg: TWMLButtonDblClk);
var
  TestInfo: THitTests;
  Pt: TPoint;

begin
  Pt := Point(Msg.XPos, Msg.YPos);
  TestInfo := Self.GetHitTestInfoAt(Pt.X, Pt.Y);

  // Aquí señalamos que hubo un doble clic sobre la etiqueta del item
  DoubleClicked := htOnLabel in TestInfo;

  inherited;
end;

No estoy cien por ciento seguro de que se cubran todos los casos pero creo que por ahí puede ir la solución.

// Saludos

Hola de nuevo, no creo que mi solución sea mejor que la de Roman, esto es lo que se me ocurre a mi, en el evento OnDobleClick.

Código Delphi [-]
procedure TForm1.TreeView1DblClick(Sender: TObject);
begin
 if Not TTreeView(Sender).Selected.Expanded then
  TTreeView(Sender).Selected.Expand(True);
 
 //tu codigo...............
end;

Saluditos