Evitar parpadeos en TListView

[Reasen]

Hola! Tengo un "Problema" al usar el TListView de Delphi XE, pues lo que hago es lo siguiente:
Cargo un par de objetos con sus sub-objetos con el típico ViewStyle(vsReport)
Hasta ahí bien pero a la hora de actualizar sus valores por ejemplo

Por ejemplo con varios objetos en bucle, etc:
Form1.listview1.items[i].subitem[1] := 'blabla';

Me parpadean todos o el mismo objeto de la lista, he estado investigando sobre el asunto pues...


Estoy usando los Styles nativos de Delphi, si los desactivo me quedo con la ventana sin Skin pero ese problema desaparece,
he leído en algunos foros que andaban con el mismo problema que dejara activado el "Doble Buffer" también lo activé pero sin resultados,
... Usarlo sin skin no es una posible solución por el momento, algún consejo? :confused:

[AgustinOrtu]

Debes indicarle al TListView que vas a realizar modificaciones o inserciones masivas de Items:

Eso se hace con los metodos BeginUpdate (http://docwiki.embarcadero.com/Libraries/en/Vcl.ComCtrls.TListItems.BeginUpdate) y EndUpdate (http://docwiki.embarcadero.com/Libraries/en/Vcl.ComCtrls.TListItems.EndUpdate) de la clase TListItems (http://docwiki.embarcadero.com/Libraries/Berlin/en/Vcl.ComCtrls.TListItems) (propiedad Items de los TListView). Basicamente lo que hace es demorar todas las actualizaciones visuales hasta que se llame a EndUpdate. La estructura general es la siguiente:


procedure ...
var
ListItem: TListItem;
begin
ListView.Items.BeginUpdate;
try
bucle for/while/ etc
begin
// crear el ListItem y setear propiedades segun corresponda
ListItem := ListView.Items.Add;
ListItem.Caption := 'blabla';
ListItem.SubItems.Add('blabla');
// etc
end;
finally
ListView.Items.EndUpdate;
end;
end;


El try-finally asegura que se invoque siempre en ultima instancia el metodo EndUpdate. De omitirse ese llamado, el ListView nunca se actualiza.

Es importante notar que por cada BeginUpdate que se invoque, se debe emparejar con un EndUpdate. Es decir, los BeginUpdate se pueden "anidar", asi que despues es necesario "deshacerlos", uno por uno, con un EndUpdate

[escafandra]

Intenta evitar el repintado durante el bucle:


// Evito que se repinte a cada actualización de línea...
SendMessage(ListView1.Handle, WM_SETREDRAW, FALSE, 0);

... Mi bucle de llenado...

// Permito que se repinte y obligo a que se actualize
SendMessage(ListView1.Handle, WM_SETREDRAW, TRUE, 0);
InvalidateRect(ListView1.Handle, nil, TRUE);



Saludos.

[Reasen]

Debes indicarle al TListView que vas a realizar modificaciones o inserciones masivas de Items:

Eso se hace con los metodos BeginUpdate (http://docwiki.embarcadero.com/Libraries/en/Vcl.ComCtrls.TListItems.BeginUpdate) y EndUpdate (http://docwiki.embarcadero.com/Libraries/en/Vcl.ComCtrls.TListItems.EndUpdate) de la clase TListItems (http://docwiki.embarcadero.com/Libraries/Berlin/en/Vcl.ComCtrls.TListItems) (propiedad Items de los TListView). Basicamente lo que hace es demorar todas las actualizaciones visuales hasta que se llame a EndUpdate. La estructura general es la siguiente:

Código Delphi [-] (http://clubdelphi.com/foros/#)procedure ... var ListItem: TListItem; begin ListView.Items.BeginUpdate; try bucle for/while/ etc begin // crear el ListItem y setear propiedades segun corresponda ListItem := ListView.Items.Add; ListItem.Caption := 'blabla'; ListItem.SubItems.Add('blabla'); // etc end; finally ListView.Items.EndUpdate; end; end;


El try-finally asegura que se invoque siempre en ultima instancia el metodo EndUpdate. De omitirse ese llamado, el ListView nunca se actualiza.

Es importante notar que por cada BeginUpdate que se invoque, se debe emparejar con un EndUpdate. Es decir, los BeginUpdate se pueden "anidar", asi que despues es necesario "deshacerlos", uno por uno, con un EndUpdate


Ese método por desgracia solo provoca más parpadeos... Si no me equivoco es por la skin.

He ido probando cosas y finalmente he encontrado una manera de evitar los parpadeos usando una Skin de Delphi,
lo dejo por aquí por si alguien se encuentra con el problema en un futuro:

Form1.DoubleBuffered:=true;
ListView1.DoubleBuffered:=true;

En StyleElements deseleccionamos seClient en ListView y en el Form y así de simple ya deja de parpadear y podemos usar una skin sin problemas.


Yo estaba ya pensando que era necesario un Hook a la Skin, me estaba mirando documentación de RRUZ jaja

[AgustinOrtu]

En mi caso no experimento parpadeo con el siguiente codigo:


unit Unit1;

interface

uses
System.Classes, Vcl.Forms, Vcl.Controls, Vcl.ExtCtrls, Vcl.StdCtrls,
Vcl.ComCtrls;

type
TForm1 = class(TForm)
ListView1: TListView;
btnPopulate: TButton;
btnPopulateBeginUpdate: TButton;
Panel1: TPanel;
procedure FormCreate(Sender: TObject);
procedure btnPopulateClick(Sender: TObject);
procedure btnPopulateBeginUpdateClick(Sender: TObject);
private
procedure PopulateListView;
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

uses
System.SysUtils,
System.Diagnostics,
Vcl.Themes, Vcl.Styles;

procedure TForm1.FormCreate(Sender: TObject);
begin
TStyleManager.TrySetStyle('Vapor');
ListView1.ViewStyle := TViewStyle.vsReport;
ListView1.Columns.Add.Caption := 'Columna 1';
ListView1.Columns.Add.Caption := 'Columna 2';
ListView1.Columns.Add.Caption := 'Columna 3';
end;

procedure TForm1.PopulateListView;
var
I: Integer;
Value: string;
ListItem: TListItem;
sw: TStopwatch;
begin
sw := TStopwatch.StartNew;

ListView1.Clear;
for I := 0 to 10000 do
begin
ListItem := ListView1.Items.Add;
Value := IntToStr(I);
ListItem.Caption := 'Item # ' + Value;
ListItem.SubItems.Add('SubItem # ' + Value);
ListItem.SubItems.Add('SubItem # ' + Value);
ListItem.SubItems.Add('SubItem # ' + Value);
end;

sw.Stop;
Caption := Format('Demoro: %d ms', [sw.ElapsedMilliseconds]);
end;

procedure TForm1.btnPopulateBeginUpdateClick(Sender: TObject);
begin
ListView1.Items.BeginUpdate;
try
PopulateListView;
finally
ListView1.Items.EndUpdate;
end;
end;

procedure TForm1.btnPopulateClick(Sender: TObject);
begin
PopulateListView;
end;

end.


Que Style estas usando? Cuantos items estas agregando?

[Reasen]

Que Style estas usando? Cuantos items estas agregando?

Bueno el Style de Delphi no es una prioridad ya que ocurre en todos,
cantidad de objetos, aproximadamente 200, los parpadeos no suelen ocurrir al agregar Items sino al editar el texto de los mismos,
pero probando con las propiedades encontré una manera de arreglar el problema.
Anteriormente antes de abrir el tema también intente con el BeginUpdate, pensaba que la situación era mucho mas complicada por algún confligto entre las skins de Delphi.

[Reasen]

Intenta evitar el repintado durante el bucle:

Código Delphi [-]

// Evito que se repinte a cada actualización de línea...
SendMessage(ListView1.Handle, WM_SETREDRAW, FALSE, 0);

... Mi bucle de llenado...

// Permito que se repinte y obligo a que se actualize
SendMessage(ListView1.Handle, WM_SETREDRAW, TRUE, 0);
InvalidateRect(ListView1.Handle, nil, TRUE);



Saludos.
Había visto ejemplos pero nunca usando InvalidateRect, me lo guardo para futuras ocasiones!

[AgustinOrtu]

Al parecer tenes razon, el problema ocurre al editar y los que noto mas que parpadean son los SubItems. El problema no existe si no se usan Styles

Creo que poco podemos hacer mas que reportar a Embarcadero (https://quality.embarcadero.com/secure/Dashboard.jspa)

[Reasen]

Al parecer tenes razon, el problema ocurre al editar y los que noto mas que parpadean son los SubItems. El problema no existe si no se usan Styles

Creo que poco podemos hacer mas que reportar a Embarcadero (https://quality.embarcadero.com/secure/Dashboard.jspa)

Pero tiene solución si lo ponemos de esta manera(Lo comenté mas arriba):

Form1.DoubleBuffered:=true;
ListView1.DoubleBuffered:=true;

En StyleElements deseleccionamos seClient en ListView y en el Form, así de simple ya deja de parpadear y podemos usar una skin sin problemas.

[AgustinOrtu]

Si pero eso es quitarle el skin al ListView. Estas quitandole una pieza a tu programa para solucionar un problema. No me parece una "solucion"

De todos modos, es tan molesto el parpadeo?

[Reasen]

Si pero eso es quitarle el skin al ListView. Estas quitandole una pieza a tu programa para solucionar un problema. No me parece una "solucion"

De todos modos, es tan molesto el parpadeo?

...No, de esa manera la skin permanece, se ve todo exactamente igual pero el parpadeo desaparece.

[AgustinOrtu]

Que interesante, en la mayoria de los controles el TStyleElement.seClient es el "mas importante". De hecho si a un TButton le sacas esa propiedad, se ve "comun" por eso la intuicion me decia lo mismo del TListView. A simple vista no note ninguna diferencia entre tener activado o no TStyleElement.seClient en el TListView.