Detectar ejecución de aplicación en Terminal Server
 

Hola. Uso la siguiente función para detectar si un programa está ejectuándose en Windows. Recibe como parámetro el nombre del programa (.exe) y devuelve "true" si lo encuentra.

Código Delphi [-]
function Ejecutandose(FileName:String):boolean;
var
    ContinueLoop:BOOLean;
    FSnapshotHandle:THandle;
    FProcessEntry32:TProcessEntry32;
    flag:boolean;
begin
    flag:=false;
    FSnapshotHandle:=CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS,0);
    FProcessEntry32.dwSize:=Sizeof(FProcessEntry32);
    ContinueLoop:=Process32First(FSnapshotHandle,FProcessEntry32);
    while integer(ContinueLoop)<>0 do
    begin
        if ((UpperCase(ExtractFileName(FProcessEntry32.szExeFile))=UpperCase(FileName))
           or (UpperCase(FProcessEntry32.szExeFile)=UpperCase(FileName))) then
        begin
             Flag:=true;
             break;
        end
        else ContinueLoop:=Process32Next(FSnapshotHandle,FProcessEntry32);
    end;
    CloseHandle(FSnapshotHandle);
    Result:=flag;
end;

Esto funciona bien, pero me surge el problema cuando el programa se ejecuta en una sesión de terminal server, ya que varios usuarios pueden estar usando el mismo programa y esta función detecta la ejecución del programa en todas las sesiones. Lo que necesito es que se limite sólo a mi sesión actual. ¿Hay alguna forma de hacerlo?
Gracias.
Un saludo
PD: no puse bien el título del post y luego no me deja cambiarlo. Sería "Detectar ejecución de aplicación en Terminal Server".

Te has salvado por los pelos :D

Puedes encontrar el usuario y el dominio conociendo el Pid de un proceso con esta función:

Código Delphi [-]
 type
 WTS_PROCESS_INFO = record
   SessionId: DWORD;    // session id
   ProcessId: DWORD;    // process id
   pProcessName: LPSTR; // name of process
   pUserSid: PSID;      // user's SID
 end;
 PWTS_PROCESS_INFO = ^WTS_PROCESS_INFO;

 TA_WTS_PROCESS_INFO = array of WTS_PROCESS_INFO;
 PTA_WTS_PROCESS_INFO = ^TA_WTS_PROCESS_INFO;

 function WTSEnumerateProcessesA(hServer: Cardinal; Reserved: DWORD; Version: DWORD;
   var ppProcessInfo: PWTS_PROCESS_INFO; var pCount: DWORD): BOOL; stdcall external 'Wtsapi32.dll';
 procedure WTSFreeMemory(pMemory: Pointer); stdcall external 'Wtsapi32.dll';

 implementation

 function GetUserAndDomainFromPID(ProcessId: Cardinal; var User, Domain: String): boolean;
 var
   snu: SID_NAME_USE;
   pProcessInfo: TA_WTS_PROCESS_INFO;
   nProc,UserSize, DomainSize: Cardinal;
 begin
   Result:= false;
   nProc:= 0;
   UserSize:= 0;
   DomainSize:= 0;

   if WTSEnumerateProcessesA(0, 0, 1, PWTS_PROCESS_INFO(pProcessInfo), nProc) then
   begin
     repeat dec(nProc) until (nProc <= 0) or (ProcessId = pProcessInfo[nProc].ProcessId);
     LookupAccountSid(nil, pProcessInfo[nProc].pUserSid, nil, UserSize, nil, DomainSize, snu);
     if (UserSize <> 0) or (DomainSize <> 0) then
     begin
       SetLength(User, UserSize);
       SetLength(Domain, DomainSize);
       Result:= LookupAccountSid(nil, pProcessInfo[nProc].pUserSid, @User[1], UserSize, @Domain[1], DomainSize, snu);
     end;
     WTSFreeMemory(pProcessInfo);
   end;
 end;

Más información aquí.

Saludos.

Podria usarse un mutex?

Código Delphi [-]
procedure OpenMutex(const AMutexName: string);
var
  FMutex: Cardinal;
begin
  FMutex := CreateMutex(NIL, True, PWChar(Format('%s.mutex', [AMutexName])));
  if (FMutex = 0) or (GetLastError = ERROR_ALREADY_EXISTS) then
   RaiseLastOSError;
end;

Edito: Ya veo que te respondio escafandra que seguro la tiene mas clara en estos temas

Gracias por vuestra ayuda.
Probaré entonces con la solución de escafandra, que si no he entendido mal sería añadir dentro de mi bucle una comprobación para todas las instancias de mi aplicación que me aparezcan, si alguna pertenece al usuario actual de la sesión de terminal server.
Un saludo

Esa es la idea. :)

Saludos.