Foros Club Delphi

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)
-   MySQL (https://www.clubdelphi.com/foros/forumdisplay.php?f=21)
-   -   guardar imagen en campo longblob o blob (https://www.clubdelphi.com/foros/showthread.php?t=93178)

LACV 07-06-2018 18:01:22

guardar imagen en campo longblob o blob
 
Buen día e estado buscando y no logro encontrar un hilo que me sirva para guiarme para guardar una imagen.

Les comento que estoy usando unidac para las conexión y consulta a la base de datos, logro visualizar y seleccionar la imagen que se va a guardar pero el problema viene cuando doy en el botón guardar pues no me guarda la imagen tengo este codigo


primero muestro y selecciona la imagen con este código
Código:

if D_Img.Execute then
  begin
    // bloqueamos el boton de guardar para que la imagen termine de cargar.
    BtmGuardar.Enabled := false;
    // verificamos el tipo de extension del archivo
    ext := ExtractFileExt(D_Img.FileName);
    // verificamos que sea de as extensiones especificadas en el filtro
    if (ext = '.png') then
    begin
      // creamos la instancia de la clase
      png := TPngImage.Create;

      // cargamos y mostramos la imagen; con SaveToStream cargamos en temporal
      Img_base.Picture.LoadFromFile(D_Img.FileName);
      png.LoadFromFile(D_Img.FileName);

      // liberamos la memoria ram
      png.Free;
      // desbloqueamos el boton de guardar para que la imagen termine de cargar.
      BtmGuardar.Enabled := true;
    end
    else if (ext = '.jpeg') or (ext = '.jpg') then
    begin
      // creamos la instancia de la clase
      jpg := TJpegImage.Create;

      // cargamos y mostramos la image
      Img_base.Picture.LoadFromFile(D_Img.FileName);
      jpg.LoadFromFile(D_Img.FileName);

      // liberamos la memoria ram
      jpg.Free;
      // desbloqueamos el boton de guardar para que la imagen termine de cargar.
      BtmGuardar.Enabled := true;
    end
    else
    begin
      // Mostramos un error por si el usuario a seleccionado una extension equibocada
      png.Free;
      jpg.Free;
      MessageBox(Application.Handle,
        Pchar('A seleccionado una extensión que no es permitida (' + ext + ')'),
        Pchar('¡Error!'), MB_OK + MB_ICONWARNING);
    end;
  end;

y luego esta el código del botón guardar

Código:

{ Insertar }
      sql := 'INSERT INTO cm_producto(Imagen,Barcode,Descripcion,Inv_min,Caja,Und,F_crear_prod,Id_catg,Id_marca,Estado_Prod) VALUES(:Param0 ,'''
        + EdtCod_Barra.Text + ''',''' + EdtDescripcion.Text + ''',''' +
        EdtInve_Min.Text + ''',''' + EdtCaja.Text + ''',''' + EdtUnd.Text +
        ''',''' + EdtFecha.Text + ''',''' + DBEdt_Categoria_id.Text + ''',''' +
        DBEdt_Marca_id.Text + ''',''Activo'')';

// mostramos el fomulario y lo ubicamos
    Frm_Producto.Visible := true;
    Frm_Producto.Show;

    MS := TMemoryStream.Create;
    MS.LoadFromFile(D_Img.FileName);

    // ejecuta la consulta
    // DataModuleLACM.Consulta_Flotante(sql);
    DataModuleLACM.UniQuery1.sql.Add(sql);
    DataModuleLACM.UniQuery1.ParamByName('Param0')
      .LoadFromStream(MS, ftGraphic);
    DataModuleLACM.UniQuery1.Active;
    DataModuleLACM.UniQuery1.ExecSQL;

    MS.Free;
    DataModuleLACM.UniQuery1.Close;


esto es lo que tengo en el botón de guardar; gracias por la atención prestada

Casimiro Notevi 07-06-2018 18:20:52

Mira los enlaces similares que están al final de esta página, abajo del todo.

LACV 07-06-2018 18:24:02

Cita:

Empezado por Casimiro Notevi (Mensaje 526910)
Mira los enlaces similares que están al final de esta página, abajo del todo.

con todo respeto estoy colocando este hilo por que no encuentro nada que me sirva que use unidac, y por eso aclaro
Cita:

Buen día e estado buscando y no logro encontrar un hilo que me sirva para guiarme para guardar una imagen.

Casimiro Notevi 07-06-2018 19:23:50

Cita:

Empezado por LACV (Mensaje 526911)
con todo respeto estoy colocando este hilo por que no encuentro nada que me sirva que use unidac, y por eso aclaro

Da igual si usas unidac o cualquier otro componente, los enlaces que te he indicado te sirven para lo que quieres hacer.
https://www.clubdelphi.com/foros/showthread.php?t=90075
https://www.clubdelphi.com/foros/showthread.php?t=81289

duilioisola 07-06-2018 21:16:44

Prueba quitando Active. Si no me equivoco esto es una función que devuelve si el query está ejecutado o no.
Por otro lado, utiliza parámetros siempre que puedas. Evita un montón de errores (por ejemplo si meten una comilla simple en la descripción.
Además es mucho mas facil leer el código.

Por otro lado, ¿cuál es el error?
  • Crea un registro con el valor de IMAGEN nulo.
  • Crea un registro con el valor de IMAGEN erróneo/cortado.
  • Da un error al ejecutar el Query ¿Cúal?

Código Delphi [-]
// Mostramos el fomulario y lo ubicamos
Frm_Producto.Visible := true;
Frm_Producto.Show;

// Insertamos imagen
MS := TMemoryStream.Create;
try
    // Cargo imagen en un Stream desde un archivo
    MS.LoadFromFile(D_Img.FileName);
    
    // Ejecuta la consulta
    with DataModuleLACM.UniQuery1 do
    begin
        sql.Clear;
        sql.Add(' INSERT INTO CM_PRODUCTO ( ');
        sql.Add(' IMAGEN, BARCODE, DESCRIPCION, INV_MIN, CAJA, UND, F_CREAR_PROD, ID_CATG, ID_MARCA, ESTADO_PROD) ');
        sql.Add(' VALUES ( ');
        sql.Add(' :IMAGEN, :BARCODE, :DESCRIPCION, :INV_MIN, :CAJA, :UND, :F_CREAR_PROD, :ID_CATG, :ID_MARCA, :ESTADO_PROD) ');

        // El parametro IMAGEN se carga de manera especial desde un stream
        ParamByName('IMAGEN').LoadFromStream(MS, ftGraphic);

        ParamByName('BARCODE').AsString := EdtCod_Barra.Text;
        ParamByName('DESCRIPCION').AsString := EdtDescripcion.Text;
        ParamByName('INV_MIN').AsString := EdtInve_Min.Text;
        ParamByName('CAJA').AsString := EdtCaja.Text;
        ParamByName('UND').AsString := EdtUnd.Text;
        ParamByName('F_CREAR_PROD').AsString := EdtFecha.Text;
        ParamByName('ID_CATG').AsString := DBEdt_Categoria_id.Text;
        ParamByName('ID_MARCA').AsString := DBEdt_Marca_id.Text;
        ParamByName('ESTADO_PROD').AsString := 'Activo';
        // Active; Quita esto
        ExecSQL;
        Close;
    end;
finally
    MS.Free;
free;

duilioisola 07-06-2018 21:22:59

También puede ser que tengas que cargar el parámetro de esta forma:

Código Delphi [-]
        BlobStream := CreateBlobStream(ParamByName('IMAGEN'), bmWrite);
        try
            BlobStream.CopyFrom(MS, MS.Size);
        finally
            BlobStream.Free;
        end;

duilioisola 07-06-2018 21:29:01

También se me ocurre que tenga el mismo "problema" que los componentes FIBPlus para Firebird.
El componente FBQuery no puede cargar ni leer BLOBs. los devuelve como el texto "Blob".

Para cargar imágenes utilizo TFIBDataSet
Agrego un SelectSQL que no me devuelva nada y un InsertSQL con el que trabajaré

Código Delphi [-]
SelectSQL.Text := 'SELECT CODIGO, NOMBRE, IMAGEN, FORMATO, ORIGEN, RUTA FROM SYS_IMAGENES WHERE CODIGO = 0';
// RefreshSQL.Text := 'SELECT CODIGO, NOMBRE, IMAGEN, FORMATO, ORIGEN, RUTA FROM SYS_IMAGENES WHERE CODIGO = :CODIGO';
InsertSQL.Text := 'INSERT INTO SYS_IMAGENES (CODIGO, NOMBRE, IMAGEN, FORMATO, ORIGEN, RUTA) VALUES (:CODIGO, :NOMBRE, :IMAGEN, :FORMATO, :ORIGEN, :RUTA)';
[...]
// Abro el DataSet
Open;
// Lo pongo en modo dsInsert
Insert;
b := DS.CreateBlobStream(FieldByName('IMAGEN'), bmWrite);
try
    f := TFileStream.Create(Archivo, fmOpenRead);
    try
       b.CopyFrom(f, f.Size);
    finally
       f.Free;
    end;
finally
   b.Free;
end;
FieldByName('NOMBRE').AsString := aFileName;
FieldByName('FORMATO').AsString := aFileExt;
[...]
// Guardo los cambios
Post;
// Cierro el DataSet
Close;
[...]

Casimiro Notevi 07-06-2018 21:50:56

Creo recordar que también puedes guardar la imagen en la BD leyéndola de un fichero imagen, más o menos así:
Código Delphi [-]
TBlobField(qrImagenes.FieldByName('imagenfactura')).LoadFromFile(cFileImage);
Con el TFIBDataSet.


La franja horaria es GMT +2. Ahora son las 21:05:37.

Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi