Combinaciones
 

Hola de nuevo, esta vez me gustaria saber una cosa, que supongo que más de uno se habrá planteado alguna vez.
Yo tengo 2 Edit, y en uno tengo un 4 escrito, y en el otro un 6.
Estos 2 los convierto a Integer con la funcion StrToInt() y entonces, necesitaria saber un bucle, que vaya haciendo desde el 4 hasta el 6 lo siguiente:
Empiezo con 4 y con aaaa
Paso a aaab
aaac, aaad, aaaf, [...], aaaA, aaaB, [...] aaAa, aaAb, aaAc... y asi succesivamente, con numeros inclusive.
Despues con 5 letras lo mismo, y finalmente con 6 letras igual. De ahi los numeros de los Edit, de 4 letras hasta 6 letras.
Alguna solución?

Gracias de antemano,
Delar

Son un par de recorridos For y la función Chr creo que es suficiente.
¿Exactamente qué necesitas?

Lo que pido, que haga un loop provando todas las posibilidades desde el numero minimo de letras hasta el maximo, indicado en los Edit.

Saludos,
Delar

Ya he entendido lo que pides; Lo que yo te digo (o intentaba decirte) es que intentes hacerlo tú y si tienes algun problema te ayudaremos encantados, pero no solemos hacer código a medida por aquí.

Intenta hacer el FOR que haga el recorrido y a ver si te sale; Si no te sale pon el código y lo revisamos; Si te da algun error, pon el error y lo discutimos...

Un saludo.

Es que no se hacer un FOR de letras, lo se hacer de numeros y con algun que otro problemilla (que tarde o temprano consigo solucionar)

¿A que te refieres con hacer un for de letras? ¿A algo como esto?

Código Delphi [-]
for i:= 'A' to 'Z' do
   str := str + i;
 ShowMessage(str);

Como te dijo Neftali. ¿Porqué no expones tu código y erroes? Asi podremos ayudarme mejor.

Saludos,

Bueno, veamos las cosas de otra manera, vamos a realizar lo que antes se conocia como una prueba de escritorio, escribe aquí como lo harias manualmente, a partir de eso, entonces seguramente cualquiera de nosotros te dara ideas de como hacerlo.

Te parece?

Salud OS.

Este es el codigo al que llegue:

Código Delphi [-]
for i:= 1 to 255 do
begin
   str[i] := Chr(i);
 ShowMessage(str[i]);
 end;

Con esto almaceno el caracter 1 en str[1]. Hasta ahi bien, pero como hago combinaciones del tipo str[1]str[1]str[1]str[1], str[1]str[1]str[1]str[2],
str[1]str[1]str[1]str[3]... Cuando el ultimo str se pone en 255 pues el penultimo sube al dos y se repite lo mismo pero asi:
str[1]str[1]str[2]str[1],str[1]str[1]str[2]str[2],str[1]str[1]str[2]str[3],... y asi succesivamente hasta que todos los str lleguen a 255.

Saludos,
Delar

Ya me confundi.

Inicialmente querias hacer esto

aaaa
aaab
aaac
.....
aaaA
aaaB
aaaC
.....
aaAa
aaAb
aaAc
.....

Estoy en lo correcto?

Salud OS.

Correctisimo.

Y cuando llegue al maximo (zzzz) se cambie a 5 cifras, cuando acabe las 5, cambia a 6, y asi hasta el numero indicado en el Edit.

Parece dificil, se os escapara esto, maestros del Delphi?
Yo lo estoy haciendo, pero no se hacer para que pase de las 4 a las 5 cifras, de las 5 a las 6, etc... sino que a mi manera tendria que hacer una funcion para cada cifra.
En cuanto acabe el codigo os cuento ;)

Saludos,
Delar

Ok, Algo es algo.
Una variante podría ser esta:

Código Delphi [-]
for i:= 1 to 255 do begin
  for j := 1 to 255 do begin
    str[i] := Chr(i) + Chr(j);
  end;
  ShowMessage(str[i]);
end;

Prueba el código y amplíalo.

Además si no quieres los 255 caracteres (creo que sólo quieres letras) ajusta los for para que en lugar de comenzar por 1 comiencen por el número correspondiente a la "a".

Ya eso ya lo hice, del 48 a 122.

Saludos y gracias ;)

En el momento en que le pones más de dos, el programa deja de responder y empieza a chupar recursos.

Código Delphi [-]
for i:= 48 to 122 do begin
  for j := 48 to 122 do begin
    for k := 48 to 122 do begin
      for l := 48 to 122 do begin
      str[i] := Chr(i) + Chr(j) + Chr(k) + Chr(l);
      Edit4.Text := str[i];
      end;
      Edit4.Text := str[i];
    end;
    Edit4.Text := str[i];
  end;
  Edit4.Text := str[i];
end;

Es normal, piensa que lo has metido en un buqle bastante largo...
Para eso está:

Código Delphi [-]
  Application.ProcessMessages;

Puedes ponerlo para que se procesen mensajes; Es decir, si lo colocas cuando "cambias" los Edit, te dará tiempo a ver los resultados.

Ahora si que es perfectisimo.
Saludos!

DUDA SOLUCIONADA

¿Ah si? Pues a mi me queda una que otra duda :)

Por ejemplo, el fragmento de código

Código Delphi [-]
for i:= 48 to 122 do begin
  for j := 48 to 122 do begin
    for k := 48 to 122 do begin
      for l := 48 to 122 do begin
        ...

está perfecto para cuatro símbolos. Pero entendí de lo que describes, que el número de símbolos se especifica durante la ejecución. ¿Cómo haces para manajera un número variable? Porque no puedes agegar un ciclo for durante la ejecución.

// Saludos

Um claro, ese es el problema, pero bueno, podria hacer que el bucle fuese del maximo, por ejemplo 10 de maximo, entonces si el numero indicado es 10, hace el bucle con los 10, si es de 9, el bucle con los 9, y asi succesivamente.

Si tenemos tres letras (a,b,c), las combinaciones con dos elementos serían:

Si ahora queremos las combinaciones con tres elementos, basta tomar las anteriores y anexarles la a,

luego la b

y finalmente la c

Esto es, una vez que tenemos las combinaciones con N elementos, podemos, a partir de ellas, formar las de N+1 elementos, anexándoles cada uno de los distintos símbolos.

Todo esto lo digo, porque se puede hacer un procedimiento recursivo para evitar el número variable de índices.

Un ejemplo:

Código Delphi [-]
procedure Combinaciones(Simbolos: array of Char; Espacios: Integer; Lista: TStrings);
var
  ListaTemp: TStringList;
  I, J: Integer;

begin
  Assert(Espacios > 0);

  {
    Si sólo se requiere un espacio, la lista de combinaciones coincide con la
    lista de símbolos.
  }
  if Espacios = 1 then
    for I := Low(Simbolos) to High(Simbolos) do
      Lista.Add(Simbolos[i])
  else
  {
    En caso contrario, colocamos en una lista temporal las combinaciones con
    un elemento menos, e iteramos sobre los símbolos anexando cada uno a la
    lista temporal.
  }
  begin
    ListaTemp := TStringList.Create;

    try
      Combinaciones(Simbolos, Espacios - 1, ListaTemp);

      for I := Low(Simbolos) to High(Simbolos) do
        for J := 0 to ListaTemp.Count -1 do
          Lista.Add(Simbolos[i] + ListaTemp[J]);
    finally
      ListaTemp.Free;
    end;
  end;
end;

Al procedimiento Combinaciones le pasas la lista de símbolos o letras que desees, así como el número de elementos que quieras poner. El procedimeitno colocará en el tercer parámetro todas las combinaciones. Un ejemplo de uso:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  Lista: TStringList;

begin
  Lista := TStringList.Create;

  try
    {
      El número de espacios (4 en el ejemplo) puede leerse del usuario.
    }
    Combinaciones(['a','b','c','d','1','2','3', '#'], 4, Lista);
    Memo1.Lines.AddStrings(Lista);
  finally
    Lista.Free;
  end;
end;

// Saludos

u.U Tiene buena pinta, lo probaré en cuanto pueda.

Saludos!