Foros Club Delphi

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)
-   OOP (https://www.clubdelphi.com/foros/forumdisplay.php?f=5)
-   -   TDBGrid, pintar/negrita texto celda parcial (https://www.clubdelphi.com/foros/showthread.php?t=89553)

AgustinOrtu 11-12-2015 23:21:41

TDBGrid, pintar/negrita texto celda parcial
 
Saludos

Estoy usando Delphi 2010, y el efecto que quiero lograr es poner en negrita (o colorear, en fin cualquier forma de resaltar texto me vendria bien) parte del contenido de una celda de un TDBGrid; la idea es lanzar una busqueda y resaltar todas los campos en donde coincide el texto buscado

Ejemplo: busco "agustin" entonces el DBGrid deberia mostrar

Código Delphi [-]
Nombre             Direccion                           ...
Agustin    Calle agustincito        ...

Al grid ademas le asigno estas propiedades:

Código Delphi [-]
DefaultDrawing := False 
Options := [dgTitles, dgIndicator, dgColumnResize, dgColLines, dgRowLines, dgTabs, dgRowSelect,
    dgAlwaysShowSelection, dgCancelOnExit, dgTitleClick, dgTitleHotTrack];

Lo que hice fue agregar un manejador al evento OnDrawColumnCell, este es el codigo:

Código Delphi [-]
TForm1.(Sender: TObject; const Rect: TRect; DataCol: Integer; Column: TColumn;
  State: TGridDrawState);
var
  R: TRect;
  LCanvas: TCanvas;
  LFieldValue, LChar: string;
  I: Integer;
begin
  LCanvas := TDBGrid(Sender).Canvas;
  if DataCol in [0 .. 1] then
  begin
    LFieldValue := Column.Field.AsString;

    if not AnsiContainsText(LFieldValue, FSearchString) then
    begin
      LCanvas.Font.Style := LCanvas.Font.Style - [fsBold];
      TDBGrid(Sender).DefaultDrawColumnCell(Rect, DataCol, Column, State);
      Exit;
    end;

    R := Rect;
    for I := 1 to Length(LFieldValue) do
    begin
      LChar := LFieldValue[i];

      // desplazamiento del rectangulo
      if I > 1 then
        R.Left := R.Left + LCanvas.TextWidth(LChar);

      if (Length(FSearchString) >= I) and (AnsiSameText(LChar, FSearchString[i])) then
        LCanvas.Font.Style := LCanvas.Font.Style + [fsBold]
      else
        LCanvas.Font.Style := LCanvas.Font.Style - [fsBold];

      // dibujar cada caracter
      LCanvas.TextRect(R, LChar);
    end;
  end
  else
  begin
    LCanvas.Font.Style := LCanvas.Font.Style - [fsBold];
    TDBGrid(Sender).DefaultDrawColumnCell(Rect, DataCol, Column, State);
  end;
end;

Basicamente voy pintando caracter a caracter, en negrita o no, segun se vaya cumpliendo la coincidencia parcial

Pero me queda "feo" el texto, asi es como sale:



Curiosamente para numeros parece "ir bien", pero el texto sale horrible :(

Alguien puede arrojar algo del luz?

PD: Otras alternativas de haberlas, encantado de oirlas; por ejemplo, si con otro control VCL es facil lograr el efecto, aunque no sea data-aware, podria escribir la parte de llenar el contenido (un ListView por ejemplo). En lo posible prefiero no usar componentes de terceros

ecfisa 12-12-2015 18:30:16

Hola Agustín.

Fijate si podes sacar algo de provecho de este código de prueba:


Código Delphi [-]
...
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  a,b,c: string;
  p    : Integer;
  cv   : TCanvas;
  fs   : TFontStyles;
begin
  p := AnsiPos(FSearched, Column.Field.AsString);
  if (p <> 0) and (Column.Field is TStringField) then
  begin
    a := Copy(Column.Field.AsString, 1, p - 1);
    b := Copy(Column.Field.AsString, p, Length(FSearched));
    c := Copy(Column.Field.AsString, p + Length(FSearched), MaxInt);
    cv := TDBGrid(Sender).Canvas;
    cv.FillRect(Rect);

    p  := Rect.Left + 2;
    fs := cv.Font.Style;
    cv.Font.Style := [];
    cv.TextOut(p, Rect.Top + 2, a);

    Inc(p, cv.TextWidth(a));
    cv.Font.Style := [fsBold];
    cv.TextOut(p, Rect.Top + 2, b);

    Inc(p, cv.TextWidth(b));
    cv.Font.Style := [];
    cv.TextOut(p , Rect.Top + 2, c);
  end;
end;

procedure TForm1.Edit1Change(Sender: TObject);
begin
  FSearched := Edit1.Text;
  DBGrid1.Invalidate;
end;
...
Esta para ser usado sobre TStringFields (y tendrías que filtrar las columnas deseadas en el condicional)

Saludos :)

AgustinOrtu 12-12-2015 19:47:10

Daniel, funciona excelente, muchas gracias

Fue cuestion solamente de hacer un par de ajustes para que quede perfecto

Por cierto, es necesario en este caso que DBGrid.DefaultDrawing este a True :)

Saludos

ecfisa 12-12-2015 20:31:08

Me alegro mucho que te haya servido :)

Aunque no influye en el funcionamiento del ejemplo, hay un detalle que se me escapó entre las pruebas y que ahora veo... debería ser:
Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  a,b,c: string;
  p    : Integer;
  cv   : TCanvas;
  fs   : TFontStyles;
begin
  p := AnsiPos(FSearched, Column.Field.AsString);
  if (p <> 0) and (Column.Field is TStringField) then
  begin
    a := Copy(Column.Field.AsString, 1, p - 1);
    b := Copy(Column.Field.AsString, p, Length(FSearched));
    c := Copy(Column.Field.AsString, p + Length(FSearched), MaxInt);
    cv := TDBGrid(Sender).Canvas;
    fs := cv.Font.Style;
    cv.FillRect(Rect);

    p  := Rect.Left + 2;
    cv.Font.Style := fs;  // <-- 
    cv.TextOut(p, Rect.Top + 2, a);

    Inc(p, cv.TextWidth(a));
    cv.Font.Style := [fsBold];
    cv.TextOut(p, Rect.Top + 2, b);

    Inc(p, cv.TextWidth(b));
    cv.Font.Style := fs;  // <--
    cv.TextOut(p , Rect.Top + 2, c);
  end;
end;

Saludos :)

AgustinOrtu 12-12-2015 20:43:02

Entiendo, es para usar la fuente original del canvas y no forzar a sin estilo (que seria un conjunto vacio, [])

Saludos :)

AgustinOrtu 12-12-2015 20:59:57

Cita:

Empezado por AgustinOrtu (Mensaje 500433)
Daniel, funciona excelente, muchas gracias

Fue cuestion solamente de hacer un par de ajustes para que quede perfecto

Por cierto, es necesario en este caso que DBGrid.DefaultDrawing este a True :)

Correccion, DefaultDraw debe estar desactivado (False), sino se escribe el texto dos veces (una el DBGrid, otra el evento)

Si no se pinta el texto en este evento, es necesario invocar al metodo DefaultDrawColumnCell

por ejemplo:

Código Delphi [-]
  p := AnsiPos(FSearched, Column.Field.AsString);
  if (p <> 0) and (Column.Field is TStringField) then
  begin
   ...
  end
  else
    TDBGrid(Sender).DefaultDrawColumnCell(Rect, DataCol, Column, State);


La franja horaria es GMT +2. Ahora son las 10:46:16.

Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi