Suma de exponente entre factorial

[Daniel2622]

Hola, tengo un problema con el siguiente ejercicio:
Escribe una función que reciba los valores del exponente (x) y el número de términos (n) y devuelva el valor de e^x, mediante la suma:
e^x=x^0/0!+x^1/1!+x^2/2!+...
Este es el código que he creado:
Function Suma(b,n,co,co1:Integer):Integer;
var c,p,i:Integer;
f:Longint;
s:Real;
begin
p:=1;
For c:=1 to n do
p:=p*b;
Suma:=p;
begin
f:=1;
For c:=1 to n do
f:=f*c;
Suma:=f;
begin
co:=p;
co1:=f;
s:=0;
While i<=n do
begin
s:=s+(co/co1);
co:=c+f;
co1:=co1+p;
i:=i+1;
end;
end;

procedure Form1.BitBtn1Click(Sender: TObject);
var b,n,p,f:Integer
begin
val(Edit1.Text,n);
p:=potencia(b,n);
Edit2.Text:=IntToStr(p);
f:=Factorial(n);
Edit3.Text:=IntToStr(f);
Edit4.Text:=FloatToStr(s);
end;

Gracias y saludos.

[Casimiro Notevi]

¿Qué son esos "begin" ahí por el medio?

Function Suma(b,n,co,co1:Integer):Integer;
var c,p,i:Integer;
f:Longint;
s:Real;
begin
p:=1;
For c:=1 to n do
p:=p*b;
Suma:=p;
begin <-----------------
f:=1;
For c:=1 to n do
f:=f*c;
Suma:=f;
begin <-----------------
co:=p;
co1:=f;
s:=0;
While i<=n do
begin
s:=s+(co/co1);
co:=c+f;
co1:=co1+p;
i:=i+1;
end;
end;

procedure Form1.BitBtn1Click(Sender: TObject);
var b,n,p,f:Integer
begin
val(Edit1.Text,n);
p:=potencia(b,n);
Edit2.Text:=IntToStr(p);
f:=Factorial(n);
Edit3.Text:=IntToStr(f);
Edit4.Text:=FloatToStr(s);
end;

[Daniel2622]

Hola Casimiro Notevi
Los "begin" los puse porque empiezo una nueva función, ya que la primera función es para que se haga la potencia del número que ingrese, la segunda para sacar el factorial del mismo número y la última función que coloque es para hacer la suma que me pide el ejercicio.

[ecfisa]

Hola.

Es que esa no es la forma correcta de declarar el inicio y finalizacíon de una función o procedimiento, el formato general sería:

function Nombre (<parámetros>): tipo retorno;

<const (declaración de constantes locales)>
<type (definición local de tipos)>
<var (declaración de variables locales)>

<function(<parámetros>): tipo retorno; (declaración de funciones locales)
begin
...
end>
<procedure(<parámetros>); (declaración de procedimientos locales)
begin
...
end>

begin
(cuerpo de la función)
end;


Podes usar las funciones o procedimientos de dos modos, habiéndo sido declaradas externas a la función:

function potencia(...): Integer;
begin
...
end;

function factorial(...): Integer;
begin
...
end;

function Suma(...): Integer;
begin
potencia(...);
factorial(...)
...
end;


o como locales a ella:

function Suma(...): Integer;
...

function potencia(...): Integer;
begin
...
end;

function factorial(...): Integer;
begin
...
end;

begin
potencia(...);
factorial(...);
end;

Las funciones potencia y factorial (locales o externas) podrían escribirse de modo iterativo,

function potencia( base, expo: Integer ): Integer;
var
i: Integer;
begin
Result := 1;
for i := 1 to expo do
Result := Result * base;
end;

function factorial( numero: Integer ): Integer;
var
i: Integer;
begin
Result := 1;
for i := 1 to numero do
Result := Result * i;
end;


o de modo recursivo:

function potencia(base, expo: Integer): Integer;
begin
if expo = 0 then
potencia := 1
else
potencia := base * potencia(base, expo - 1);
end;

function factorial(n: Integer): Integer;
begin
if n = 0 then
factorial := 1
else
factorial := n * factorial( n - 1);
end;

Pero en cualquiera de los casos, contando con las funciones potencia/factorial, la función Suma podría ser:

function Suma(const x, y: Integer): Double;
var
i: Integer;

// ...

begin
Result := 0;
for i := 0 to y do
Result := Result + potencia(x, i) / factorial(i);
end;


Saludos :)

[Daniel2622]

Hola ecfisa, ya trate de construir un código siguiendo tus recomendaciones.
El programa ya corre, pero al momento de imprimir los valores y calcular el resultado me sale este mensaje:

El proyecto project1 ha lanzado una exepción de la claes 'External:SIGFPE'.

At address 43E83B

Y este es mi nuevo código:

Function Potencia(b,n:Integer):Integer;
var c,p:Integer;
begin
p:=1;
For c:=1 to n do
p:=p*b;
Potencia:=p;
end;
Function Factorial(n:Integer):Integer;
var c:Integer;f:Longint;
begin
f:=1;
For c:=1 to n do
f:=f*c;
Factorial:=f;
end;
Function Suma(const x,y:Integer):Double;
var i:Integer;
begin
Result:=0;
For i:=0 to y do
Result:=Result+(Potencia(x,i)/Factorial(i));
end;
procedure TForm1.BitBtn1Click(Sender: TObject);
var b,n,p:Integer;
i:Real;
begin
val(Edit1.Text,n);
p:=Potencia(b,n);
Edit2.Text:=IntToStr(p);
Edit3.Text:=FloatToStr(i);
end;

Esperó y me puedas seguir ayudando.
Saludos y Gracias.

[ecfisa]

Hola.

Intentalo de este modo:

Function Potencia(b,n:Integer):Integer;
var c,p:Integer;
begin
p:=1;
For c:=1 to n do
p:=p*b;
Potencia:=p;
end;

Function Factorial(n:Integer):Integer;
var c:Integer;f:Longint;
begin
f:=1;
For c:=1 to n do
f:=f*c;
Factorial:=f;
end;

Function Suma(const x,y:Integer):double;
var i:Integer;
begin
Result:=0;
For i:=0 to y do
Result:=Result+ Potencia(x,i) / Factorial(i) ;
end;

procedure TForm1.BitBtn1Click(Sender: TObject);
var
a,b: Integer;
i : Double;
begin
a := StrToIntDef( Edit1.Text, 0 ); // a : primer argumento de Suma
b := StrToIntDef( Edit2.Text, 0 ); // b : segundo argumento de Suma
i := Suma( a, b ); // i : resultado de Suma

// mostrar el valor de "i" en Edit3
Edit3.Text := FloatToStr( i );
end;


Saludos :)

[Daniel2622]

Gracias ecfisa, me sirvió mucho el último código.
Sólo que tengo dos dudas, la primera es:
¿Por qué se utiliza el tipo de retorno "Double"? y ¿Para qué sirve el "StrToIntDef"?

Saludos.

[ecfisa]

Hola.

¿Por qué se utiliza el tipo de retorno "Double"?

A fin de obtener un resultado mas fidedigno.

Se podría declarar con un retorno de tipo entero, vg.:

function SumaInt(const x, y: Integer): Integer;
var
i: Integer;
begin
Result := 0;
for i := 0 to y do
Result := Result + Trunc(pot(x, i) / fac(i) );
// ó: Result := Result + pot(x, i) div fac(i);
end;

Pero se pierden decimales por la división entera, ejemplificando: Si enviamos a la función SumaInt como argumentos los valores 3 y 4 nos devuelve como resultado 15, cuando debería ser 16,375


y ¿Para qué sirve el "StrToIntDef"?

La función StrToIntDef convierte una cadena en un número entero y de no ser posible la conversión, devuelve el valor por defecto (segundo parámetro), ejemplo:

var
n : Integer;
begin
n := StrToIntDef( 'xxx', 99 );
Caption := FloatToStr( n ); // Caption = '99'

Usé esa función por que tu código toma los valores a convertir desde dos Edits y el usuario podría introducir un valor que no represente un número válido y por tanto elevar una excepción como sucedería en el caso de usar la función StrToInt.

Por si desearas hacer comprobaciónes, te pongo dos ejemplos con distintos modos:

...
var
n : Integer;
begin
try
n := StrToInt( Edit1.Text );
except on E: Exception do
ShowMessage(E.Message);
end;
end;



var
n : Integer;
begin
if not TryStrToInt( Edit1.Text, n ) then
ShowMessage('Edit1 no contiene un entero válido');



Saludos :)

[Daniel2622]

Muchas gracias ecfisa, me fue de gran ayuda tu explicación.
Saludos.