como escribir texto en diferentes angulos?
 

Hola buenas, me gustaría como poder escribir texto en un canvas (en mi caso en el de un PaintBox) en diferentes angulos, se que tiene la propiedad TextOut para escribir, pero necesito poder hacerlo con varias inclinaciones del texto.

Por favor, una ayudita!!!

Tengo este ejemplo con SpinButton para un Tpanel creo que sirva:

Código Delphi [-]
 
 procedure TForm1.SpinEdit1Change(Sender: TObject);
 var
  LogFont: TLogFont;
  OldFont, NewFont: HFONT;
 begin
  //l'image récupére les propriétes du Handle (Font)
  GetObject(Image1.Canvas.Font.Handle, SizeOf(LogFont), @LogFont);
  //à partir de là, toutes les instructions permettront de changer l'angle
  LogFont.lfEscapement:= SpinEdit1.Value * 10; //this does the rotation
 
  //créer le handle de la font
  NewFont := CreateFontIndirect(LogFont);
  //enregistre l'ancien handle de la font et assigne le nouveau
  OldFont := SelectObject(Image1.Canvas.Handle,NewFont);
  //imprimer le text
  Image1.Canvas.FillRect(Image1.Canvas.ClipRect);
  Image1.Canvas.TextOut(100, 95, 'SERGE WEB');
  //sauvegarde l'ancien handle et le remplace par le nouveau
  NewFont := SelectObject(Image1.Canvas.Handle,OldFont);
  //efface le handle de la fonte (qui a été crée au dessus)
   DeleteObject(NewFont);
 end;

Un Saludo.

muchas gracias por contestar tan rapido, supongo que funcionara...pero me podrías decir en que unidades estan los tipos HFONT, el metodo GetObject, etc, en fin, los tipos y metodos que utilizas en tu código. ya que por ejemplo el tipo HFONT ni si quiera esta en la ayuda de delphi, y me estoy temiendo que sean componentes adicionales que no tenga instalados!.

Muchas gracias!

No tienes que incluir nada en especial mira la "Unit" entera:

Código Delphi [-]
 unit Rotatexto;
 
 interface
 
 uses
   Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
   StdCtrls, ExtCtrls, Spin;
 
 type
   TForm1 = class(TForm)
     Panel1: TPanel;
     Image1: TImage;
     SpinEdit1: TSpinEdit;
     Label1: TLabel;
     BtnVertic: TButton;
     BtnHoriz: TButton;
     ScrollBar1: TScrollBar;
     Label2: TLabel;
     Label3: TLabel;
     Label4: TLabel;
     procedure FormCreate(Sender: TObject);
     procedure SpinEdit1Change(Sender: TObject);
     procedure BtnVerticClick(Sender: TObject);
     procedure BtnHorizClick(Sender: TObject);
     procedure ScrollBar1Change(Sender: TObject);
   private
     { Private declarations }
   public
     { Public declarations }
   end;
 
 var
   Form1: TForm1;
 
 implementation
 
 {$R *.DFM}
 
 procedure TForm1.FormCreate(Sender: TObject);
 begin
  Image1.Canvas.Font.Size := 10;
  Image1.Canvas.Font.Name := 'Arial';
  Image1.Canvas.TextOut(100,75,'SERGE WEB');
 end;
 
 procedure TForm1.SpinEdit1Change(Sender: TObject);
 var
  LogFont: TLogFont;
  OldFont, NewFont: HFONT;
 begin
  //l'image récupére les propriétes du Handle (Font)
  GetObject(Image1.Canvas.Font.Handle, SizeOf(LogFont), @LogFont);
  //à partir de là, toutes les instructions permettront de changer l'angle
  LogFont.lfEscapement:= SpinEdit1.Value * 10; //this does the rotation
 
  //créer le handle de la font
  NewFont := CreateFontIndirect(LogFont);
  //enregistre l'ancien handle de la font et assigne le nouveau
  OldFont := SelectObject(Image1.Canvas.Handle,NewFont);
  //imprimer le text
  Image1.Canvas.FillRect(Image1.Canvas.ClipRect);
  Image1.Canvas.TextOut(100, 95, 'SERGE WEB');
  //sauvegarde l'ancien handle et le remplace par le nouveau
  NewFont := SelectObject(Image1.Canvas.Handle,OldFont);
  //efface le handle de la fonte (qui a été crée au dessus)
   DeleteObject(NewFont);
 end;
 
 // position du texte à la verticale
 procedure TForm1.BtnVerticClick(Sender: TObject);
 begin
  SpinEdit1.Value := 90;
 end;
 
 // position du texte à l'horizontale
 procedure TForm1.BtnHorizClick(Sender: TObject);
 begin
  SpinEdit1.Value := 0;
 end;
 
 // le texte pivote selon l'action du ScrollBar
 procedure TForm1.ScrollBar1Change(Sender: TObject);
 begin
  SpinEdit1.Value := ScrollBar1.Position;
 end;
 
 end.

Un Saludo.

muchas gracias tio, era la liberria windows, que como estaba utilizando lo del texto por ahi en una unidad...esta no tenia en el uses Windows, solo lo imprescindible....
GRACIAS y un saludo!