Como cambiarle el Font al Caption de una forma
 

Hola:

Como puedo cambiarle el Font al titulo principal de una forma (Caption de la Forma), cambiando el font de la forma.... solamente me cambia el font de todo los labels y textos que pongo en la forma pero no en el titulo de esta.

Saludos

No hay una forma sencilla de hacer esto ya que debes ser tú mismo quien se encargue de dibujar todo el título si quieres que se haga de forma distinta al estándar.

El código que te pongo a continuación puede servirte aunque posiblemente sólo funcione con ventanas con borde bsSizeable. Para otros casos tendrás que calcular la posición correcta del título.

Código Delphi [-]
type
  TForm1 = class(TForm)
  private
    (*
      Windows pinta el título en cualquiera de estos dos mensajes, así
      que hay que interceptarlos para dibujar el título nosotros mismos
    *)
    procedure WMNCPaint(var Msg: TWMNCPaint); message WM_NCPAINT;
    procedure WMNCActivate(var Msg: TWMNCActivate); message WM_NCACTIVATE;

  public
    (* Método para dibujar el título *)
    procedure PaintCaption;
end;

implementation

procedure TForm1.WMNCActivate(var Msg: TWMNCActivate);
begin
  inherited;
  PaintCaption; // Pintar el título
end;

procedure TForm1.WMNCPaint(var Msg: TWMNCPaint);
begin
  inherited;
  PaintCaption; // Pintar el título
end;

procedure TForm1.PaintCaption;
var
  NewCaption: String;
  ncCanvas: TCanvas;
  cxSmIcon: Integer;
  cxSizeFrame: Integer;
  cySizeFrame: Integer;
  cyCaption: Integer;
  cyText: Integer;

begin
  { Título de la ventana }
  NewCaption := 'Foros del Club Delphi';

  ncCanvas := TCanvas.Create;
  try
    { Obtener un canvas que incluya el área no-cliente }
    ncCanvas.Handle := GetWindowDC(Handle);
    with ncCanvas do
    begin
      { Usar fondo transparente }
      Brush.Style := bsClear;

      { Fuente del título }
      Font.Name := 'Comic Sans MS';
      Font.Size := 8;
      Font.Color := clYellow;
      Font.Style := [fsBold];

      { Medidas para colocar el título }
      cxSmIcon := GetSystemMetrics(SM_CXSMICON);
      cxSizeFrame := GetSystemMetrics(SM_CXSIZEFRAME);
      cySizeFrame := GetSystemMetrics(SM_CYSIZEFRAME);
      cyCaption := GetSystemMetrics(SM_CYCAPTION);
      cyText := TextHeight(NewCaption);

      { Pintar el título }
      TextOut(cxSizeFrame + cxSmIcon + 4, cySizeFrame + ((cyCaption - cyText) div 2) - 1, NewCaption);
    end;
  finally
    ReleaseDC(Handle, ncCanvas.Handle);
    ncCanvas.Free;
  end;
end;

Para que funcione bien deberás borrar la propiedad Caption del formulario.

// Saludos

Sólo una pregunta Roman, ¿pq utilizar una nueva propiedad, pq no utilizar la propia Caption del Form?

Wop!

Igual me he perdido algo, pero.... ¿Dónde ves tú una nueva propiedad? :confused: :confused:

No, no te has perdido nada, tienes razón, ¿y dónde habré visto yo la propiedad? Me ha debido dar mucho el sol en la cabeza... y no se cómo he leído el mensaje...
No he dicho nada, olvidémolo. :confused:

Entonces al final todo quedaria como esta puesto en el principio no ?

Por mi sí, como si no hubiera dicho nada...

Lo de la nueva propiedad quizá lo pensaron por la variable NewCaption y el hecho de borrar la propiedad Caption.

Eso hay que hacerlo porque si se fijan, los manejadores de NCPaint y NCActivate de cualquier forma llaman a inherited antes de dibujar el título. Si no borran la propiedad Caption, tal llamada a inherited de cualquier manera pintará el título con la fuente estándar y la nuestra simplemente se dibujará encima de ella. Para evitar esto es que borramos la propiedad Caption.

// Saludos

Gracias Román.
 

Muchas gracias por contestarme y sobre todo por solucionar mi duda, además he estado probando diferentes formulas para ver si hay alguna que sea la fuente que sea me centre el texto en el formulario, es esta:

TextOut(cxSizeFrame + (cySizeFrame*40) + cxSmICon + 1,cySizeFrame + ((cyCaption - cyText) div 2) -1,NewCaption);

Se trata de sustituir la última linea del ejemplo que pusiste y sea el tipo de fuente que sea siempre sale centrado. Muchas gracias.