Foros Club Delphi - Interpolacion RGB

Página 1 de 2

Mostrar 40 mensajes desde este tema en una página

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)

- Gráficos (https://www.clubdelphi.com/foros/forumdisplay.php?f=8)

- - Interpolacion RGB (https://www.clubdelphi.com/foros/showthread.php?t=61818)

JF Sebastian

23-11-2008 18:33:54

Interpolacion RGB

Desearia realizar un espectro de colores desde el rojo al azul.
Sabeis como variar los parametros RGB para recorrer el espectro de colores?

Saludos

coso	23-11-2008 20:14:38

Hola,
TColor es un entero entre 0 y $02FFFFFF, si haces

Código Delphi [-]color := r*$01 + g*$0100 + b*$010000;

tendras un color a medida.

JF Sebastian

23-11-2008 20:19:43

lo que quiero es calcular que valores de r,g,b debo poner a un color para que quede entre el espectro de colores (llamalo arco iris...) siendo 1 el color rojo puro y 0 el azul puro siendo el color un numero entre 0 y 1

coso	23-11-2008 21:59:44

Cita:

lo que quiero es calcular que valores de r,g,b debo poner a un color para que quede entre el espectro de colores (llamalo arco iris...)

un color siempre estara dentro del espectro de colores... ¿Que es realmente lo que buscas hacer? me da que lo que quieres hacer es un gradiente. Lo que tienes que hacer entonces es, desde unos r,g,b iniciales ir sumando unos incrementos (que dependeran del numero de pasos) hasta llegar a los r,g,b del color final. Busca la palabra gradiente o degradado en el foro (o en los trucos). Hay algunos ejemplos bastante elaborados. Saludos.

JF Sebastian

24-11-2008 18:18:17

Gracias,
He encontrado este post http://www.clubdelphi.com/foros/showthread.php?t=29167
pero me gustaria implementar manualmente la funcion de la dll.
Basicamente quiero calcular el color intermedio que esta entre el rojo y el azul-violeta de modo que si asigno el numero 1 al rojo y el 0 al azul-violeta la funcion me devuelva la tonalidad correspondiente a un numero intermedio entre 0..1. El gradiente de colores ha de estar de acuerdo con el espectro estandar de colores. No necesito que me pinte el gradiente pues necesito como maximo 20 colores fijos intermedios.
No parece dificil, pero se me resite el problema...

Delphius

24-11-2008 20:06:58

Hola JF Sebastian,
La verdad es que no termino de comprender lo que buscas.
Por empezar el espacio formado entre rojo (255,0,0) y azul (0,0,255) es amplio. Por lo que existen muchos colores posibles.
Si entedemos a esto en el espacio, tendremos tres ejes: R, G, B. Los ejes van desde el 0 al 255. Si sólo debemos desplazarnos desde el eje R al B, quiere decir que en ningún momento intervendrá el eje G. Claramente se ve que se trata de un giro de 90º. Por tanto sólo obtendremos combinaciones de distintas tonalidades de rojo y azul.

Con esto en mente a mi se me ocurre rotar el vector (x,0,z) "a" grados uniformemente distribuídos. Es decir que cuando a es cero, tendremos:

x (rojo) = 255 * cos(0) = 255
z (azul) = 255 * sen(0) = 0
Por tanto el color que se obtiene es: (x,0,z) = (255,0,0)

Cuando a = 90, tenemos:

x (rojo) = 255 * cos(90) = 0
z (azul) = 255 * sen(90) = 255

Es decir el color (0,0,255)

¿Se entiende la idea?
Bueno ahora la cuestión es como obtener ese "a"... bueno si consideramos que 90º es el 100% o 1, y que 0º es 0% o 0... entonces el grado de desplazamiento estará dado por 90/cantidad, siendo "cantidad" la cantidad de colores que deseas obtener... por ejemplo tus 20. En este caso, los 20 colores estarán espaciados 90/20º (4,5º) uno de otro.

Bueno esa es mi idea... no se si es eso lo que buscas. Si no se me entiende y/o no es lo que buscas te agradecería que lo hicieras saber.

¿Cúal es el problema de éste método? que sólo obtendrás los colores ubicados sobre el contorno que describe el vector por lo que no comprende todo el especto posible con dos colores. Por ejemplo el color (255,0,255) no estará cubierto.

Si nos pudieras explicar con mejores detalles lo que buscas te podríamos ser de ayuda.

Saludos,

coso	24-11-2008 20:12:47

Cita:

pero me gustaria implementar manualmente la funcion de la dll.

¿que dll?

Cita:

El gradiente de colores ha de estar de acuerdo con el espectro estandar de colores.

¿?

Lo que tienes que hacer es conseguir los r,g,b del color final, restar de ellos los r,g,b del color inicial. Estos valores, llamemosles dr,dg,db, los divides en un numero de pasos, pon 100, por ejemplo. Para encontrar el color medio en la posicion n tansolo tendrias que hacer Color nuevo = r + dr*n,g + dg*n, b + db*n. El color medio entre el final y el inicial seria con n = 50. Mirate bien los ejemplos que hay por el foro, pues hacen mas o menos esto mismo. saludos.

Lepe	24-11-2008 22:09:39

Delphi ya cuenta con funciones para decodificar un color:

Código Delphi [-]
function RGB(r, g, b: Byte): COLORREF;

function GetRValue(rgb: DWORD): Byte;

function GetGValue(rgb: DWORD): Byte;

function GetBValue(rgb: DWORD): Byte;

function rgb

esas están en la unidad windows, pero también tienes otras en graphics, por ejemplo ColorToRGB

Saludos

JF Sebastian

24-11-2008 22:10:55

Gracias por vuestra amabilidad.
Pero lo que necesito es una escala de todos los colores posibles y no de un degradado entre dos colores dados.
Aqui podeis ver el espectro del que hablo: http://www.fullspectrumrgb.com/why_do.htm
En principio seria indiferente el espectro de lo que el ojo ve o el de lo que ve una camara. Me bastaria con que recorriese de forma similar todos los colores posibles. Se como hacer un gradiente de dos colores dados.
Os cuento, si me permitis, con un poco mas de detalle:
Se trata de una aplicacion de analisis estructural en la que en un momento dado se precisa dibujar con colores los resultados del calculo de una placa. Esta placa esta sometida a fuerzas puntuales o distribuidas que producen unas deformaciones y unas tensiones. Una forma habitual de representar graficamente los resultados es con colores y normalmente se emplean todos los colores del espectro, rojo para el valor maximo y azul-violeta para el minimo. Al lado del espectro se anotan varios valores numericos (10 o 20)normalmente equiespaciados. Esta escala suele ser variable en cuanto al numero de valores a representar. La pregunta es dado un valor intermedio (de los resultados, no del color), que color (R,G,B) le corresponde?
Hasta ahora venia haciendo lo siguiente:
Tomaba R=1 y G=0 y decrementaba R y aumentaba B hasta R=0 y G=1 luego tomaba G=1 y B=0, decrementaba G y aumentaba B hasta G=0 y B=1 pero no sale nada parecido al espectro deseado (cualquiera parecido al del link que os dejo)
Si el numero de valores a representar fuese fijo la cosa parece facil de implementar pero puede ser variable a gusto del usuario y ahi esta la pega.

Imagino que la solucion buscada es una de las infinitas trayectorias que tendria un vector unitario que en tres instantes diferentes adoptase los valores [1,0,0],[0,1,0],[0,0,1]
Lo que se me ocurre es tomar los valores RGB de 7 colores basicos: rojo,naranja,amarillo,verde,azul,anil,violeta e interpolar linealmente entre cada dos de esos colores y creo que es lo que voy a hacer, pero si sabeis de algo mas elegante soy todo oidos
Os dejo otro link de mi aplicacion con lo que tengo actualmente implementado:

http://www.ustatic.net/Images/Demo10.jpg

Un saludo y muchas gracias.

coso	24-11-2008 22:31:23

Hola de nuevo. Ahora si que te he entendido. Para hacer eso lo mejor es tratar el color por HSV (hue, saturation,value) y teniendo H fija, ir variando la saturacion y el valor del color. No se si en versiones posteriores a la 5 ya vienen funciones estandar para HSV. Te dejo este link a ver si te sirve. Saludos.

coso	24-11-2008 22:56:02

...y otra manera, aunque quiza sea mas dificil de implementar, seria usando el concepto de R³ como dice Delphius: crear un vector en R,G,B y ir desplazandolo gradualmente sin modificar su modulo. No estoy seguro si funcionaria :confused: pero podrias probar. Saludos de nuevo.

cHackAll

25-11-2008 01:33:54

Código Delphi [-]procedure TForm1.Button1Click(Sender: TObject); // matriz o paleta de colores
var Offset, Value, Index: Cardinal;
begin
 Offset := 0;
 Value := 255;
 for Index := 0 to 255 * 3 do
  begin
   Canvas.Pen.Color := Value;
   Canvas.MoveTo(Index, 0);
   Canvas.LineTo(Index + 16, 32);
   Dec(PByte(Cardinal(@Value) + (Offset mod 3))^);
   Inc(PByte(Cardinal(@Value) + ((Offset + 1) mod 3))^);
   if ((Index + 1) mod 255) = 0 then
    Inc(Offset);
  end;
end;

Lepe	25-11-2008 03:47:57

Todavía me estoy preguntando cómo has puesto el código sin ninguna palabra, al menos el foro te obliga a escribir 10 letras.... Pero a lo que iba, tu código suele impresionar por su calidad, pero en este caso, es superado por la belleza del resultado.

Salud.

Delphius

25-11-2008 04:08:34

Viendo las nuevas aportaciones, me parece que lo que he dicho yo no es muy viable que digamos.
Por empezar yo mismo he aclarado que mi idea es rotar el vector desde el eje R hacia el B, un total de 90º. Por tanto todos los puntos que pertenezcan a dicho plano tendrán sólo dos componentes: rojo y azul.
Y es así como lo entendí puesto que por la forma en como describía el problema se trataba de una rotación del rojo al azul, pero no daba evidencia alguna del verde;).

Por si no fuera poco, la segunda limitante a mi "diseño", no se cubre todo el espectro de la combinación de hasta dos colores. Sólo se obtienen aquellos cuyo valor de módulo sea 255.

Tal vez dos "trucos" sean posibles:
1. Dado un valor "y" (verde) llevar a cabo la rotación desde el rojo al azul. O tal vez, dado un rango de verde y_min, y_max obtener para cada valor perteneciente a dicho rango, su rotación. Por ejemplo y = [0,255]:

(255,0,0) -> ... -> (0,0,255)
...
(255,255,0) -> ... -> (0,255,255)

2. Alterar el valor del módulo para forzar el uso de los valores, y no necesariamente del valor correspondiente al módulo. Con esta "técnica" se podría llegar a valores "inaccesibles", como (255,y,255). Se puede aumentar o disminuir el módulo.

Si es necesario cubrir el especto visible pues lo veo un tanto difícil... pero no se como diablos hizo Javier para demostrarlo tan sencillo (1)

(1) Sencillo por las pocas líneas... yo la verdad que me pierdo en interpretarlo:o

Saludos,

Lepe	25-11-2008 04:18:41

Cita:

Empezado por Delphius (Mensaje 327796)

(1) Sencillo por las pocas líneas... yo la verdad que me pierdo en interpretarlo:o

Pero eso es normal con c-Hack-All ;)

Saludos

egostar

25-11-2008 04:27:31

Cita:

Empezado por Lepe (Mensaje 327791)

Cita:

Empezado por Lepe (Mensaje 327799)

Pero eso es normal con c-Hack-All ;)

Saludos

La respuesta a tu pregunta la has dado tu mismo :)

Salud OS

coso	26-11-2008 12:48:22

Hola de nuevo, y ya considerando el hilo resuelto : dejo aqui este codigo para ilustrar la idea de delphius de usar el 'cubo' RGB e ir rotando un vector de color en el.

Código Delphi [-]procedure TForm1.FormPaint(Sender: TObject);
var
     phi,rho : double;
     m : integer;
     r,g,b : integer;
     x,y : integer;
begin
     m := TrackBar1.Position;
     phi := 0;
     while phi < PI/2 do
     begin
          rho := 0;
          while rho < PI/2 do
          begin
               r := Round(m*sin(phi));         // proyeccion del vector en r
               g := Round(m*cos(phi)*cos(rho));// proyeccion en g
               b := Round(m*cos(phi)*sin(rho));// proyeccion en b

               canvas.Pixels[20+Round(rho*100),20+Round(phi*100)] := r*$01 + g*$0100 + b*$010000;
               rho := rho + 0.01;
          end;
          phi := phi + 0.01;
     end;
end;

procedure TForm1.TrackBar1Change(Sender: TObject);
begin
     Paint;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
     doublebuffered := true;
     TrackBar1.Max := 255;
     TrackBar1.Min := 0;
end;

PD: tremendo el codigo, cHackAll

JF Sebastian

26-11-2008 19:35:43

Muy buenas aportaciones, companeros.

JF Sebastian

26-11-2008 19:38:44

Muy buenas aportaciones, companeros.

Os dejo otra solucion que encontre por ahi y que permite interpolar facilmente y obtener el color deseado...

implementation
{$R *.dfm}
uses math;

Código Delphi [-] 
procedure TForm1.FormClick(Sender: TObject);
var i: integer; R,G,B: byte; cl:TColor;
begin
  for i := 400 to 750 do
  begin
    WavelengthToRGB(1.0*i,R,G,B);
    cl := rgb(r,g,b);
    Canvas.Pen.Color := cl;
    Canvas.Moveto(i-300,0);
    Canvas.LineTo(i-300,100);
  end;
end;
 
procedure TForm1.WavelengthToRGB(const Wavelength:  double; var R,G,B: byte);
const
  Gamma        =   0.80;
  IntensityMax = 255;
var
  Blue   :  double;
  factor :  double;
  Green  :  double;
  Red    :  double;
  function Adjust(const Color, Factor: double):integer;
  begin
    if   Color = 0.0
    then result := 0
    else result := round(IntensityMax * Power(Color * Factor, Gamma))
  end;
begin
  case trunc(Wavelength) OF
    380..439: begin
        Red   := -(Wavelength - 440) / (440 - 380);
        Green := 0.0;
        Blue  := 1.0
    end;
    440..489: begin
        Red   := 0.0;
        Green := (Wavelength - 440) / (490 - 440);
        Blue  := 1.0
    end;
    490..509: begin
        Red   := 0.0;
        Green := 1.0;
        Blue  := -(Wavelength - 510) / (510 - 490)
    end;
    510..579: begin
        Red   := (Wavelength - 510) / (580 - 510);
        Green := 1.0;
        Blue  := 0.0
    end;
    580..644: begin
        Red   := 1.0;
        Green := -(Wavelength - 645) / (645 - 580);
        Blue  := 0.0
    end;
    645..780: begin
        Red   := 1.0;
        Green := 0.0;
        Blue  := 0.0
    end;
    else
      Red   := 0.0;
      Green := 0.0;
      Blue  := 0.0
  end;
  case trunc(Wavelength) of
    380..419:  factor := 0.3 + 0.7*(Wavelength - 380) / (420 - 380);
    420..700:  factor := 1.0;
    701..780:  factor := 0.3 + 0.7*(780 - Wavelength) / (780 - 700)
    else       factor := 0.0
  end;
  R := Adjust(Red,   Factor);
  G := Adjust(Green, Factor);
  B := Adjust(Blue,  Factor)
end;

JF Sebastian

26-11-2008 19:40:04

Que inutil soy:rolleyes:

La franja horaria es GMT +2. Ahora son las 15:58:19.

Página 1 de 2

Mostrar 40 mensajes desde este tema en una página