Recorrer y desabilitar actions en TactionList
 

Hola de nuevo por acá, a pesar de que tengo tiempo usando delphi(ahora lazarus) nunca antes había usado actionList, la razón no la tengo clara en todo caso, tengo una serie de controles (especificamente toolbuttom) los cuales segun si vinculación a ciertas y determinados origenes de datos o privilegios del usuario activo sobre estas funcionalidades habilito o no, pues bien quiero implementar dicha funcionalidad pero usando actionList lo cual me permite habilitar o no esas funcionalidades a los distintos controles que esten asociadas....
pues bien recorrer el actionlist no es problema

Código Delphi [-]
for i:=0 to actionList.ActionCount -1 do
Begin
NombreAccion:=actionList.Actions[i].Name; 

end;

pues bien la idea es que según una o varias condiciones se habilite o no el action(y en consecuencia los controles asociados)

Código Delphi [-]
if condicion then actionList.Actions[i].enabled := false;

lo cual no funciona... la propiedad enabled si existe pero en tiempo de ejecución no puedo acceder a ella...que alternativas tengo ? que me falta para que sea funcional ...

Gracias por su atención ...

Hola Kenobi.

Hay que trabajar un poco para acceder a las propiedades de TAction, un ejemplo:

Código Delphi [-]
// Asignar Tag's a Actions
procedure TForm1.FormCreate(Sender: TObject);
var
  i: Integer;
begin
  for i := 0 to ActionList1.ActionCount - 1 do
    TAction(ActionList1.Actions[i]).Tag := i;
end;

// Desactivar Actions con Tag's impares
procedure TForm1.btImparesClick(Sender: TObject);
var
  i : Integer;
begin
  for i := 0 to ActionList1.ActionCount - 1 do
    TAction(ActionList1.Actions[i]).Enabled := Odd(ActionList1.Actions[i].Tag);
end;

// Activar Actions con Tag's impares, desactivar pares
procedure TForm1.btParesClick(Sender: TObject);
var
  i : Integer;
begin
  for i := 0 to ActionList1.ActionCount - 1 do
  begin
    TAction(ActionList1.Actions[i]).Enabled := Odd(ActionList1.Actions[i].Tag);
    TAction(ActionList1.Actions[i]).Enabled := not Odd(ActionList1.Actions[i].Tag);
  end;
end;

Salida:


Saludos :)

Gracias funciona al 100
 

muy agradecido, la funcionalidad esta lograda, ahora bien podrias explicar un poco(si no es molestia) como aplica este casting (o algo asi) que hiciste con

Código Delphi [-]
taction(actionList.actions[i]).enabled:=true

cosa de aplicarlo a otros escenarios y así aprender un poco mas y molestar menos por aca ....

Buscamos la declaracion de TAction:

Código Delphi [-]
TAction = class(TCustomAction)
...
published
  property Enabled;

Bien, parece ser que quien publica la propiedad Enabled es TAction, que desciende de TCustomAction

Luego, si TAction hereda de TCustomAction podemos decir que los TAction son TCustomAction

Esto implica que esto es valido:

Código Delphi [-]
var
  ACustomAction: TCustomAction;
  AAction: TAction;
begin
  // supongamos que AAction ya esta asignado en otra parte..
  ACustomAction := TCustomAction(AAction);
end;

Siguiendo con la jerarquia..

Código Delphi [-]
TCustomAction = class(TContainedAction)

Entonces sabemos que los TCustomAction son TContainedAction. Evidentemente, los TAction al ser TCustomAction, tambien serán TContainedAction

Y resulta que el TActionList tiene la propiedad Actions declarada asi:

Código Delphi [-]
property Actions[Index: Integer]: TContainedAction read GetAction write SetAction; default;

asi que basicamente lo que estas haciendo es: TContainedAction <-- TCustomAction <-- TAction.Enabled

De hecho, podrias castear directamente a TCustomAction. Ya que esta clase es quien declara la propiedad Enabled. Pero las clases definidas como TCustomXXX no contienen ciertas propiedades como publicadas (published) mas bien como públicas

Esto permite que en la herencia, si yo quiero definir un tipo especial de TCustomAction el cual no quiero que en el inspector de objetos aparezca su propiedad Enabled, debo elegir como ancestro TCustomAction. De lo contrario, si el ancestro es TAction, la propiedad Enabled apareceria en el inspector de objetos. Una ves una clase declara una propiedad como publicada, los descendientes no podran ocultarla, incluso aunque la redeclaren en secciones strict private, private, protected