como instalar tWebView2 en delphi berlin
 

Alguien ha posido instalar el componente twebview2 en delphi berlin ???

no he podido hacerlo si alguien sabe como instalarlos por favor compártalo se lo agradeceré mucho.
el componente twebbowser que tiene instalado delphi, no respeta bootstrap, ni jquery. ya he intentado muchas cosas, pienso que el componente esta obsoleto y necesito instalar otro componente.

Desde la versión 10.4, trae un nuevo componente que se llama TEdgeBrowser, pero hay que hacer pasos adicionales para que funcione correctamente, espero te sirva el siguiente link:
https://yilmazyoru.medium.com/how-to...e-38d106bc7446

Yo estoy usando CEF4Delphi https://github.com/salvadordf/CEF4Delphi que usa Chromium, hay que agregar algunos procedimientos en el form principal, modificar el proyecto y además descargar los binarios.
Y posiblemente cambiar algo en los archivos de CEF4Delphi porque los binarios generalmente están mas actualizados.

Hola a todos,

Otro componente que puede usarse es el que proporciona WinSoft aquí. Está disponible en todas las versiones de Delphi, y, personalmente, lo he adquirido para cierto proyecto desarrollado con Delphi 2007. Lo pongo aquí como una alternativa, puesto que, funciona bien, no es muy caro (en mi opinión) y como digo sirve para todas las versiones de Delphi. En fin, es otra posible alternativa. El proyecto CEF4Delphi que ha mencionado arriba el compañero también funciona bastante bien.

También es posible usar el componente WebBrowser basado en Internet Explorer "emulando" la última versión de este último, tal como se explica en este artículo, por ejemplo, con lo que seguramente podrías utilizar Bootstrap CSS y jQuery, tal como dices, sin embargo, lo cierto es que aunque esta opción esté disponible, seguramente, es mejor decantarse por el nuevo WebView2 basado en Edge y dejar a un lado el componente WebBrowser e Internet Explorer, sobre todo si hablamos de nuevos proyectos.

Hola a todos,

Dejo aquí una unidad que, con sólo añadirla al proyecto, añade lo necesario para "emular" Internet Explorer 11 en el componente WebBrowser: de este modo, al menos podría usarse esta última versión del explorador, que, ofrece ciertas mejoras, aunque, como he comentado arriba, hoy día, lo mejor sería plantearse utilizar el "WebView2" de Microsoft:

Código Delphi [-]

unit UBrowserFixes;

interface

type
  TBrowserFixes = class(TObject)
  public
    class procedure Initialize();
    class procedure Uninitialize();
  end;

implementation

uses
  // Delphi
  Windows,
  SysUtils,
  Registry;

const
  FEATURE_GPU_RENDERING_KEY = 'Software\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_GPU_RENDERING';
  FEATURE_BROWSER_EMULATION_KEY = 'Software\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION';

{ TBrowserFixes }

class procedure TBrowserFixes.Initialize();
var
  ExeName: string;
begin
  ExeName := ExtractFileName(ParamStr(0));
  with TRegistry.Create() do
  try
    RootKey := HKEY_CURRENT_USER;

    if OpenKey(FEATURE_BROWSER_EMULATION_KEY, True) then
    begin
      if not ValueExists(ExeName) then
      begin
        // http://msdn.microsoft.com/en-us/libr...8VS.85%29.aspx
        WriteInteger(ExeName, 11001);
      end;
      CloseKey();
    end;

    if OpenKey(FEATURE_GPU_RENDERING_KEY, True) then
    begin
      if not ValueExists(ExeName) then
      begin
        // https://msdn.microsoft.com/en-us/lib...=vs.85%29.aspx
        WriteInteger(ExeName, DWORD(1));
      end;
      CloseKey();
    end;

  finally
    Free();
  end;
end;

class procedure TBrowserFixes.Uninitialize();
var
  ExeName: string;
begin
  ExeName := ExtractFileName(ParamStr(0));

  with TRegistry.Create() do
  try
    RootKey := HKEY_CURRENT_USER;

    if OpenKey(FEATURE_BROWSER_EMULATION_KEY, False) then
    begin
      if ValueExists(ExeName) then
        DeleteValue(ExeName);
      CloseKey();
    end;

    if OpenKey(FEATURE_GPU_RENDERING_KEY, False) then
    begin
      if ValueExists(ExeName) then
        DeleteValue(ExeName);
      CloseKey();
    end;

  finally
    Free();
  end;
end;

initialization
  TBrowserFixes.Initialize();

finalization
  TBrowserFixes.Uninitialize();

end.