deshabilitar componentes a traves de una lista

[DarkBlue]

Hola ahora quisiera saber como desabilitar componentes por medio de una lista ya que ya encontre como desabilitar componentes dependiendo de la clase que sean ...

Procedure ActDescBotones(Valor:Boolean);
Var
i: integer;
Begin
for i := ComponentCount - 1 downto 0 do
begin
if Components is TButton then
TButton(Components).Enabled := False;
end;
End;

intente modificar el codigo pero me hace falta conocimiento e imaginacion , tengo en un arreglo de string (desabilita) los nombres de los componentes que quiero desabilitar pero no se me ocurre una manera intente algo como esto pero nisiquiera corre jajaja . Ademas que me sorprende eso del IS que es?



for x:=0 to length(desabilita) do
begin


if inventario.Components[X].Name=desabilita[x] then
TComponent(inventario.Components[x]).Enabled := False;

end;


por su atención gracias

[ecfisa]

Hola DarkBlue.

La palabra clave is, se utiliza para saber si un objeto pertenece o desciende de una clase determinada.

Por lo que veo en tu código: for x:=0 to length(desabilita) do..., supongo que intentas pasarle a un procedimiento,
mediante un vector abierto, los nombres de los componentes a deshabilitar.

Un modo de hacerlo puede ser:

procedure TForm1.Deshabilita(v: array of string);
var
i,j: Integer;
begin
for i:= 0 to ComponentCount -1 do
for j:= High(v) downto Low(v) do
if (Components[i] is TControl) and (Components[i].Name = v[j]) then
TControl(Components[i]).Enabled:= False;
end;


Llamadas de ejemplo:

procedure TForm1.Button1Click(Sender: TObject);
var
v: array[1..5] of string;
begin
v[1]:= 'Button5';
v[2]:= 'Button2';
v[3]:= 'Edit2';
v[4]:= 'Button7';
v[5]:= 'Label1';
Deshabilita(v);
end;

O directamente:

procedure TForm1.Button1Click(Sender: TObject);
begin
Deshabilita(['Label1','Edit2','Button2','Button7', 'OpenDialog1']);
end;


Como verás utilicé la comprobación:

if (Components[i] is TControl) and (Components[i].Name = v[j]) then


Para evitar una posible excepción al referenciar un componente que no derive de TControl, como en el último ejemplo. ( 'Opendialog1' ).

Un saludo.

[DarkBlue]

wow tienes mucho conocimiento gracias me has ayudado a descubrir cosas nuevas como por ejemplo eso de Components ¿Es acaso un objeto que contiene la lista de todos los componentes de nuestra aplicacion?, por que tiene esos corchetes que la mayoria de los arreglos tienen.

Otra pregunta usualmente que se hace con esas funciones que arrojan un resultado Tcomponent o un Tcontrol me podrias dar un ejemplo :D




ahh por que sera que no me funciono esto... se me bloqueaba el form entero...:cool:

for x:=0 to length(desabilita)-1 do
begin
Pos

with findcomponent(desabilita[x]) do enabled:=false;

end;

Gracias!!

[ecfisa]

Hola DarkBlue.


wow tienes mucho conocimiento

¡ Por aprender ! ... ;)


como por ejemplo eso de Components ¿Es acaso un objeto que contiene la lista de todos los componentes de nuestra aplicacion?


Components no es un objeto, es una propiedad vectorial de la clase TComponent. Y sí contiene la lista de todos los componentes de los cuales es propietario.(Owner).


ahh por que sera que no me funciono esto... se me bloqueaba el form entero...


for x:=0 to length(desabilita)-1 do
begin
Pos // Esto te tendría que dar sintax error
with findcomponent(desabilita[x]) do enabled:=false;
end;

El principal motivo de que no funcione es que la propiedad Enabled no existe en TComponent (si en TControl).

Usando FindComponent sería:

procedure TForm1.Deshabilita(v: array of string);
var
i:Integer;
TC: TComponent;
begin
for i:= Low(v) to High(v) do
begin
TC:= FindComponent(v[i]);
if TC is TControl then
TControl(TC).Enabled:=false;
end;
end;


Y ya que menciono a TControl, la propiedad vectorial Controls del mismo, también devuelve una lista de todos los controles de los cuales es propietaro.

Por lo que el ejemplo anterior también se podría haber escrito:

procedure TForm1.Deshabilita(v: array of string);
var
i,j: Integer;
begin
for i:= 0 to ControlCount -1 do
for j:= Low(v) to High(v) do
if Controls[i].Name = v[j] then
Controls[i].Enabled:= False;
end;


Es decir que sumando a la del mensaje anterior, ya tenemos tres formas de hacer lo mismo. :)

Un saludo.

[Neftali [Germán.Estévez]]

Sólo añadir, como complemento, que también se puede utilizar RTTI, para acceder a las propiedades de los componentes; Especialmente útil si hay muchos tipos de componentes a modificar o si no se sabe a ciencia cieta si la propiedad existe o no. Hay un ejemplo aquí (http://neftali.clubdelphi.com/?p=53).