¿Cómo hago para que la propiedad Caption de un botón tenga múltiples líneas?
 

¿Cómo hago para que la propiedad Caption de un botón tenga múltiples líneas?.

Tengo un botón cuyo Caption es un texto un poco largo y me gustaría repartirlo en dos líneas, ¿sabeis cómo puedo hacerlo?.

Gracias y un saludo.

PD: No sabía en que subforo meter el post, ¿está bien aquí?.

EDITO: He pensado en poner lo siguiente por código:

Código Delphi [-]
Button1.Caption := 'hola' + #13 + 'adios';

pero no me funciona, sale ago así: hola|adios

prueba poniendo la propiedad wordwrap := true

No veo que los objetos de tipo TButton tengan tal propiedad.

¿Estás seguro?.

Gracias.

uy perdon fallo mío, creí te referias a un TLabel, es culpa de la dislexia :o

Al menos en Delphi7 si existe esa propiedad en la clase TButton, seguramente tienes una versión anterior.

Saludos

Efectivamente, en las versiones anteriores no existe, al menos en Delphi4 que tengo no está, pero en Turbo Delphi si está.

Bueno, lo que quiero agregar es lo siguiente:

1. Es indispensable que tengas WordWrap en True

2. Si usas esta forma

Código Delphi [-]
Button1.Caption := 'hola' + #13 + 'adios';

No importa el tamaño del botón te va a mostrar la frase en dos líneas.


3. Con esto solo va a escribirlo en dos líneas si el botón no es lo suficiente grande para alojar la frase en una sola línea.

Código Delphi [-]
Button2.Caption := 'hola como estas, que te vaya bien, adios';

Te va a mostrar mas o menos esto:


Salud OS

Si no tienes la propiedad WordWrap en tu versión de delphi, podemos intentar un apaño. En la unit de tu formulario coloca esto, justo antes de la definición del formulario:

Código Delphi [-]
TButton = class(StdCtrls.TButton)
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;

El procedure CreateParams tendría este aspecto:

Código Delphi [-]
procedure TButton.CreateParams(var Params: TCreateParams);
begin
  inherited;
  if Tag = 32 then
    Params.Style := Params.Style or $2000;
end;

Es decir la cosa nos quedaría mas o menos así:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TButton = class(StdCtrls.TButton)
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TButton }

procedure TButton.CreateParams(var Params: TCreateParams);
begin
  inherited;
  if Tag = 32 then
    Params.Style := Params.Style or $2000;
end;

end.

Ahora en los botones que quieras tener mas de una linea, coloca la propiedad Tag = 32

Exacto, tengo Delphi 6.

Pero ¿no he de llamar al procedimiento que has definido?.

Pues no, si haces lo que te dije, estas modificando la clase TButton. Esta clase internamente llama al procedimiento CreateParams al crearse. Tu solo tienes que poner la propiedad Tag = 32 (en tiempo de diseño) en los botones que quieras y punto.

De acuerdo, ya me salió, es que había metido el código que me dijiste en una clase a parte para que estuviera un poco más estructurado todo.

¡Muchas gracias!

Saludos.