Mostrar texto en 2 colores, en celda dbgrid
 

BUENAS TARDES A TODOS, buena mi consulta es la siguiente: Tengo un Dbgrid, en la cual muetro nombre del cantante - nombre del tema
ej: ricardo arjona - el problema
Aclaro esto esta en una sola celda.
Y yo quisiera que me aparesca asi :
ej: ricardo arjona - el problema

bueno desde ya muchas gracias.

¿Ricardo Arjona? Pues sí que es un problema... :rolleyes:

Lo que no entiendo muy bien es de dónde sacas el autor y el tema. ¿Son campos cada uno o tienes un campo donde ya están mezclados ambos?

De cualquier forma la ideas es que uses el evento OnDrawColumnCell del DBGrid. Aquí un ejemplo:

Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(
  Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
const
  Separador = ' - '; // Separador entre autor y tema

var
  Autor, Tema: String;
  AutorW, SeparadorW: Integer;

begin
  with Sender as TDBGrid do
    if (DataCol = 3) then
    begin
      Autor := Columns[1].Field.AsString;
      Tema := Columns[2].Field.AsString;

      AutorW := Canvas.TextWidth(Autor);
      SeparadorW := Canvas.TextWidth(Separador);

      // Escribes el autor en rojo
      Canvas.Font.Color := clRed;
      Canvas.TextOut(Rect.Left + 2, Rect.Top + 2, Autor);

      // Escribes el separador entre autor y tema en negro
      Canvas.Font.Color := clBlack;
      Canvas.TextOut(Rect.Left + 2 + AutorW, Rect.Top + 2, Separador);

      // Escribes el tema en azul
      Canvas.Font.Color := clBlue;
      Canvas.TextOut(Rect.Left + 2 + AutorW + SeparadorW, Rect.Top + 2, Tema);
    end
    else
      DefaultDrawColumnCell(Rect, DataCol, Column, State);
end;

Aquí estoy suponiendo que el autor y el tema están en las columnas 1 y 2 y que agregaste una columna 3 al dbgrid, que es donde pintas la combinación.

// Saludos

Gracias roman.
 

La ayuda fue enorme, Gracias Roman.