Encontrar todas las Computadoras de una Red LAN TCP/IP
 

Llamar a la función <b>FindComputer, </b>ésta devolverá un error de WinAPI en caso contrario.

La función llenará un StringList con los nombres de las computadoras de la RED.

Código Delphi [-]
unit FindComp;

interface

uses
  Windows, Classes;

function FindComputers: DWORD;

var
  Computers: TStringList;

implementation

uses
  SysUtils;

const
  MaxEntries = 250;

function FindComputers: DWORD;

var
  EnumWorkGroupHandle, EnumComputerHandle: THandle;
  EnumError: DWORD;
  Network: TNetResource;
  WorkGroupEntries, ComputerEntries: DWORD;
  EnumWorkGroupBuffer, EnumComputerBuffer: array[1..MaxEntries] of TNetResource;
  EnumBufferLength: DWORD;
  I, J: DWORD;

begin

  Computers.Clear;

  FillChar(Network, SizeOf(Network), 0);
  with Network do
  begin
    dwScope := RESOURCE_GLOBALNET;
    dwType := RESOURCETYPE_ANY;
    dwUsage := RESOURCEUSAGE_CONTAINER;
  end;

  EnumError := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_ANY, 0, @Network,
               EnumWorkGroupHandle);

  if EnumError = NO_ERROR then
  begin
    WorkGroupEntries := MaxEntries;
    EnumBufferLength := SizeOf(EnumWorkGroupBuffer);
    EnumError := WNetEnumResource(EnumWorkGroupHandle, WorkGroupEntries,
                 @EnumWorkGroupBuffer, EnumBufferLength);

    if EnumError = NO_ERROR then
    begin
      for I := 1 to WorkGroupEntries do
      begin
        EnumError := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_ANY, 0,
                     @EnumWorkGroupBuffer[i], EnumComputerHandle);
        if EnumError = NO_ERROR then
        begin
          ComputerEntries := MaxEntries;
          EnumBufferLength := SizeOf(EnumComputerBuffer);
          EnumError := WNetEnumResource(EnumComputerHandle, ComputerEntries,
                       @EnumComputerBuffer, EnumBufferLength);
          if EnumError = NO_ERROR then
            for J := 1 to ComputerEntries do
              Computers.Add(Copy(EnumComputerBuffer[J].lpRemoteName, 3,
                        Length(EnumComputerBuffer[J].lpRemoteName) - 2));
          WNetCloseEnum(EnumComputerHandle);
        end;
      end;
    end;
    WNetCloseEnum(EnumWorkGroupHandle);
  end;

  if EnumError = ERROR_NO_MORE_ITEMS then
    EnumError := NO_ERROR;
  Result := EnumError;

end;

initialization

  Computers := TStringList.Create;

finalization

  Computers.Free;

end.

esata funcion es la

esata funcion es la

esta es la funcion que necesito pero no la puedo llamar me da el siguiente error de compilacion al click de un boton

procedure Tform1.button1click(Sender: Tobjecty);
begin
findcomputer;
//findcomp;
//findcomputers;
end;

undeclaraded identifier 'findcomputer'

te agradeceria si me puedes ayudar

gracias

no funciona

si que funciona... y a la perfección... solo que hay que hacerle unos toquesitos al código.. a mi parecer está así a propósito para no dar las cosas tan servidas, porque copiar y pegar hace que solucionemos nuestros problemas y nos olvidemos del trabajo del que lo hizo, de esta manera tenemos que meternos en el código, lo entendemos y valoramos el esfuerzo de quien lo realizó. es una de las filosofías del foro y me parece muy bien..