Guardar un tipo de dato como archivo
 

Buenos días,

Es posible guardar un tipo de dato en un archivo y cargarlo en memoria posteriormente? Es decir tengo una variable de una Clase creada por ejemplo TMiPropiaClase esta clase tiene en su interior muchos tipo de datos distintos, se puede guardar de alguna manera el contenido de esta clase en un archivo, base de datos, etc. y después cargarla al abrir el programa nuevamente?

De antemano muchas gracias.

Buenas tardes,

• Guardar un type packed record - ClubDelphi
• Simple read/write record .dat file - StackOverflow
• Trabajando con archivos de texto y binarios - Delphi al Límite

-

Gracias por responder, parece ser que es lo que necesito, lo voy a probar, yo trabajo en C++ Builder pero no debe haber gran diferencia.

Saludos

Hola mordaz.

Otra opción es usar los métodos ReadComponent y WriteComponent, lo cuál podes hacer de dos formas:

Derivando tu clase de TComponent encapsulando las funciones y hacíendolas miembros de la primera, como por ejemplo:
O como funciones fuera de la clase, por ejemplo:
Llamadas de ejemplo:
Saludos. :)

Edito: Toma en cuenta que sólo funciona para los miembros publicados.

Hola nuevamente ecfisa,

Esta perfectamente detalla tu explicación, el punto de todo esto es que estoy usando algunas librerías ActiveX del controlador de una tarjeta electrónica que se comunica por USB, mi complicación surgió al intentar guardar uno de estos objetos que me escribe en memoria el propio dispositivo, el cual es una clase derivada de otra clase y así sucesivamente, necesito guardar un numero determinado de estos objetos para después volverlos a cargar en memoria y utilizarlos sin necesidad que me los vuelva a proporcionar el dispositivo, voy a probar las opciones que me propones y posteriormente publico como lo resolví.

Nuevamente gracias y te envió un cordial saludo.

ecfisa,

Pregunto: ¿El código del Msg # 4 como sería en Delphi?.

Gracias de antemano :)

Nelson.

Hola Nelson.

Como funciones independientes:

Código Delphi [-]
procedure SaveComponent(CP: TComponent; aFileName: TFileName);
begin
  if not Assigned(CP) then
    raise Exception.Create('Objeto inexistente');
  with TFileStream.Create(aFileName, fmCreate) do
  try
    WriteComponent(CP);
  finally
    Free;
  end;
end;

procedure LoadComponent(CP: TComponent;aFileName: TFileName);
begin
  if not Assigned(CP) then
    raise Exception.Create('Objeto inexistente');
  if not FileExists(aFileName) then
    raise Exception.Create('Archivo inexistente');
  with TFileStream.Create(aFileName, fmOpenRead) do
  try
    ReadComponent(CP);
  finally
    Free;
  end;
end;

Como métodos de clase:

Código Delphi [-]
...
implementation 

type
  TMiClase = class(TComponent)
  private
    FStr : string;
    FEnt : integer;
    FDob : Double;
  published
    property Str : string read FStr write FStr;
    property Ent : Integer read FEnt write FEnt;
    property Dob : Double read FDob write FDob;
  public
    constructor Create(AOwner: TComponent); override;
    procedure SaveToFile(const aFileName: TFileName);
    procedure LoadFromFile(const aFileName: TFileName);
  end;

var
  MC : TMiClase;

constructor TMiClase.Create;
begin
  inherited;
  FStr := 'Una frase cualquiera';
  FEnt := 1234;
  FDob := 3.141592654
end;

procedure TMiClase.SaveToFile(const aFileName: TFileName);
begin
 if not Assigned(Self) then
    raise Exception.Create('Objeto inexistente');
  with TFileStream.Create(aFileName, fmCreate) do
  try
    WriteComponent(Self);
  finally
    Free
  end
end;

procedure TMiClase.LoadFromFile(const aFileName: TFileName);
begin
  if not Assigned(Self) then
    raise Exception.Create('Objeto inexistente');
  if not FileExists(aFileName) then
    raise Exception.Create('Archivo inexistente');
  with TFileStream.Create(aFileName, fmOpenRead) do
  try
    ReadComponent(Self);
  finally
    Free
  end
end;


{ TForm1 }
procedure TForm1.Button1Click(Sender: TObject);
var
  MC : TMiClase;
begin
  MC := TMiClase.Create(Self);
  try
    MC.SaveToFile('C:\MiComp.dat');
  finally
    MC.Free
  end
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  MC : TMiClase;
begin
  MC := TMiClase.Create(Self);
  try
    MC.LoadFromFile('C:\MiComp.dat');
    ShowMessage(Format('%s %s%d %s%f',[MC.Str,#10,MC.Ent,#10,MC.Dob]));
  finally
    MC.Free
  end
end;
...

Saludos :)

ecfisa,

Gracias Daniel :)

Nelson.