Validar Contenido Portapapeles

[juniorSoft]

Hola de nuevo Amigos,

he creado las siguientes acciones en Firemonkey para copiar y pegar texto pero que su contenido sean números

procedure TFrmCalculadora.AcCopiarExecute(Sender: TObject);
var
Clipboard: IFMXClipboardService;
Value: TValue;
begin
if TPlatformServices.Current.SupportsPlatformService(IFMXClipboardService,
IInterface(Clipboard)) then
begin
Value := TValue.From<string>(label1.Text);
Clipboard.SetClipboard(Value);
end;
end;

procedure TFrmCalculadora.AcPegarExecute(Sender: TObject);
var
Clipboard: IFMXClipboardService;
Value: TValue;
begin
if TPlatformServices.Current.SupportsPlatformService(IFMXClipboardService,
IInterface(Clipboard)) then
begin
Value := Clipboard.GetClipboard;
label1.Text:=Value.AsString;
end;
end;


Mi pregunta es como puedo validar la información que tiene el Portapapeles para saber si este contenido es un número de punto flotante y no otro tipo de información.

[juniorSoft]

Ya, me respondo y a cualquiera que le pueda ser util

procedure TFrmCalculadora.AcPegarExecute(Sender: TObject);
var
Clipboard: IFMXClipboardService;
Value: TValue;
begin
if TPlatformServices.Current.SupportsPlatformService(IFMXClipboardService,
IInterface(Clipboard)) then
begin
Value := Clipboard.GetClipboard;
if StrToFloatDef(Value.AsString, -0) <> -0 then
Display.Text:=Value.AsString
else
Display.Text:='0';
end;
end;
end;

[juniorSoft]

Trate de Utilizar


if value.IsType<.Double> then

pero no funciono

[AgustinOrtu]

Mas alla de que lo hayas solucionado, como consejo para el futuro, debes aprender a identificar y aislar los problemas. Osea en este caso, mas que un problema del portapapeles, lo que tenes delante es un problema de validacion de strings. Simplemente debes validar que un string (no importa de donde venga, ingresado por el usuario, una respuesta de un webservice, un campo de una base de datos, el contenido de portapapeles) contenga solo numeros

Y otra cosa es que debes tener cuidado con el tratamiento de numeros de punto flotante, sobre todo para las comparaciones. Esta es la explicacion universal (http://floating-point-gui.de/), mientras que este link (http://pages.cs.wisc.edu/~rkennedy/exact-float) es mas "Delphi especifico", y esta es la documentacion oficial (http://docwiki.embarcadero.com/RADStudio/en/About_Floating-Point_Arithmetic)

En pocas palabras, los numeros de punto flotante no se pueden representar con exactitud. Pueden ocurrir absurdos matematicos como 2.0 = 2.0 --> Evaluando a False

Obviamente hay soluciones al problema, para comparar numeros de coma flotante podes usar las funciones definidas en la unidad System.Math (http://docwiki.embarcadero.com/Libraries/en/System.Math). En particular para saber si un flotante es cero deberias utilizar la funcion System.Math.IsZero (http://docwiki.embarcadero.com/Libraries/Berlin/en/System.Math.IsZero). Otros metodos para comparar incluyen System.Math.SameValue (http://docwiki.embarcadero.com/Libraries/Berlin/en/System.Math.SameValue) y System.Math.CompareValue (http://docwiki.embarcadero.com/Libraries/Berlin/en/System.Math.CompareValue)

Y por ultimo, la solucion mas adecuada a tu problema (es este string un numero de punto flotante?) sea utilizar la funcion System.SysUtils.TryStrToFloat (http://docwiki.embarcadero.com/Libraries/en/System.SysUtils.TryStrToFloat)

Esta funcion devuelve un Boolean indicando si el string es un numero de punto flotante, y tambien tiene un parametro de salida con la conversion ya realizada:


var
s: string;
Value: Double;
begin
s := // obtienes el contenido como string del clipboard
if TryStrToFloat(s, Value) then
begin
// "s" es un string que representa un valor de tipo Double, y la variable Value contiene ese valor
end
else
// "s" no representa un valor de tipo Double; el valor de la variable Value es indefinido
end;

[AgustinOrtu]

Trate de Utilizar


if value.IsType<.Double> then

pero no funciono


El registro System.Rtti.TValue (http://docwiki.embarcadero.com/Libraries/en/System.Rtti.TValue) es un tanto especial, ya que es un "contenedor" de cualquier tipo de datos. Desde objetos, a interfaces, metaclases, punteros, primitivos, otros registros, metodos anonimos..

Ahora bien, dicho "valor" se escribe con un dato de entrada de "cierto tipo", y el metodo IsType<T> (http://docwiki.embarcadero.com/Libraries/Seattle/en/System.Rtti.TValue.IsType) lo que hace es comparar el TypeInfo (http://docwiki.embarcadero.com/Libraries/en/System.TypeInfo) entre lo que le envias como generico y el del valor almacenado.

Un ejemplo practico:


var
v: TValue;
begin
// inicializamos un TValue con un string
v := TValue.From<string>('1234');

// la sobrecarga del operador implicito hace posible esta sintaxis tambien
v := '1234';

Writeln(v.IsType<string>); // --> True
Writeln(v.IsType<Integer>); // -- False
end;


Lo que te quiero decir es que IsType<T> va a comparar por el valor "raw" internamente almacenado. No realiza ninguna conversion ni ninguna validacion, estas comparando el tipo de datos; y tiene logica puesto que un string no es un Integer, por mucho mas que la conversion en este caso fuera posible

[juniorSoft]

Como ultima Interrogante de este caso, sería muy costoso en términos de recursos utilizar el evento onUpdate de la acción para verificar si hay datos en el Portapapeles; en VCL esa acción para el TActionList viene Stadard. Como lo hice funciona bien pero uno siempre trata de hacer las cosas lo mejor que se puede.

Siempre que puedo evito tener que usar este evento para mantener activo/inactivos controles pero en casos como este la opción pegar solo estaría activa si hay algo en el portapapeles y en este caso un número

Definí el OnUpdate de la Acción de la siguiente manera

procedure TFrmCalculadora.AcPegarUpdate(Sender: TObject);
var
Clipboard: IFMXClipboardService;
Value:Double;
begin
if TPlatformServices.Current.SupportsPlatformService(IFMXClipboardService,
IInterface(Clipboard)) then
TAction(Sender).Enabled:= TryStrToFloat(Clipboard.GetClipboard.ToString, Value);
end;


Gracias nuevamente AgustinOrtu

[AgustinOrtu]

En realidad el evento TAction.OnUpdate (http://docwiki.embarcadero.com/Libraries/en/System.Classes.TBasicAction.OnUpdate) es invocado cuando la aplicación está ociosa. Siempre y cuando no hagas cosas que demoren tiempo dentro de estos eventos no habrá problema. Una posible mejora que no tendrá gran impacto en el código es guardar la referencia al servicio del portapapeles e invocar sobre esa referencia el método GetClipboard

No programes tan defensivamente. Si realmente este evento te genera un problema de performance, recién ahí es el momento de optimizar.

[juniorSoft]

Gracias Nuevamente ^\||/